bionic/libc/arch-sh/bionic/ffs.S

   1 /*      $NetBSD: ffs.S,v 1.1 2005/12/20 19:28:50 christos Exp $ */
   2
   3 /*-
   4  * Copyright (c) 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by ITOH Yasufumi.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. All advertising materials mentioning features or use of this software
  19  *    must display the following acknowledgement:
  20  *      This product includes software developed by the NetBSD
  21  *      Foundation, Inc. and its contributors.
  22  * 4. Neither the name of The NetBSD Foundation nor the names of its
  23  *    contributors may be used to endorse or promote products derived
  24  *    from this software without specific prior written permission.
  25  *
  26  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  27  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  28  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  29  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  30  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  31  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  32  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  33  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  34  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  35  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  36  * POSSIBILITY OF SUCH DAMAGE.
  37  */
  38
  39 #include <machine/asm.h>
  40
  41 #if defined(LIBC_SCCS) && !defined(lint)
  42         RCSID("$NetBSD: ffs.S,v 1.1 2005/12/20 19:28:50 christos Exp $")
  43 #endif
  44
  45 /*
  46  * ffs - find first bit set
  47  *
  48  * This code makes use of ``test 8bit'' and ``shift 8bit'' instructions.
  49  * The remaining 8bit is tested in every 2bit.
  50  */
  51
  52 ENTRY(ffs)
  53         mov     r4,r0           ! using r0 specific instructions
  54         tst     #0xff,r0
  55         bf/s    L8bit
  56         mov     #0+1,r1         ! ret = 1..8
  57
  58         tst     r0,r0           ! ffs(0) is 0
  59         bt      Lzero           ! testing here to accelerate ret=1..8 cases
  60
  61         shlr8   r0
  62         tst     #0xff,r0
  63         bf/s    L8bit
  64         mov     #8+1,r1         ! ret = 9..16
  65
  66         shlr8   r0
  67         tst     #0xff,r0
  68         bf/s    L8bit
  69         mov     #16+1,r1        ! ret = 17..24
  70
  71         shlr8   r0
  72         mov     #24+1,r1        ! ret = 25..32
  73
  74 L8bit:
  75         tst     #0x0f,r0
  76         bt      4f
  77
  78         tst     #0x03,r0
  79         bt      2f
  80         tst     #0x01,r0        ! not bit 0 -> T
  81         mov     #0,r0
  82         rts
  83          addc   r1,r0           ! 0 + r1 + T -> r0
  84
  85 2:      tst     #0x04,r0
  86         mov     #2,r0
  87         rts
  88          addc   r1,r0
  89
  90 4:      tst     #0x30,r0
  91         bt      6f
  92         tst     #0x10,r0
  93         mov     #4,r0
  94         rts
  95          addc   r1,r0
  96
  97 6:      tst     #0x40,r0
  98         mov     #6,r0
  99         rts
 100          addc   r1,r0
 101
 102 Lzero:  rts
 103          nop