configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(hengband, 3.0.0.0)
   3
   4 AC_CONFIG_HEADERS(src/autoconf.h)
   5 AC_CONFIG_SRCDIR(src/main.c)
   6 AM_INIT_AUTOMAKE
   7
   8 AC_ARG_WITH(setgid,
   9 [  --with-setgid=NAME      install hengband as group NAME],
  10 [case "${withval}" in
  11   no) GAMEGROUP="";;
  12   yes) AC_MSG_ERROR(missing argument for --with-setgid);;
  13   *) GAMEGROUP="$withval";;
  14 esac])
  15 AC_SUBST(GAMEGROUP)
  16 AM_CONDITIONAL(SET_GID, test "$GAMEGROUP" != "")
  17
  18 AC_LANG_C
  19
  20 dnl generate the installation path for the ./lib/ folder
  21 if test "$GAMEGROUP" != ""; then
  22   MY_EXPAND_DIR(game_libpath, "$datadir/games/$PACKAGE/lib/")
  23 else
  24   MY_EXPAND_DIR(game_libpath, "./lib/")
  25   bindir=".."
  26 fi
  27
  28 dnl overwrite the path with an user-specified value
  29 AC_ARG_WITH(libpath,
  30 [  --with-libpath=path     specify the path to the Hengband lib folder],
  31 [game_libpath="$withval"])
  32
  33 AC_ARG_WITH(varpath,
  34 [  --with-varpath=path     specify the path to the Hengband var folder],
  35 [game_varpath="$withval"],
  36 [game_varpath="$game_libpath"])
  37
  38 AC_DEFINE_UNQUOTED(DEFAULT_LIB_PATH, "$game_libpath", [Path to the Hengband lib folder])
  39 DEFAULT_LIB_PATH="$game_libpath"
  40 AC_SUBST(DEFAULT_LIB_PATH)
  41
  42 AC_DEFINE_UNQUOTED(DEFAULT_VAR_PATH, "$game_varpath", [Path to the Hengband var folder])
  43 DEFAULT_VAR_PATH="$game_varpath"
  44 AC_SUBST(DEFAULT_VAR_PATH)
  45
  46 dnl Checks for programs.
  47 AC_PROG_CC
  48
  49 AC_ARG_ENABLE(japanese,
  50 [  --disable-japanese      build english version], use_japanese=no, [AC_DEFINE(JP, 1, [Enable Japanese]) AC_DEFINE(EUC, 1, [Use Extended Unix Code])])
  51
  52 AC_ARG_ENABLE(xim,
  53 [  --disable-xim           disable xim support], use_xim=no, use_xim=yes)
  54 AC_ARG_ENABLE(fontset,
  55 [  --disable-fontset       disable fontset support], use_fontset=no, use_fontset=yes)
  56 AC_ARG_ENABLE([xft],
  57         AS_HELP_STRING([--enable-xft], [Enable xft support]))
  58 AC_ARG_ENABLE(worldscore,
  59 [  --disable-worldscore    disable worldscore support], worldscore=no, AC_DEFINE(WORLD_SCORE, 1, [Allow the game to send scores to the score server]))
  60 AC_ARG_ENABLE(chuukei,
  61 [  --enable-chuukei        enable internet chuukei support], AC_DEFINE(CHUUKEI, 1, [Chuukei mode]))
  62
  63 dnl Checks for libraries.
  64 dnl Replace `main' with a function in -lncurses:
  65 AC_CHECK_LIB(ncursesw, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncursesw"])
  66 if test "$ac_cv_lib_ncursesw_initscr" != yes; then
  67   AC_CHECK_LIB(ncurses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncurses"])
  68   if test "$ac_cv_lib_ncurses_initscr" != yes; then
  69     AC_CHECK_LIB(curses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) LIBS="$LIBS -lcurses"])
  70     if test "$ac_cv_lib_curses_initscr" != yes; then
  71       AC_CHECK_LIB(termcap, tgetent, [AC_DEFINE(USE_CAP, 1, [Allow -mCAP environment]) LIBS="$LIBS -ltermcap"])
  72     fi
  73   fi
  74 fi
  75
  76 AC_CHECK_LIB(iconv, iconv_open)
  77
  78 AC_CHECK_FILE(/dev/urandom, AC_DEFINE(RNG_DEVICE, "/dev/urandom", [Random Number Generation device file]))
  79
  80 if test "$worldscore" != no; then
  81   PKG_CHECK_MODULES(libcurl, [libcurl])
  82 fi
  83
  84 dnl Checks for header files.
  85 AC_PATH_XTRA
  86 if test "$have_x" = yes; then
  87   LIBS="$LIBS -lX11"
  88   AC_DEFINE(USE_X11, 1, [Allow -mX11 environment])
  89   CFLAGS="$X_CFLAGS $CFLAGS"
  90   LDFLAGS="$X_LIBS $LDFLAGS"
  91
  92   if test "$use_fontset" = yes; then
  93     AC_DEFINE(USE_FONTSET, 1, [Use FontSet])
  94   else
  95     if test "$use_japanese" != no; then
  96       AC_DEFINE(USE_JP_FONTSTRUCT, 1, [Use Kanji without FontSet])
  97     fi
  98   fi
  99
 100   if test "$use_xim" = yes; then
 101     AC_DEFINE(USE_XIM, 1, [Use X Imput Method])
 102   fi
 103
 104   if test "$use_fontset" = yes || test "$use_xim" = yes; then
 105     AC_DEFINE(USE_LOCALE, 1, [Support Locale])
 106     if test "$use_japanese" != no; then
 107       AC_DEFINE(DEFAULT_LOCALE, "ja_JP.eucJP", Default Japanese Locale)
 108     fi
 109     AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE, 1, [Use XLocale]))
 110     AC_CHECK_LIB(xpg4, setlocale, LIBS="$LIBS -lxpg4")
 111   fi
 112
 113   AS_IF([test "x$enable_xft" = "xyes"], [
 114     PKG_CHECK_MODULES(XFT, [xft],
 115       [AC_DEFINE([USE_XFT], [1], [Use XFT])])
 116   ])
 117 fi
 118
 119 if test "$use_japanese" != no; then
 120   AC_CHECK_PROG(NKF, nkf, yes)
 121   if test x"$NKF" != x"yes"; then
 122     AC_MSG_ERROR([nkf is not found. Please install nkf.])
 123   fi
 124 fi
 125
 126 AC_HEADER_STDC
 127 AC_CHECK_HEADERS(fcntl.h strings.h sys/file.h sys/ioctl.h sys/time.h termio.h unistd.h stdint.h)
 128
 129 dnl Checks for typedefs, structures, and compiler characteristics.
 130 AC_C_CONST
 131 AC_TYPE_PID_T
 132 AC_TYPE_SIZE_T
 133 AC_HEADER_TIME
 134 AC_STRUCT_TM
 135
 136 dnl Checks for library functions.
 137 AC_PROG_GCC_TRADITIONAL
 138 AC_FUNC_MEMCMP
 139 AC_TYPE_SIGNAL
 140 AC_FUNC_STRFTIME
 141 AC_FUNC_VPRINTF
 142 AC_CHECK_FUNCS(gethostname mkdir select socket strtol vsnprintf mkstemp usleep)
 143
 144 AC_OUTPUT(Makefile src/Makefile lib/Makefile lib/apex/Makefile lib/bone/Makefile lib/data/Makefile lib/edit/Makefile lib/file/Makefile lib/help/Makefile lib/info/Makefile lib/pref/Makefile lib/save/Makefile lib/script/Makefile lib/user/Makefile lib/xtra/Makefile lib/xtra/font/Makefile lib/xtra/graf/Makefile lib/xtra/music/Makefile lib/xtra/sound/Makefile)