putty/UNIX/CONFIGUR.AC

   1 # To compile this into a configure script, you need:\r
   2 # * Autoconf 2.50 or newer\r
   3 # * Gtk (for $prefix/share/aclocal/gtk.m4)\r
   4 # * Automake (for aclocal)\r
   5 # If you've got them, running "autoreconf" should work.\r
   6 \r
   7 AC_INIT\r
   8 AC_CONFIG_FILES([Makefile])\r
   9 AC_CONFIG_HEADERS([uxconfig.h:uxconfig.in])\r
  10 \r
  11 AC_PROG_INSTALL\r
  12 AC_PROG_CC\r
  13 if test "X$GCC" = Xyes; then\r
  14     PUTTYCFLAGS="-Wall -Werror"\r
  15 else\r
  16     PUTTYCFLAGS=""\r
  17 fi\r
  18 AC_SUBST(PUTTYCFLAGS)\r
  19 \r
  20 AC_ARG_WITH([gssapi],\r
  21   [AS_HELP_STRING([--without-gssapi],\r
  22                   [disable GSSAPI support])],\r
  23   [],\r
  24   [with_gssapi=yes])\r
  25 \r
  26 WITH_GSSAPI=\r
  27 AS_IF([test "x$with_gssapi" != xno],\r
  28   [AC_DEFINE([WITH_GSSAPI], [1], [Define if building with GSSAPI support.])])\r
  29 \r
  30 AC_CHECK_HEADERS([utmpx.h sys/select.h],,,[\r
  31 #include <sys/types.h>\r
  32 #include <utmp.h>])\r
  33 \r
  34 # Look for both GTK 1 and GTK 2.\r
  35 AM_PATH_GTK([1.2.0], [gtk=1], [gtk=none])\r
  36 AM_PATH_GTK_2_0([2.0.0], [gtk=2], [])\r
  37 if test "$gtk" = "none"; then\r
  38   all_targets="all-cli"\r
  39 else\r
  40   all_targets="all-cli all-gtk"\r
  41 fi\r
  42 if test "$gtk" = "2"; then\r
  43   ac_save_CFLAGS="$CFLAGS"\r
  44   ac_save_LIBS="$LIBS"\r
  45   CFLAGS="$CFLAGS $GTK_CFLAGS"\r
  46   LIBS="$GTK_LIBS $LIBS"\r
  47   AC_CHECK_FUNCS([pango_font_family_is_monospace pango_font_map_list_families])\r
  48   CFLAGS="$ac_save_CFLAGS"\r
  49   LIBS="$ac_save_LIBS"\r
  50 fi\r
  51 AC_SUBST([all_targets])\r
  52 \r
  53 AC_SEARCH_LIBS([socket], [xnet])\r
  54 \r
  55 AS_IF([test "x$with_gssapi" != xno],\r
  56   [AC_SEARCH_LIBS(\r
  57     [dlopen],[dl],\r
  58     [],\r
  59     [AC_DEFINE([NO_LIBDL], [1], [Define if we could not find libdl.])\r
  60      AC_CHECK_HEADERS([gssapi/gssapi.h])\r
  61      AC_SEARCH_LIBS(\r
  62        [gss_init_sec_context],[gssapi gssapi_krb5 gss],\r
  63        [],\r
  64        [AC_DEFINE([NO_GSSAPI_LIB], [1], [Define if we could not find a gssapi library])])])])\r
  65 \r
  66 AC_CHECK_LIB(X11, XOpenDisplay)\r
  67 \r
  68 AC_CHECK_FUNCS([getaddrinfo ptsname setresuid strsignal updwtmpx])\r
  69 \r
  70 AC_OUTPUT\r
  71 \r
  72 AH_BOTTOM([\r
  73 /* Convert autoconf definitions to ones that PuTTY wants. */\r
  74 \r
  75 #ifndef HAVE_GETADDRINFO\r
  76 # define NO_IPV6\r
  77 #endif\r
  78 #ifndef HAVE_SETRESUID\r
  79 # define HAVE_NO_SETRESUID\r
  80 #endif\r
  81 #ifndef HAVE_STRSIGNAL\r
  82 # define HAVE_NO_STRSIGNAL\r
  83 #endif\r
  84 #if !defined(HAVE_UTMPX_H) || !defined(HAVE_UPDWTMPX)\r
  85 # define OMIT_UTMP\r
  86 #endif\r
  87 #ifndef HAVE_PTSNAME\r
  88 # define BSD_PTYS\r
  89 #endif\r
  90 #ifndef HAVE_SYS_SELECT_H\r
  91 # define HAVE_NO_SYS_SELECT_H\r
  92 #endif\r
  93 #ifndef HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE\r
  94 # define PANGO_PRE_1POINT4\r
  95 #endif\r
  96 #ifndef HAVE_PANGO_FONT_MAP_LIST_FAMILIES\r
  97 # define PANGO_PRE_1POINT6\r
  98 #endif\r
  99 #if !defined(WITH_GSSAPI)\r
 100 # define NO_GSSAPI\r
 101 #endif\r
 102 #if !defined(NO_GSSAPI) && defined(NO_LIBDL)\r
 103 # if !defined(HAVE_GSSAPI_GSSAPI_H) || defined(NO_GSSAPI_LIB)\r
 104 #  define NO_GSSAPI\r
 105 # endif\r
 106 #endif\r
 107 ])\r