configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(hengband, 3.0.1.2-Beta)
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5 AC_CONFIG_HEADERS(src/autoconf.h)
   6 AC_CONFIG_SRCDIR(src/main.cpp)
   7 AM_INIT_AUTOMAKE
   8
   9 AC_ARG_WITH(setgid,
  10 [  --with-setgid=NAME      install hengband as group NAME],
  11 [case "${withval}" in
  12   no) GAMEGROUP="";;
  13   yes) AC_MSG_ERROR(missing argument for --with-setgid);;
  14   *) GAMEGROUP="$withval";;
  15 esac])
  16 AC_SUBST(GAMEGROUP)
  17 AM_CONDITIONAL(SET_GID, test "$GAMEGROUP" != "")
  18
  19 dnl generate the installation path for the ./lib/ folder
  20 if test "$GAMEGROUP" != ""; then
  21   MY_EXPAND_DIR(game_libpath, "$datarootdir/games/$PACKAGE/lib/")
  22 else
  23   MY_EXPAND_DIR(game_libpath, "./lib/")
  24   bindir="`pwd`"
  25 fi
  26
  27 dnl overwrite the path with an user-specified value
  28 AC_ARG_WITH(libpath,
  29 [  --with-libpath=path     specify the path to the Hengband lib folder],
  30 [game_libpath="$withval"])
  31
  32 AC_ARG_WITH(varpath,
  33 [  --with-varpath=path     specify the path to the Hengband var folder],
  34 [game_varpath="$withval"],
  35 [game_varpath="$game_libpath"])
  36
  37 AC_DEFINE_UNQUOTED(DEFAULT_LIB_PATH, "$game_libpath", [Path to the Hengband lib folder])
  38 DEFAULT_LIB_PATH="$game_libpath"
  39 AC_SUBST(DEFAULT_LIB_PATH)
  40
  41 AC_DEFINE_UNQUOTED(DEFAULT_VAR_PATH, "$game_varpath", [Path to the Hengband var folder])
  42 DEFAULT_VAR_PATH="$game_varpath"
  43 AC_SUBST(DEFAULT_VAR_PATH)
  44
  45 dnl Checks for programs.
  46 AC_LANG(C++)
  47 AC_PROG_CXX
  48 dnl Note that the -std= option for Objective-C++ is hardwired in
  49 dnl src/Makefile.am so that should be changed if this is.
  50 AX_CXX_COMPILE_STDCXX(20, [ext], [mandatory])
  51 PKG_PROG_PKG_CONFIG
  52
  53 AC_ARG_ENABLE(japanese,
  54 [  --disable-japanese      build english version], use_japanese=no, [AC_DEFINE(JP, 1, [Enable Japanese]) AC_DEFINE(EUC, 1, [Use Extended Unix Code])])
  55
  56 AC_ARG_ENABLE(xim,
  57 [  --disable-xim           disable xim support], use_xim=no, use_xim=yes)
  58 AC_ARG_ENABLE(fontset,
  59 [  --disable-fontset       disable fontset support], use_fontset=no, use_fontset=yes)
  60 AC_ARG_ENABLE([xft],
  61         AS_HELP_STRING([--enable-xft], [Enable xft support]))
  62 AC_ARG_ENABLE(net,
  63 [  --disable-net           disable networking support], use_net=no)
  64 AC_ARG_ENABLE(worldscore,
  65 [  --disable-worldscore    disable worldscore support], worldscore=no)
  66 AC_ARG_ENABLE([pch],
  67 [  --disable-pch           disable use of precompiled headers],
  68 enable_pch=no, enable_pch=yes)
  69 AM_CONDITIONAL([PCH], [test x$enable_pch = xyes])
  70 AC_ARG_ENABLE([cocoa],
  71 [  --enable-cocoa          enable a Cocoa user interface (OS X only)],
  72 [AC_DEFINE([MACH_O_COCOA], [1], [Use a Cocoa interface (OS X only)])], [])
  73 AM_CONDITIONAL([COCOA], [test x$enable_cocoa = xyes])
  74 dnl Since AC_PROG_OBJCXX has the side effect of setting this conditional,
  75 dnl guarantee that is is always set, regardless of what happens in the if
  76 dnl statement.
  77 AM_CONDITIONAL([am__fastdepOBJCXX], false)
  78 if test x"$enable_cocoa" = xyes ; then
  79   dnl Use AC_LANG_PUSH and AC_LANG_POP to try to get back to the state that
  80   dnl AC_LANG_C set in case there are side effects.
  81   AC_LANG_PUSH([Objective C++])
  82   AC_PROG_OBJCXX
  83   AC_LANG_POP([Objective C++])
  84   AC_DEFINE(SAFE_DIRECTORY, 1, [Mark var directory with version string])
  85   AC_DEFINE(VERSION_STRING, "3.0.0", [Version string to use for var directory])
  86 fi
  87
  88 dnl Checks for libraries.
  89 dnl Replace `main' with a function in -lncurses:
  90 if test x"$enable_cocoa" != xyes ; then
  91   AC_CHECK_LIB(ncursesw, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncursesw"])
  92   if test "$ac_cv_lib_ncursesw_initscr" != yes; then
  93     AC_CHECK_LIB(ncurses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) AC_DEFINE(USE_NCURSES, 1, [Use ncurses]) LIBS="$LIBS -lncurses"])
  94     if test "$ac_cv_lib_ncurses_initscr" != yes; then
  95       AC_CHECK_LIB(curses, initscr, [AC_DEFINE(USE_GCU, 1, [Allow -mGCU environment]) LIBS="$LIBS -lcurses"])
  96       if test "$ac_cv_lib_curses_initscr" != yes; then
  97         AC_CHECK_LIB(termcap, tgetent, [AC_DEFINE(USE_CAP, 1, [Allow -mCAP environment]) LIBS="$LIBS -ltermcap"])
  98       fi
  99     fi
 100   fi
 101 fi
 102
 103 AC_CHECK_LIB(iconv, iconv_open)
 104
 105 if test "$use_net" = no; then
 106   AC_DEFINE(DISABLE_NET, 1, [Disable networking support])
 107   worldscore=no;
 108 else
 109   PKG_CHECK_MODULES(libcurl, [libcurl], , [AC_CHECK_LIB([curl], [curl_global_init], [libcurl_LIBS=-lcurl], [AC_MSG_ERROR([Could not find libcurl for networking support])])])
 110 fi
 111
 112 dnl The world score server is currently only available in Japanese.
 113 if test "$use_japanese" = no; then
 114   worldscore=no
 115 fi
 116 if test "$worldscore" != no; then
 117   AC_DEFINE(WORLD_SCORE, 1, [Allow the game to send scores to the score server])
 118 fi
 119
 120 dnl Checks for header files.
 121 dnl AC_PATH_XTRA has side effects on CPP which are beneficial on Mac OS X.
 122 dnl Removing it or conditionally executing it will likely lead to warnings
 123 dnl on that platform about the preprocessor disagreeing with the compiler on
 124 dnl the tests in AC_CHECK_HEADERS.
 125 AC_PATH_XTRA
 126 AS_IF([test "$have_x" = yes && test x"$enable_cocoa" != xyes], [
 127   LIBS="$LIBS -lX11"
 128   AC_DEFINE(USE_X11, 1, [Allow -mX11 environment])
 129   CXXFLAGS="$X_CFLAGS $CXXFLAGS"
 130   LDFLAGS="$X_LIBS $LDFLAGS"
 131
 132   if test "$use_fontset" = yes; then
 133     AC_DEFINE(USE_FONTSET, 1, [Use FontSet])
 134   else
 135     if test "$use_japanese" != no; then
 136       AC_DEFINE(USE_JP_FONTSTRUCT, 1, [Use Kanji without FontSet])
 137     fi
 138   fi
 139
 140   if test "$use_xim" = yes; then
 141     AC_DEFINE(USE_XIM, 1, [Use X Imput Method])
 142   fi
 143
 144   if test "$use_fontset" = yes || test "$use_xim" = yes; then
 145     AC_DEFINE(USE_LOCALE, 1, [Support Locale])
 146     if test "$use_japanese" != no; then
 147       AC_DEFINE(DEFAULT_LOCALE, "ja_JP.eucJP", Default Japanese Locale)
 148     fi
 149     AC_CHECK_LIB(X11, _Xsetlocale, AC_DEFINE(X_LOCALE, 1, [Use XLocale]))
 150     AC_CHECK_LIB(xpg4, setlocale, LIBS="$LIBS -lxpg4")
 151   fi
 152
 153   AS_IF([test "x$enable_xft" = "xyes"], [
 154     PKG_CHECK_MODULES(XFT, [xft],
 155       [AC_DEFINE([USE_XFT], [1], [Use XFT])])
 156   ])
 157 ])
 158
 159 if test "$use_japanese" != no; then
 160   AC_CHECK_PROG(NKF, nkf, yes)
 161   if test x"$NKF" != x"yes"; then
 162     AC_MSG_ERROR([nkf is not found. Please install nkf.])
 163   fi
 164 fi
 165
 166 if test "$enable_pch" != no; then
 167   dnl md5sum, sha224sum, sha256sum, sha384sum, sha512sum and b2sum are
 168   dnl frequently available on Linux.  md5 is available on macOS and OpenBSD.
 169   dnl sha1, sha256, and sha512 are available on OpenBSD.
 170   AC_PATH_PROGS(PCH_CHECKSUMMER, [md5sum md5 sha1sum sha1 sha224sum sha256sum sha256 sha384sum sha512sum sha512 b2sum], [none])
 171   AC_ARG_VAR([PCH_CHECKSUMMER], [full path to a utility to compute the checksum for the precompiled header; checksum is for ccache's pch_external_checksum])
 172 fi
 173
 174 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/ioctl.h sys/time.h termio.h unistd.h stdint.h)
 175
 176 dnl Checks for typedefs, structures, and compiler characteristics.
 177 AC_C_CONST
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_STRUCT_TM
 181
 182 dnl Checks for library functions.
 183 AC_PROG_GCC_TRADITIONAL
 184 AC_FUNC_MEMCMP
 185 AC_FUNC_STRFTIME
 186 AC_FUNC_VPRINTF
 187 AC_CHECK_FUNCS(gethostname mkdir select socket strtol mkstemp usleep)
 188
 189 AC_CONFIG_FILES(Makefile src/Makefile lib/Makefile lib/apex/Makefile \
 190         lib/bone/Makefile lib/data/Makefile \
 191         lib/edit/Makefile lib/edit/quests/Makefile lib/edit/towns/Makefile \
 192         lib/file/Makefile lib/file/books/Makefile lib/help/Makefile \
 193         lib/info/Makefile lib/pref/Makefile lib/save/Makefile \
 194         lib/script/Makefile lib/user/Makefile lib/xtra/Makefile \
 195         lib/xtra/graf/Makefile lib/xtra/music/Makefile lib/xtra/sound/Makefile)
 196 AC_OUTPUT()