MSP_EXP430FR2355.asm

   1 ; -*- coding: utf-8 -*-
   2
   3 ; Fast Forth For Texas Instrument MSP430FR5739
   4 ; Tested on MSP-EXP430FR2355 launchpad
   5 ;
   6 ; Copyright (C) <2018>  <J.M. THOORENS>
   7 ;
   8 ; This program is free software: you can redistribute it and/or modify
   9 ; it under the terms of the GNU General Public License as published by
  10 ; the Free Software Foundation, either version 3 of the License, or
  11 ; (at your option) any later version.
  12 ;
  13 ; This program is distributed in the hope that it will be useful,
  14 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ; GNU General Public License for more details.
  17 ;
  18 ; You should have received a copy of the GNU General Public License
  19 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ; ======================================================================
  22 ; INIT MSP-EXP430FR2355 board
  23 ; ======================================================================
  24
  25 ; J101 (7xjumper)
  26 ; "SBWTCK"   ---> TEST
  27 ; "SBWTDIO"  ---> RST
  28 ; "TXD"      <--- P4.3  == UCA0TXD <-- UCA0TXDBUf
  29 ; "RXD"      ---> P4.2  == UCA0RXD --> UCA0RXDBUF
  30 ; "3V3"      <--> 3V3
  31 ; "5V0"      <--> 5V0
  32 ; "GND"      <--> GND
  33
  34
  35 ; SW1 -- P4.1
  36 ; SW2 -- P2.3
  37
  38 ; LED1 - P1.0   (red)
  39 ; LED2 - P6.6   (green)
  40
  41 ; I/O pins on J1:
  42 ; J1.1  - 3V3
  43 ; J1.2  - P1.5
  44 ; J1.3  - P1.6
  45 ; J1.4  - P1.7
  46 ; J1.5  - P3.6
  47 ; J1.6  - P5.2
  48 ; J1.7  - P4.5
  49 ; J1.8  - P3.4
  50 ; J1.9  - P1.3
  51 ; J1.10 - P1.2
  52
  53 ; I/O pins on J3:
  54 ; J3.21 - 5V0
  55 ; J3.22 - GND
  56 ; J3.23 - P1.4 A4 SEED
  57 ; J3.24 - P5.3 A11
  58 ; J3.25 - P5.1 A9
  59 ; J3.26 - P5.0 A8
  60 ; J3.27 - P5.4
  61 ; J3.28 - P1.1 A1 SEED
  62 ; J3.29 - P3.5 OA3O
  63 ; J3.30 - P3.1 OA2O
  64
  65
  66 ; I/O pins on J2:
  67 ; J2.11 - P3.0
  68 ; J2.12 - P2.5
  69 ; J2.13 - P4.4
  70 ; J2.14 - P4.7
  71 ; J2.15 - P4.6
  72 ; J2.16 - RST
  73 ; J2.17 - P4.0
  74 ; J2.18 - P2.2
  75 ; J2.19 - P2.0
  76 ; J2.20 - GND
  77
  78 ; I/O pins on J4:
  79 ; J2.31 - P3.2
  80 ; J2.32 - P3.3
  81 ; J2.33 - P2.4
  82 ; J2.34 - P3.7
  83 ; J2.35 - P6.4
  84 ; J2.36 - P6.3
  85 ; J2.37 - P6.2
  86 ; J2.38 - P6.1
  87 ; J2.39 - P6.0
  88 ; J2.40 - 2.1
  89
  90 ; LFXTAL XOUT- P2.6
  91 ; LFXTAL XIN - P2.7
  92
  93 ; ======================================================================
  94 ; MSP-EXP430FR2355 LAUNCHPAD    <--> OUTPUT WORLD
  95 ; ======================================================================
  96
  97 ;                                 +--4k7-< DeepRST switch <-- GND
  98 ;                                 |
  99 ; P4.3  - UCA1 TXD    J101.6 -  <-+-> RX  UARTtoUSB bridge
 100 ; P4.2  - UCA1 RXD    J101.8 -  <---- TX  UARTtoUSB bridge
 101 ; P2.0  - RTS         J2.19  -  ----> CTS UARTtoUSB bridge (TERMINAL4WIRES)
 102 ; P2.1  - CTS         J4.40  -  <---- RTS UARTtoUSB bridge (TERMINAL5WIRES)
 103
 104 ; P1.2  - UCB0 SDA    J1.10  -  <---> SDA I2C Master_Slave
 105 ; P1.3  - UCB0 SCL    J1.9   -  ----> SCL I2C Master_Slave
 106
 107 ; P2.2  -             J2.18  -  <---- TSSOP32236 (IR RC5)
 108
 109 ; P2.5  -             J2.13  -  <---- SD_CD (Card Detect)
 110 ; P4.4  -             J2.12  -  ----> SD_CS (Card Select)
 111 ; P4.5  - UCB1 CLK    J1.7   -  ----> SD_CLK
 112 ; P4.6  - UCB1 SIMO   J2.15  -  ----> SD_SDI
 113 ; P4.7  - UCB1 SOMI   J2.14  -  <---- SD_SDO
 114
 115 ; P6.0  -             J4.39  -  ----> SCL I2C Soft_Master
 116 ; P6.1  -             J4.38  -  <---> SDA I2C Soft_Master
 117
 118 ; ----------------------------------------------------------------------
 119 ; INIT order : WDT, GPIOs, FRAM, Clock, UARTs...
 120 ; ----------------------------------------------------------------------
 121
 122 ; ----------------------------------------------------------------------
 123 ; POWER ON RESET AND INITIALIZATION : LOCK PMM_LOCKLPM5
 124 ; ----------------------------------------------------------------------
 125
 126 ;              BIS     #LOCKLPM5,&PM5CTL0 ; unlocked by WARM
 127
 128 ; ----------------------------------------------------------------------
 129 ; POWER ON RESET AND INITIALIZATION : WATCHDOG TIMER A
 130 ; ----------------------------------------------------------------------
 131
 132 ; WDT code
 133         MOV #WDTPW+WDTHOLD+WDTCNTCL,&WDTCTL    ; stop WDT
 134
 135 ; ----------------------------------------------------------------------
 136 ; POWER ON RESET AND INITIALIZATION : I/O
 137 ; ----------------------------------------------------------------------
 138
 139 ; ----------------------------------------------------------------------
 140 ; POWER ON RESET AND INITIALIZATION : PORT1/2
 141 ; ----------------------------------------------------------------------
 142
 143 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 144
 145 ; PORTA usage
 146
 147 ;               P1.0  -   LED1 red
 148 ; UART RTS      P2.0  -   J2.19     ---->   CTS UARTtoUSB bridge (TERMINAL4WIRES)
 149 ; UART CTS      P2.1  -   J4.40     <----   RTS UARTtoUSB bridge (TERMINAL5WIRES)
 150 ;               P2.3  -   SW2
 151 ;               P2.5  -   J2.10     <----   SD_CD (Card Detect)
 152
 153             MOV #-1,&PAREN      ; all inputs with pull resistors
 154             MOV #1,&PADIR       ; all pins as input else LED1 as output
 155             MOV #0FFFEh,&PAOUT  ; all pins with pullup resistors else LED1 = output low
 156
 157     .IFDEF UCA0_TERM
 158 ; UCA0_RXD  -   P1.6    - J1.3      <----   TX  UARTtoUSB bridge
 159 ; UCA0_TXD  -   P1.7    - J1.4      ---->   RX  UARTtoUSB bridge
 160 RXD         .equ 40h        ; P1.6 = RXD
 161 TXD         .equ 80h        ; P1.7 = TXD + FORTH Deep_RST pin
 162 TERM_BUS    .equ 0C0h
 163 TERM_IN     .equ P1IN
 164 TERM_REN    .equ P1REN
 165 TERM_SEL    .equ P1SEL0
 166     .ENDIF
 167
 168     .IFDEF TERMINAL4WIRES
 169 ; RTS output is wired to the CTS input of UART2USB bridge
 170 ; configure RTS as output high (false) to disable RX TERM during start FORTH
 171 HANDSHAKOUT .equ    P2OUT
 172 HANDSHAKIN  .equ    P2IN
 173 RTS         .equ    1           ; P2.0
 174             BIS.B #RTS,&P2DIR   ; RTS as output high
 175         .IFDEF TERMINAL5WIRES
 176 ; CTS input must be wired to the RTS output of UART2USB bridge
 177 ; configure CTS as input low (true) to avoid lock when CTS is not wired
 178 CTS         .equ    2           ; P2.1
 179             BIC.B #CTS,&P2OUT   ; CTS input pulled down
 180         .ENDIF  ; TERMINAL5WIRES
 181     .ENDIF  ; TERMINAL4WIRES
 182
 183
 184 SD_CD       .equ  20h           ; P2.5
 185 SD_CDIN     .equ  P2IN
 186
 187 ; ----------------------------------------------------------------------
 188 ; POWER ON RESET AND INITIALIZATION : PORT3-4
 189 ; ----------------------------------------------------------------------
 190
 191 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 192
 193 ; PORTB usage
 194
 195 ;               P4.1    -   SW1
 196 ; UCA1 RXD      P4.2    -   J101.8  <----   TX  UARTtoUSB bridge
 197 ; UCA1 TXD      P4.3    -   J101.6  ---->   RX  UARTtoUSB bridge
 198 ;               P4.4    -   J2.9    ---->   SD_CS(Card Select)
 199 ; UCB1 CLK      P4.5    -   J1.7    ---->   SD_CLK
 200 ; UCB1 SIMO     P4.6    -   J2.15   ---->   SD_SDI
 201 ; UCB1 SOMI     P4.7    -   J2.14   <----   SD_SDO
 202
 203             MOV.B #-1,&PBOUT  ; pullup resistors for all pins
 204             BIS.B #-1,&PBREN  ; all pins with pull resistors
 205
 206     .IFDEF UCA1_TERM
 207 ; UCA1 RXD      P4.2    -   J101.8  <----   TX  UARTtoUSB bridge
 208 ; UCA1 TXD      P4.3    -   J101.6  ---->   RX  UARTtoUSB bridge
 209 RXD         .equ 4      ; P4.2 = RXD
 210 TXD         .equ 8      ; P4.3 = TXD + FORTH Deep_RST pin
 211 TERM_BUS    .equ 0Ch
 212 TERM_IN     .equ P4IN
 213 TERM_REN    .equ P4REN
 214 TERM_SEL    .equ P4SEL0
 215     .ENDIF
 216
 217     .IFDEF UCB1_SD
 218 SD_CS       .equ 10h    ; P4.4
 219 SD_CSOUT    .equ P4OUT
 220 SD_CSDIR    .equ P4DIR
 221
 222 SD_SEL      .equ PBSEL0 ; to configure UCB1
 223 SD_REN      .equ PBREN  ; to configure pullup resistors
 224 SD_BUS      .equ 0E000h ; pins P4.5 as UCA1CLK, P4.6 as UCA1SIMO & P4.7 as UCA1SOMI
 225     .ENDIF
 226 ; ----------------------------------------------------------------------
 227 ; POWER ON RESET AND INITIALIZATION : PORT5-6
 228 ; ----------------------------------------------------------------------
 229
 230 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 231
 232 ; PORT6 usage
 233
 234 ;           P6.6    -   LED2 green
 235
 236             BIS.B #0BFh,&P6REN  ; all pins with pull up resistors else P6.6
 237             MOV.B #0BFh,&P6OUT  ; OUT high for all pins else P6.6
 238             MOV.B #040h,&P6DIR  ; all pins with pullup resistors else LED2 = output low
 239
 240 ; ----------------------------------------------------------------------
 241 ; FRAM config
 242 ; ----------------------------------------------------------------------
 243
 244     .IF (FREQUENCY >8 ) && ( FREQUENCY <= 16)
 245             MOV.B   #0A5h, &FRCTL0_H     ; enable FRCTL0 access
 246             MOV.B   #10h, &FRCTL0         ; 1 waitstate @ 16 MHz
 247             MOV.B   #01h, &FRCTL0_H       ; disable FRCTL0 access
 248     .ELSEIF FREQUENCY > 16
 249             MOV.B   #0A5h, &FRCTL0_H     ; enable FRCTL0 access
 250             MOV.B   #20h, &FRCTL0         ; 2 waitstate @ 24 MHz
 251             MOV.B   #01h, &FRCTL0_H       ; disable FRCTL0 access
 252     .ENDIF
 253
 254 ; ----------------------------------------------------------------------
 255 ; POWER ON RESET SYS config
 256 ; ----------------------------------------------------------------------
 257
 258     MOV #0A500h,&SYSCFG0    ; enable write MAIN + INFO
 259
 260 ; ----------------------------------------------------------------------
 261 ; POWER ON RESET AND INITIALIZATION : CLOCK SYSTEM
 262 ; ----------------------------------------------------------------------
 263
 264 ; CS code for MSP430FR2355
 265
 266 ; to measure SMCLK frequency, wires SMCLK on P1.0:
 267 ;    BIS.B #1,&P1SEL1
 268 ;    BIS.B #1,&P1DIR
 269
 270 ; to measure REFO frequency, wires ACLK on P1.1:
 271 ;    BIS.B #2,&P1SEL1
 272 ;    BIS.B #2,&P1DIR
 273
 274
 275     .IF FREQUENCY = 0.5
 276
 277 ;            MOV     #058h,&CSCTL0       ; preset DCO = measured value @ 0x180 (88)
 278 ;            MOV     #0001h,&CSCTL1      ; Set 1MHZ DCORSEL,disable DCOFTRIM,Modulation
 279             MOV     #1ED1h,&CSCTL0       ; preset MOD=31, DCO = measured value @ 0x180 (209)
 280             MOV     #00B0h,&CSCTL1      ; Set 1MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 281 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 282 ;            MOV     #100Dh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Dh
 283                                         ; fCOCLKDIV = 32768 x (13+1) = 0.459 MHz ; measured :  MHz
 284 ;            MOV     #100Eh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Eh
 285                                         ; fCOCLKDIV = 32768 x (14+1) = 0.491 MHz ; measured :  MHz
 286             MOV     #100Fh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Fh
 287                                         ; fCOCLKDIV = 32768 x (15+1) = 0.524 MHz ; measured :  MHz
 288 ; =====================================
 289             MOV     #8,X
 290
 291     .ELSEIF FREQUENCY = 1
 292
 293 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 294 ;            MOV     #00B1h,&CSCTL1      ; Set 1MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 295             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 296             MOV     #00B0h,&CSCTL1      ; Set 1MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 297 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 298 ;            MOV     #001Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Dh
 299                                         ; fCOCLKDIV = 32768 x (29+1) = 0.983 MHz ; measured : 0.989MHz
 300             MOV     #001Eh,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Eh
 301                                         ; fCOCLKDIV = 32768 x (30+1) = 1.015 MHz ; measured : 1.013MHz
 302 ;            MOV     #001Fh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Fh
 303                                         ; fCOCLKDIV = 32768 x (31+1) = 1.049 MHz ; measured : 1.046MHz
 304 ; =====================================
 305             MOV     #16,X
 306
 307     .ELSEIF FREQUENCY = 2
 308
 309 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 310 ;            MOV     #00B3h,&CSCTL1      ; Set 2MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 311             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 312             MOV     #00B2h,&CSCTL1      ; Set 2MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 313 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 314 ;            MOV     #003Bh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Bh
 315                                         ; fCOCLKDIV = 32768 x (59+1) = 1.996 MHz ; measured :  MHz
 316             MOV     #003Ch,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Ch
 317                                         ; fCOCLKDIV = 32768 x (60+1) = 1.998 MHz ; measured :  MHz
 318 ;            MOV     #003Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Dh
 319                                         ; fCOCLKDIV = 32768 x (61+1) = 2.031 MHz ; measured :  MHz
 320 ; =====================================
 321             MOV     #32,X
 322
 323     .ELSEIF FREQUENCY = 4
 324
 325 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 326 ;            MOV     #00B5h,&CSCTL1      ; Set 4MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 327             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 328             MOV     #00B4h,&CSCTL1      ; Set 4MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 329 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 330 ;            MOV     #0078h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=78h
 331                                         ; fCOCLKDIV = 32768 x (120+1) = 3.965 MHz ; measured : 3.96MHz
 332
 333             MOV     #0079h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=79h
 334                                         ; fCOCLKDIV = 32768 x (121+1) = 3.997 MHz ; measured : 3.99MHz
 335
 336 ;            MOV     #007Ah,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=7Ah
 337                                         ; fCOCLKDIV = 32768 x (122+1) = 4.030 MHz ; measured : 4.020MHz
 338 ; =====================================
 339             MOV     #64,X
 340
 341     .ELSEIF FREQUENCY = 8
 342
 343 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 344 ;            MOV     #00B7h,&CSCTL1      ; Set 8MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 345             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 346             MOV     #00B6h,&CSCTL1      ; Set 8MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 347 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 348 ;            MOV     #00F3h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F3h
 349                                         ; fCOCLKDIV = 32768 x (243+1) = 7.995 MHz ; measured : 7.976MHz
 350             MOV     #00F4h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F4h
 351                                         ; fCOCLKDIV = 32768 x (244+1) = 8.028 MHz ; measured : 8.009MHz
 352
 353 ;            MOV     #00F5h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F5h
 354                                         ; fCOCLKDIV = 32768 x (245+1) = 8.061 MHz ; measured : 8.042MHz
 355 ; =====================================
 356             MOV     #128,X
 357
 358     .ELSEIF FREQUENCY = 12
 359
 360 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 361 ;            MOV     #00B9h,&CSCTL1      ; Set 12MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 362             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 363             MOV     #00B8h,&CSCTL1      ; Set 12MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 364 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 365 ;            MOV     #016Dh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E7h
 366                                         ; fCOCLKDIV = 32768 x 365+1) = 11.993 MHz ; measured : 11.xxxMHz
 367             MOV     #016Eh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E8h
 368                                         ; fCOCLKDIV = 32768 x 366+1) = 12.025 MHz ; measured : 12.xxxMHz
 369 ;            MOV     #016Fh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E9h
 370                                         ; fCOCLKDIV = 32768 x 367+1) = 12.058 MHz ; measured : 12.xxxMHz
 371 ; =====================================
 372             MOV     #192,X
 373
 374     .ELSEIF FREQUENCY = 16
 375
 376 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 377 ;            MOV     #00BBh,&CSCTL1      ; Set 16MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 378             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 379             MOV     #00BAh,&CSCTL1      ; Set 16MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 380 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 381 ;            MOV     #01E7h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E7h
 382                                         ; fCOCLKDIV = 32768 x 487+1) = 15.991 MHz ; measured : 15.95MHz
 383             MOV     #01E8h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E8h
 384                                         ; fCOCLKDIV = 32768 x 488+1) = 16.023 MHz ; measured : 15.99MHz
 385 ;            MOV     #01E9h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E9h
 386                                         ; fCOCLKDIV = 32768 x 489+1) = 16.056 MHz ; measured : 16.02MHz
 387 ; =====================================
 388             MOV     #256,X
 389
 390     .ELSEIF FREQUENCY = 20
 391
 392 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 393 ;            MOV     #00BDh,&CSCTL1      ; Set 20MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 394             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 395             MOV     #00BCh,&CSCTL1      ; Set 20MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 396 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 397 ;            MOV     #0261h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=261h
 398                                         ; fCOCLKDIV = 32768 x 609+1) = 19.988 MHz ; measured : 19.xxxMHz
 399             MOV     #0262h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=262h
 400                                         ; fCOCLKDIV = 32768 x 610+1) = 20.021 MHz ; measured : 20.xxxMHz
 401 ;            MOV     #0263h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=263h
 402                                         ; fCOCLKDIV = 32768 x 611+1) = 20.054 MHz ; measured : 20.xxxMHz
 403 ; =====================================
 404             MOV     #320,X
 405
 406     .ELSEIF FREQUENCY = 24
 407
 408 ;            MOV     #100h,&CSCTL0       ; preset DCO = 256
 409 ;            MOV     #00BFh,&CSCTL1      ; Set 24MHZ DCORSEL,enable DCOFTRIM=3h ,disable Modulation
 410             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 411             MOV     #00BEh,&CSCTL1      ; Set 24MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 412 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 413 ;            MOV     #02DBh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DBh
 414                                         ; fCOCLKDIV = 32768 x 731+1) = 23.986 MHz ; measured : 23.xxxMHz
 415             MOV     #02DCh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DCh
 416                                         ; fCOCLKDIV = 32768 x 732+1) = 24.019 MHz ; measured : 23.xxxMHz
 417 ;            MOV     #02DDh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DDh
 418                                         ; fCOCLKDIV = 32768 x 733+1) = 24.051 MHz ; measured : 24.xxxMHz
 419 ; =====================================
 420             MOV     #384,X
 421
 422     .ELSEIF
 423     .error "bad frequency setting, only 0.5,1,2,4,8,12,16,20,24 MHz"
 424     .ENDIF
 425
 426     .IFDEF LF_XTAL
 427 ;           MOV     #0000h,&CSCTL3      ; FLL select XT1, FLLREFDIV=0 (default value)
 428             MOV     #0000h,&CSCTL4      ; ACLOCK select XT1, MCLK & SMCLK select DCOCLKDIV
 429     .ELSE
 430             BIS     #0010h,&CSCTL3      ; FLL select REFCLOCK
 431 ;           MOV     #0100h,&CSCTL4      ; ACLOCK select REFO, MCLK & SMCLK select DCOCLKDIV (default value)
 432     .ENDIF
 433
 434             BIS &SYSRSTIV,&SAVE_SYSRSTIV; store volatile SYSRSTIV preserving a pending request for DEEP_RST
 435 ;            MOV &SAVE_SYSRSTIV,TOS  ;
 436 ;            CMP #2,TOS              ; POWER ON ?
 437 ;            JZ      ClockWaitX      ; yes
 438 ;            RRUM    #1,X            ; wait only 250 ms
 439 ClockWaitX  MOV     #5209,Y             ; wait 0.5s before starting after POR
 440
 441 ClockWaitY  SUB     #1,Y                ;1
 442             JNZ     ClockWaitY          ;2 5209x3 = 15625 cycles delay = 15.625ms @ 1MHz
 443             SUB     #1,X                ; x 32 @ 1 MHZ = 500ms
 444             JNZ     ClockWaitX          ; time to stabilize power source ( 500ms )
 445
 446 ;WAITFLL     BIT #300h,&CSCTL7         ; wait FLL lock
 447 ;            JNZ WAITFLL