epa-file.el

   1 ;;; epa-file.el --- the EasyPG Assistant, transparent file encryption
   2 ;; Copyright (C) 2006 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG
   6
   7 ;; This file is part of EasyPG.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Code:
  25
  26 (require 'epa)
  27
  28 (defgroup epa-file nil
  29   "The EasyPG Assistant hooks for transparent file encryption"
  30   :group 'epa)
  31
  32 (defun epa-file--file-name-regexp-set (variable value)
  33   (set-default variable value)
  34   (if (fboundp 'epa-file-name-regexp-update)
  35       (epa-file-name-regexp-update)))
  36
  37 (defcustom epa-file-name-regexp "\\.gpg\\(~\\|\\.~[0-9]+~\\)?\\'"
  38   "Regexp which matches filenames to be encrypted with GnuPG.
  39
  40 If you set this outside Custom while epa-file is already enabled, you
  41 have to call `epa-file-name-regexp-update' after setting it to
  42 properly update file-name-handler-alist.  Setting this through Custom
  43 does that automatically."
  44   :type 'regexp
  45   :group 'epa-file
  46   :set 'epa-file--file-name-regexp-set)
  47
  48 (defcustom epa-file-cache-passphrase-for-symmetric-encryption nil
  49   "If non-nil, cache passphrase for symmetric encryption."
  50   :type 'boolean
  51   :group 'epa-file)
  52
  53 (defcustom epa-file-inhibit-auto-save t
  54   "If non-nil, disable auto-saving when opening an encrypted file."
  55   :type 'boolean
  56   :group 'epa-file)
  57
  58 (defcustom epa-file-select-keys nil
  59   "If non-nil, always asks user to select recipients."
  60   :type 'boolean
  61   :group 'epa-file)
  62
  63 (defvar epa-file-encrypt-to nil
  64   "*Recipient(s) used for encrypting files.
  65 May either be a string or a list of strings.")
  66
  67 ;;;###autoload
  68 (put 'epa-file-encrypt-to 'safe-local-variable
  69      (lambda (val)
  70        (or (stringp val)
  71            (and (listp val)
  72                 (catch 'safe
  73                   (mapc (lambda (elt)
  74                           (unless (stringp elt)
  75                             (throw 'safe nil)))
  76                         val)
  77                   t)))))
  78
  79 ;;;###autoload
  80 (put 'epa-file-encrypt-to 'permanent-local t)
  81
  82 (defvar epa-file-handler
  83   (cons epa-file-name-regexp 'epa-file-handler))
  84
  85 (defvar epa-file-passphrase-alist nil)
  86
  87 (eval-and-compile
  88   (if (fboundp 'encode-coding-string)
  89       (defalias 'epa-file--encode-coding-string 'encode-coding-string)
  90     (defalias 'epa-file--encode-coding-string 'identity)))
  91
  92 (eval-and-compile
  93   (if (fboundp 'decode-coding-string)
  94       (defalias 'epa-file--decode-coding-string 'decode-coding-string)
  95     (defalias 'epa-file--decode-coding-string 'identity)))
  96
  97 (defun epa-file-name-regexp-update ()
  98   (interactive)
  99   (unless (equal (car epa-file-handler) epa-file-name-regexp)
 100     (setcar epa-file-handler epa-file-name-regexp)))
 101
 102 (defun epa-file-passphrase-callback-function (context key-id file)
 103   (if (and epa-file-cache-passphrase-for-symmetric-encryption
 104            (eq key-id 'SYM))
 105       (let ((entry (assoc file epa-file-passphrase-alist))
 106             passphrase)
 107         (or (copy-sequence (cdr entry))
 108             (progn
 109               (unless entry
 110                 (setq entry (list file)
 111                       epa-file-passphrase-alist (cons entry
 112                                                  epa-file-passphrase-alist)))
 113               (setq passphrase (epa-passphrase-callback-function context
 114                                                                  key-id nil))
 115               (setcdr entry (copy-sequence passphrase))
 116               passphrase)))
 117     (epa-passphrase-callback-function context key-id nil)))
 118
 119 (defun epa-file-handler (operation &rest args)
 120   (save-match-data
 121     (let ((op (get operation 'epa-file)))
 122       (if op
 123           (apply op args)
 124         (epa-file-run-real-handler operation args)))))
 125
 126 (defun epa-file-run-real-handler (operation args)
 127   (let ((inhibit-file-name-handlers
 128          (cons 'epa-file-handler
 129                (and (eq inhibit-file-name-operation operation)
 130                     inhibit-file-name-handlers)))
 131         (inhibit-file-name-operation operation))
 132     (apply operation args)))
 133
 134 (defun epa-file-decode-and-insert (string file visit beg end replace)
 135   (if (fboundp 'decode-coding-inserted-region)
 136       (save-restriction
 137         (narrow-to-region (point) (point))
 138         (let ((multibyte enable-multibyte-characters))
 139           (set-buffer-multibyte nil)
 140           (insert string)
 141           (set-buffer-multibyte multibyte)
 142           (decode-coding-inserted-region
 143            (point-min) (point-max)
 144            (substring file 0 (string-match epa-file-name-regexp file))
 145            visit beg end replace)))
 146     (insert (epa-file--decode-coding-string string (or coding-system-for-read
 147                                                        'undecided)))))
 148
 149 (defvar last-coding-system-used)
 150 (defun epa-file-insert-file-contents (file &optional visit beg end replace)
 151   (barf-if-buffer-read-only)
 152   (if (and visit (or beg end))
 153       (error "Attempt to visit less than an entire file"))
 154   (setq file (expand-file-name file))
 155   (let ((local-copy (epa-file-run-real-handler #'file-local-copy (list file)))
 156         (context (epg-make-context))
 157         string length entry)
 158     (if visit
 159         (setq buffer-file-name file))
 160     (epg-context-set-passphrase-callback
 161      context
 162      (cons #'epa-file-passphrase-callback-function
 163            file))
 164     (epg-context-set-progress-callback context
 165                                        #'epa-progress-callback-function)
 166     (unwind-protect
 167         (progn
 168           (if replace
 169               (goto-char (point-min)))
 170           (condition-case error
 171               (setq string (epg-decrypt-file context file nil))
 172             (error
 173              (if (setq entry (assoc file epa-file-passphrase-alist))
 174                  (setcdr entry nil))
 175              (signal 'file-error
 176                      (cons "Opening input file" (cdr error)))))
 177           (make-local-variable 'epa-file-encrypt-to)
 178           (setq epa-file-encrypt-to
 179                 (mapcar #'car (epg-context-result-for context 'encrypted-to)))
 180           (if (or beg end)
 181               (setq string (substring string (or beg 0) end)))
 182           (save-excursion
 183             (save-restriction
 184               (narrow-to-region (point) (point))
 185               (epa-file-decode-and-insert string file visit beg end replace)
 186               (setq length (- (point-max) (point-min))))
 187             (if replace
 188                 (delete-region (point) (point-max)))))
 189       (if (and local-copy
 190                (file-exists-p local-copy))
 191           (delete-file local-copy)))
 192     (list file length)))
 193 (put 'insert-file-contents 'epa-file 'epa-file-insert-file-contents)
 194
 195 (defun epa-file-write-region (start end file &optional append visit lockname
 196                                     mustbenew)
 197   (if append
 198       (error "Can't append to the file."))
 199   (setq file (expand-file-name file))
 200   (let* ((coding-system (or coding-system-for-write
 201                             (if (fboundp 'select-safe-coding-system)
 202                                 ;; This is needed since Emacs 22 has
 203                                 ;; no-conversion setting for *.gpg in
 204                                 ;; `auto-coding-alist'.
 205                                 (let ((buffer-file-name
 206                                        (file-name-sans-extension file)))
 207                                   (select-safe-coding-system
 208                                    (point-min) (point-max)))
 209                               buffer-file-coding-system)))
 210          (context (epg-make-context))
 211          (coding-system-for-write 'binary)
 212          string entry
 213          (recipients
 214           (cond
 215            ((listp epa-file-encrypt-to) epa-file-encrypt-to)
 216            ((stringp epa-file-encrypt-to) (list epa-file-encrypt-to)))))
 217     (epg-context-set-passphrase-callback
 218      context
 219      (cons #'epa-file-passphrase-callback-function
 220            file))
 221     (epg-context-set-progress-callback context
 222                                        #'epa-progress-callback-function)
 223     (condition-case error
 224         (setq string
 225               (epg-encrypt-string
 226                context
 227                (if (stringp start)
 228                    (epa-file--encode-coding-string start coding-system)
 229                  (epa-file--encode-coding-string (buffer-substring start end)
 230                                                  coding-system))
 231                (if (or epa-file-select-keys
 232                        (not (local-variable-p 'epa-file-encrypt-to)))
 233                    (epa-select-keys
 234                     context
 235                     "Select recipents for encryption.
 236 If no one is selected, symmetric encryption will be performed.  "
 237                     recipients)
 238                  (if epa-file-encrypt-to
 239                      (epg-list-keys context recipients)))))
 240       (error
 241        (if (setq entry (assoc file epa-file-passphrase-alist))
 242            (setcdr entry nil))
 243        (signal 'file-error (cons "Opening output file" (cdr error)))))
 244     (epa-file-run-real-handler
 245      #'write-region
 246      (list string nil file append visit lockname mustbenew))
 247     (if (boundp 'last-coding-system-used)
 248         (setq last-coding-system-used coding-system))
 249     (if (eq visit t)
 250         (progn
 251           (setq buffer-file-name file)
 252           (set-visited-file-modtime))
 253       (if (stringp visit)
 254           (progn
 255             (set-visited-file-modtime)
 256             (setq buffer-file-name visit))))
 257     (if (or (eq visit t)
 258             (eq visit nil)
 259             (stringp visit))
 260         (message "Wrote %s" buffer-file-name))))
 261 (put 'write-region 'epa-file 'epa-file-write-region)
 262
 263 (defun epa-file-find-file-hook ()
 264   (if (and buffer-file-name
 265            (string-match epa-file-name-regexp buffer-file-name)
 266            epa-file-inhibit-auto-save)
 267       (auto-save-mode 0)))
 268
 269 (defun epa-file-select-keys ()
 270   "Select recipients for encryption."
 271   (interactive)
 272   (make-local-variable 'epa-file-encrypt-to)
 273   (setq epa-file-encrypt-to
 274         (epa-select-keys
 275          (epg-make-context)
 276          "Select recipents for encryption.
 277 If no one is selected, symmetric encryption will be performed.  ")))
 278
 279 ;;;###autoload
 280 (defun epa-file-enable ()
 281   (interactive)
 282   (if (memq epa-file-handler file-name-handler-alist)
 283       (message "`epa-file' already enabled")
 284     (setq file-name-handler-alist
 285           (cons epa-file-handler file-name-handler-alist))
 286     (add-hook 'find-file-hooks 'epa-file-find-file-hook)
 287     (message "`epa-file' enabled")))
 288
 289 ;;;###autoload
 290 (defun epa-file-disable ()
 291   (interactive)
 292   (if (memq epa-file-handler file-name-handler-alist)
 293       (progn
 294         (setq file-name-handler-alist
 295               (delq epa-file-handler file-name-handler-alist))
 296         (remove-hook 'find-file-hooks 'epa-file-find-file-hook)
 297         (message "`epa-file' disabled"))
 298     (message "`epa-file' already disabled")))
 299
 300 (provide 'epa-file)
 301
 302 ;;; epa-file.el ends here