inc/MSP_EXP430FR2355.asm

   1 ; -*- coding: utf-8 -*-
   2
   3 ; Fast Forth For Texas Instrument MSP430FR5739
   4 ; Tested on MSP-EXP430FR2355 launchpad
   5 ;
   6 ; Copyright (C) <2018>  <J.M. THOORENS>
   7 ;
   8 ; This program is free software: you can redistribute it and/or modify
   9 ; it under the terms of the GNU General Public License as published by
  10 ; the Free Software Foundation, either version 3 of the License, or
  11 ; (at your option) any later version.
  12 ;
  13 ; This program is distributed in the hope that it will be useful,
  14 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ; GNU General Public License for more details.
  17 ;
  18 ; You should have received a copy of the GNU General Public License
  19 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ; ======================================================================
  22 ; INIT MSP-EXP430FR2355 board
  23 ; ======================================================================
  24
  25 ; J101 (7xjumper)
  26 ; "SBWTCK"   ---> TEST
  27 ; "SBWTDIO"  ---> RST
  28 ; "TXD"      <--- P4.3  == UCA0TXD <-- UCA0TXDBUf
  29 ; "RXD"      ---> P4.2  == UCA0RXD --> UCA0RXDBUF
  30 ; "3V3"      <--> 3V3
  31 ; "5V0"      <--> 5V0
  32 ; "GND"      <--> GND
  33
  34
  35 ; SW1 -- P4.1
  36 ; SW2 -- P2.3
  37
  38 ; LED1 - P1.0   (red)
  39 ; LED2 - P6.6   (green)
  40
  41 ; I/O pins on J1:
  42 ; J1.1  - 3V3
  43 ; J1.2  - P1.5
  44 ; J1.3  - P1.6
  45 ; J1.4  - P1.7
  46 ; J1.5  - P3.6
  47 ; J1.6  - P5.2
  48 ; J1.7  - P4.5
  49 ; J1.8  - P3.4
  50 ; J1.9  - P1.3
  51 ; J1.10 - P1.2
  52
  53 ; I/O pins on J3:
  54 ; J3.21 - 5V0
  55 ; J3.22 - GND
  56 ; J3.23 - P1.4 A4 SEED
  57 ; J3.24 - P5.3 A11
  58 ; J3.25 - P5.1 A9
  59 ; J3.26 - P5.0 A8
  60 ; J3.27 - P5.4
  61 ; J3.28 - P1.1 A1 SEED
  62 ; J3.29 - P3.5 OA3O
  63 ; J3.30 - P3.1 OA2O
  64
  65
  66 ; I/O pins on J2:
  67 ; J2.11 - P3.0
  68 ; J2.12 - P2.5
  69 ; J2.13 - P4.4
  70 ; J2.14 - P4.7
  71 ; J2.15 - P4.6
  72 ; J2.16 - RST
  73 ; J2.17 - P4.0
  74 ; J2.18 - P2.2
  75 ; J2.19 - P2.0
  76 ; J2.20 - GND
  77
  78 ; I/O pins on J4:
  79 ; J2.31 - P3.2
  80 ; J2.32 - P3.3
  81 ; J2.33 - P2.4
  82 ; J2.34 - P3.7
  83 ; J2.35 - P6.4
  84 ; J2.36 - P6.3
  85 ; J2.37 - P6.2
  86 ; J2.38 - P6.1
  87 ; J2.39 - P6.0
  88 ; J2.40 - 2.1
  89
  90 ; LFXTAL XOUT- P2.6
  91 ; LFXTAL XIN - P2.7
  92
  93 ; ======================================================================
  94 ; MSP-EXP430FR2355 LAUNCHPAD    <--> OUTPUT WORLD
  95 ; ======================================================================
  96
  97 ;                                 +--4k7-< DeepRST switch <-- GND
  98 ;                                 |
  99 ; P4.3  - UCA1 TXD    J101.6 -  <-+-> RX  UARTtoUSB bridge
 100 ; P4.2  - UCA1 RXD    J101.8 -  <---- TX  UARTtoUSB bridge
 101 ; P2.0  - RTS         J2.19  -  ----> CTS UARTtoUSB bridge (TERMINAL4WIRES)
 102 ; P2.1  - CTS         J4.40  -  <---- RTS UARTtoUSB bridge (TERMINAL5WIRES)
 103
 104 ; P1.2  - UCB0 SDA    J1.10  -  <---> SDA I2C Master_Slave
 105 ; P1.3  - UCB0 SCL    J1.9   -  ----> SCL I2C Master_Slave
 106
 107 ; P2.2  -             J2.18  -  <---- TSSOP32236 (IR RC5)
 108
 109 ; P2.5  -             J2.13  -  <---- SD_CD (Card Detect)
 110 ; P4.4  -             J2.12  -  ----> SD_CS (Card Select)
 111 ; P4.5  - UCB1 CLK    J1.7   -  ----> SD_CLK
 112 ; P4.6  - UCB1 SIMO   J2.15  -  ----> SD_SDI
 113 ; P4.7  - UCB1 SOMI   J2.14  -  <---- SD_SDO
 114
 115 ; P6.0  -             J4.39  -  ----> SCL I2C Soft_Master
 116 ; P6.1  -             J4.38  -  <---> SDA I2C Soft_Master
 117
 118 ; ----------------------------------------------------------------------
 119 ; POWER ON RESET AND INITIALIZATION : I/O
 120 ; ----------------------------------------------------------------------
 121
 122 ; ----------------------------------------------------------------------
 123 ; POWER ON RESET AND INITIALIZATION : PORT1/2
 124 ; ----------------------------------------------------------------------
 125
 126 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 127
 128 ; PORTA usage
 129
 130 LED1_OUT    .equ    P1OUT
 131 LED1_DIR    .equ    P1DIR
 132 LED1        .equ    1           ;  P1.0 LED1 red
 133
 134     .IFDEF UCB0_TERM            ;
 135 TERM_SEL    .equ    P1SEL0
 136 TERM_REN    .equ    P1REN
 137 TERM_OUT    .equ    P1OUT
 138 BUS_TERM    .equ    0Ch         ; P1.2=SDA, P1.3=SCL
 139     .ENDIF
 140
 141 ;               P1.0  -   LED1 red
 142 ; UART RTS      P2.0  -   J2.19     ---->   CTS UARTtoUSB bridge (TERMINAL4WIRES)
 143 ; UART CTS      P2.1  -   J4.40     <----   RTS UARTtoUSB bridge (TERMINAL5WIRES)
 144 ;               P2.3  -   SW2
 145 ;               P2.5  -   J2.10     <----   SD_CD (Card Detect)
 146
 147             BIS #-1,&PAREN      ; all inputs with pull up/down resistors
 148             MOV #0FFFEh,&PAOUT  ; all pins with pullup resistors else LED1
 149
 150     .IFDEF TERMINAL4WIRES
 151 ; RTS output is wired to the CTS input of UART2USB bridge
 152 ; configure RTS as output high (false) to disable RX TERM during start FORTH
 153 HANDSHAKOUT .equ    P2OUT
 154 HANDSHAKIN  .equ    P2IN
 155 RTS         .equ    1           ; P2.0
 156             BIS.B #RTS,&P2DIR   ; RTS as output high
 157         .IFDEF TERMINAL5WIRES
 158 ; CTS input must be wired to the RTS output of UART2USB bridge
 159 ; configure CTS as input low (true) to avoid lock when CTS is not wired
 160 CTS         .equ    2           ; P2.1
 161             BIC.B #CTS,&P2OUT   ; CTS input resistor is pulled down
 162         .ENDIF  ; TERMINAL5WIRES
 163     .ENDIF  ; TERMINAL4WIRES
 164
 165
 166 SW2_IN      .equ P2IN
 167 SW2         .equ 8              ; P2.3 = S2
 168
 169 SD_CDIN     .equ  P2IN
 170 CD_SD       .equ  20h           ; P2.5
 171
 172 ; ----------------------------------------------------------------------
 173 ; POWER ON RESET AND INITIALIZATION : PORT3-4
 174 ; ----------------------------------------------------------------------
 175
 176 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 177
 178 ; PORTB usage
 179
 180 ;               P4.1    -   SW1
 181 ; UCA1 RXD      P4.2    -   J101.8  <----   TX  UARTtoUSB bridge
 182 ; UCA1 TXD      P4.3    -   J101.6  ---->   RX  UARTtoUSB bridge
 183 ;               P4.4    -   J2.9    ---->   SD_CS(Card Select)
 184 ; UCB1 CLK      P4.5    -   J1.7    ---->   SD_CLK
 185 ; UCB1 SIMO     P4.6    -   J2.15   ---->   SD_SDI
 186 ; UCB1 SOMI     P4.7    -   J2.14   <----   SD_SDO
 187
 188             BIS #-1,&PBREN  ; all pins with pull resistors
 189             MOV #-1,&PBOUT  ; pullup resistors for all pins
 190
 191 SW1_IN      .equ P4IN
 192 SW1         .equ 2      ; P4.1 = S1
 193
 194 WIPE_IN     .equ P4IN
 195 IO_WIPE     .equ 2      ; P4.1 = S1 = FORTH Deep_RST pin
 196
 197     .IFDEF UCA1_TERM
 198 ; UCA1 RXD      P4.2    -   J101.8  <----   TX  UARTtoUSB bridge
 199 ; UCA1 TXD      P4.3    -   J101.6  ---->   RX  UARTtoUSB bridge
 200 TERM_IN     .equ P4IN
 201 TERM_REN    .equ P4REN
 202 TERM_SEL    .equ P4SEL0
 203 RXD         .equ 4      ; P4.2 = RXD
 204 TXD         .equ 8      ; P4.3 = TXD
 205 BUS_TERM    .equ 0Ch
 206     .ENDIF
 207
 208     .IFDEF UCB1_SD
 209 SD_CSOUT    .equ P4OUT
 210 SD_CSDIR    .equ P4DIR
 211 CS_SD       .equ 10h    ; P4.4
 212
 213 SD_SEL      .equ PBSEL0 ; to configure UCB1
 214 SD_REN      .equ PBREN  ; to configure pullup resistors
 215 BUS_SD      .equ 0E000h ; pins P4.5 as UCA1CLK, P4.6 as UCA1SIMO & P4.7 as UCA1SOMI
 216     .ENDIF
 217 ; ----------------------------------------------------------------------
 218 ; POWER ON RESET AND INITIALIZATION : PORT5-6
 219 ; ----------------------------------------------------------------------
 220
 221 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 222
 223 ; PORT6 usage
 224 LED2_OUT    .equ    P6OUT
 225 LED2_DIR    .equ    P6DIR
 226 LED2        .equ    40h         ;  P6.6 LED2 green
 227
 228             BIS.B #-1,&P6REN    ; all pins with pull up/down resistors
 229             MOV.B #0BFh,&P6OUT  ; all pins with pull up resistors else P6.6
 230
 231 ; ----------------------------------------------------------------------
 232 ; FRAM config
 233 ; ----------------------------------------------------------------------
 234
 235     .IF (FREQUENCY >8 ) && ( FREQUENCY <= 16)
 236             MOV.B   #0A5h, &FRCTL0_H     ; enable FRCTL0 access
 237             MOV.B   #10h, &FRCTL0         ; 1 waitstate @ 16 MHz
 238             MOV.B   #01h, &FRCTL0_H       ; disable FRCTL0 access
 239     .ELSEIF FREQUENCY > 16
 240             MOV.B   #0A5h, &FRCTL0_H     ; enable FRCTL0 access
 241             MOV.B   #20h, &FRCTL0         ; 2 waitstate @ 24 MHz
 242             MOV.B   #01h, &FRCTL0_H       ; disable FRCTL0 access
 243     .ENDIF
 244
 245 ; ----------------------------------------------------------------------
 246 ; POWER ON RESET SYS config
 247 ; ----------------------------------------------------------------------
 248
 249     MOV #0A500h,&SYSCFG0    ; enable write MAIN + INFO
 250
 251 ; ----------------------------------------------------------------------
 252 ; POWER ON RESET AND INITIALIZATION : CLOCK SYSTEM
 253 ; ----------------------------------------------------------------------
 254
 255 ; CS code for MSP430FR2355
 256
 257 ; to measure SMCLK frequency, wires SMCLK on P1.0:
 258 ;    BIS.B #1,&P1SEL1
 259 ;    BIS.B #1,&P1DIR
 260
 261 ; to measure REFO frequency, wires ACLK on P1.1:
 262 ;    BIS.B #2,&P1SEL1
 263 ;    BIS.B #2,&P1DIR
 264
 265     .IF FREQUENCY = 0.5
 266
 267             MOV     #1ED1h,&CSCTL0       ; preset MOD=31, DCO = measured value @ 0x180 (209)
 268             MOV     #00B0h,&CSCTL1      ; Set 1MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 269 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 270 ;            MOV     #100Dh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Dh
 271                                         ; fCOCLKDIV = 32768 x (13+1) = 0.459 MHz ; measured :  MHz
 272             MOV     #100Eh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Eh
 273                                         ; fCOCLKDIV = 32768 x (14+1) = 0.491 MHz ; measured :  MHz
 274 ;            MOV     #100Fh,&CSCTL2      ; Set FLLD=1 (DCOCLKCDIV=DCO/2),set FLLN=0Fh
 275                                         ; fCOCLKDIV = 32768 x (15+1) = 0.524 MHz ; measured :  MHz
 276 ; =====================================
 277             MOV     #8,X
 278
 279     .ELSEIF FREQUENCY = 1
 280
 281             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 282             MOV     #00B0h,&CSCTL1      ; Set 1MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 283 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 284 ;            MOV     #001Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Dh
 285                                         ; fCOCLKDIV = 32768 x (29+1) = 0.983 MHz ; measured : 0.989MHz
 286             MOV     #001Eh,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Eh
 287                                         ; fCOCLKDIV = 32768 x (30+1) = 1.015 MHz ; measured : 1.013MHz
 288 ;            MOV     #001Fh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1Fh
 289                                         ; fCOCLKDIV = 32768 x (31+1) = 1.049 MHz ; measured : 1.046MHz
 290 ; =====================================
 291             MOV     #16,X
 292
 293     .ELSEIF FREQUENCY = 2
 294
 295             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 296             MOV     #00B2h,&CSCTL1      ; Set 2MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 297 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 298 ;            MOV     #003Bh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Bh
 299                                         ; fCOCLKDIV = 32768 x (59+1) = 1.966 MHz ; measured :  MHz
 300             MOV     #003Ch,&CSCTL2         ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Ch
 301                                         ; fCOCLKDIV = 32768 x (60+1) = 1.998 MHz ; measured :  MHz
 302 ;            MOV     #003Dh,&CSCTL2        ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=3Dh
 303                                         ; fCOCLKDIV = 32768 x (61+1) = 2.031 MHz ; measured :  MHz
 304 ; =====================================
 305             MOV     #32,X
 306
 307     .ELSEIF FREQUENCY = 4
 308
 309             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 310             MOV     #00B4h,&CSCTL1      ; Set 4MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 311 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 312 ;            MOV     #0078h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=78h
 313                                         ; fCOCLKDIV = 32768 x (120+1) = 3.965 MHz ; measured : 3.96MHz
 314
 315             MOV     #0079h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=79h
 316                                         ; fCOCLKDIV = 32768 x (121+1) = 3.997 MHz ; measured : 3.99MHz
 317
 318 ;            MOV     #007Ah,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=7Ah
 319                                         ; fCOCLKDIV = 32768 x (122+1) = 4.030 MHz ; measured : 4.020MHz
 320 ; =====================================
 321             MOV     #64,X
 322
 323     .ELSEIF FREQUENCY = 8
 324
 325             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 326             MOV     #00B6h,&CSCTL1      ; Set 8MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 327 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 328             MOV     #00F3h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F3h
 329                                         ; fCOCLKDIV = 32768 x (243+1) = 7.995 MHz ; measured : 7.976MHz
 330 ;            MOV     #00F4h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F4h
 331                                         ; fCOCLKDIV = 32768 x (244+1) = 8.028 MHz ; measured : 8.009MHz
 332
 333 ;            MOV     #00F5h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=F5h
 334                                         ; fCOCLKDIV = 32768 x (245+1) = 8.061 MHz ; measured : 8.042MHz
 335 ; =====================================
 336             MOV     #128,X
 337
 338     .ELSEIF FREQUENCY = 12
 339
 340             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 341             MOV     #00B8h,&CSCTL1      ; Set 12MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 342 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 343             MOV     #016Dh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E7h
 344                                         ; fCOCLKDIV = 32768 x 365+1) = 11.993 MHz ; measured : 11.xxxMHz
 345 ;            MOV     #016Eh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E8h
 346                                         ; fCOCLKDIV = 32768 x 366+1) = 12.025 MHz ; measured : 12.xxxMHz
 347 ;            MOV     #016Fh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E9h
 348                                         ; fCOCLKDIV = 32768 x 367+1) = 12.058 MHz ; measured : 12.xxxMHz
 349 ; =====================================
 350             MOV     #192,X
 351
 352     .ELSEIF FREQUENCY = 16
 353
 354             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 355             MOV     #00BAh,&CSCTL1      ; Set 16MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 356 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 357 ;            MOV     #01E7h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E7h
 358                                         ; fCOCLKDIV = 32768 x 487+1) = 15.991 MHz ; measured : 15.95MHz
 359             MOV     #01E8h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E8h
 360                                         ; fCOCLKDIV = 32768 x 488+1) = 16.023 MHz ; measured : 15.99MHz
 361 ;            MOV     #01E9h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=1E9h
 362                                         ; fCOCLKDIV = 32768 x 489+1) = 16.056 MHz ; measured : 16.02MHz
 363 ; =====================================
 364             MOV     #256,X
 365
 366     .ELSEIF FREQUENCY = 20
 367
 368             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 369             MOV     #00BCh,&CSCTL1      ; Set 20MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 370 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 371 ;            MOV     #0261h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=261h
 372                                         ; fCOCLKDIV = 32768 x 609+1) = 19.988 MHz ; measured : 19.xxxMHz
 373             MOV     #0262h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=262h
 374                                         ; fCOCLKDIV = 32768 x 610+1) = 20.021 MHz ; measured : 20.xxxMHz
 375 ;            MOV     #0263h,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=263h
 376                                         ; fCOCLKDIV = 32768 x 611+1) = 20.054 MHz ; measured : 20.xxxMHz
 377 ; =====================================
 378             MOV     #320,X
 379
 380     .ELSEIF FREQUENCY = 24
 381
 382             MOV     #1EFFh,&CSCTL0       ; preset MOD=31, DCO=255
 383             MOV     #00BEh,&CSCTL1      ; Set 24MHZ DCORSEL,enable DCOFTRIM=3h ,enable Modulation to reduce EMI
 384 ; ===================================== ;  fCOCLKDIV = REFO x (FLLN+1)
 385 ;            MOV     #02DBh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DBh
 386                                         ; fCOCLKDIV = 32768 x 731+1) = 23.986 MHz ; measured : 23.xxxMHz
 387             MOV     #02DCh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DCh
 388                                         ; fCOCLKDIV = 32768 x 732+1) = 24.019 MHz ; measured : 23.xxxMHz
 389 ;            MOV     #02DDh,&CSCTL2      ; Set FLLD=0 (DCOCLKCDIV=DCO),set FLLN=2DDh
 390                                         ; fCOCLKDIV = 32768 x 733+1) = 24.051 MHz ; measured : 24.xxxMHz
 391 ; =====================================
 392             MOV     #384,X
 393
 394     .ELSEIF
 395     .error "bad frequency setting, only 0.5,1,2,4,8,12,16,20,24 MHz"
 396     .ENDIF
 397
 398     .IFDEF LF_XTAL
 399 ;           MOV     #0000h,&CSCTL3      ; FLL select XT1, FLLREFDIV=0 (default value)
 400             MOV     #0000h,&CSCTL4      ; ACLOCK select XT1, MCLK & SMCLK select DCOCLKDIV
 401 ;            BIC.B   #1,&CSCTL6          ; disable XT1AUTOOFF
 402
 403             BIS.B   #0C0h,&P2SEL1       ; P2.6 as XOUT, P2.7 as XIN
 404
 405     .ELSE
 406             BIS     #0010h,&CSCTL3      ; FLL select REFCLOCK
 407 ;           MOV     #0100h,&CSCTL4      ; ACLOCK select REFO, MCLK & SMCLK select DCOCLKDIV (default value)
 408     .ENDIF
 409
 410
 411             BIS &SYSRSTIV,&SAVE_SYSRSTIV; store volatile SYSRSTIV preserving a pending request for DEEP_RST
 412 ;            MOV &SAVE_SYSRSTIV,TOS  ;
 413 ;            CMP #2,TOS              ; POWER ON ?
 414 ;            JZ      ClockWaitX      ; yes
 415 ;            RRUM    #1,X            ; wait only 250 ms
 416 ClockWaitX  MOV     #5209,Y         ; wait 0.5s before starting after POR
 417                                     ;       ...because FLL lock time = 280 ms
 418 ClockWaitY  SUB     #1,Y            ;1
 419             JNZ     ClockWaitY      ;2 5209x3 = 15625 cycles delay = 15.625ms @ 1MHz
 420             SUB     #1,X            ; x 32 @ 1 MHZ = 500ms
 421             JNZ     ClockWaitX      ; time to stabilize power source ( 500ms )
 422
 423 ;WAITFLL     BIT #300h,&CSCTL7       ; wait FLL lock
 424 ;            JNZ WAITFLL
 425