[keitairc/keitairc.git] / lib / Keitairc / IrcBuffer.pm

# -*-perl-*-
# Keitairc::IrcBuffer
# $Id: IrcBuffer.pm,v 1.1 2008-01-08 05:52:14 morimoto Exp $
# $Source: /home/ishikawa/work/keitairc/tmp/keitairc/lib/Keitairc/IrcBuffer.pm,v $
#
# Copyright (c) 2008 Jun Morimoto <morimoto@mrmt.net>
# This program is covered by the GNU General Public License 2

package Keitairc::IrcBuffer;
use strict;
use Encode;

################################################################
sub new{
        my $proto = shift;
        my $arg = shift;
        my $me = {};

        $me->{history} = $arg->{history};

        # join ¤·¤Æ¤¤¤ë¥Á¥ã¥Í¥ë¤Î̾¾Î¤òµ­Ï¿¤¹¤ë¥Ï¥Ã¥·¥å (jis)
        $me->{name} = {};

        # join ¤·¤Æ¤¤¤ë¥Á¥ã¥Í¥ë¤Î̾¾Î¤òµ­Ï¿¤¹¤ë¥Ï¥Ã¥·¥å (jis)
        $me->{topic} = {};

        # ¥Á¥ã¥Í¥ë¤Î²ñÏÃÆâÍƤòµ­Ï¿¤¹¤ë¥Ï¥Ã¥·¥å (euc-jp)
        $me->{buffer} = {};
        $me->{unread} = {};

        # ³Æ¥Á¥ã¥Í¥ë¤ÎºÇ½ª¥¢¥¯¥»¥¹»þ¹ï¡¢ºÇ¿·È¯¸À»þ¹ï
        $me->{mtime} = {};
        # ³Æ¥Á¥ã¥Í¥ë¤Î̤ÆɹԿô
        $me->{unread_lines} = {};

        # chk
        $me->{message_added} = 0;

        bless $me;
}

################################################################
sub channels{
        my $me = shift;
        sort {
                $me->mtime($b) <=> $me->mtime($a)
        } keys %{$me->{name}};
}

################################################################
sub now{
        my ($sec, $min, $hour) = localtime(time);
        sprintf('%02d:%02d', $hour, $min);
}

################################################################
sub canon_name{
        local($_) = shift;
        tr/A-Z[\\]^/a-z{|}~/;
        $_;
}

################################################################
sub part{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        delete $me->{name}->{$cc};
}

################################################################
sub join{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{name}->{$cc} = $channel;
}

################################################################
sub mtime{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{mtime}->{$cc};
}

################################################################
sub name{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{name}->{$cc};
}

################################################################
sub message_added{
        my($me, $v) = @_;
        if(defined $v){
                $me->{message_added} = $v;
        }
        $me->{message_added};
}

################################################################
sub unread_lines{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{unread_lines}->{$cc};
}

################################################################
sub unread{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{unread}->{$cc};
}

################################################################
sub clear_unread{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{unread}->{$cc} = '';
        $me->{unread_lines}->{$cc} = 0;
}

################################################################
sub topic{
        my($me, $channel, $topic) = @_;
        my $cc = canon_name($channel);
        if(defined $topic){
                $me->{topic}->{$cc} = $topic;
        }
        $me->{topic}->{$cc};
}

################################################################
sub buffer{
        my($me, $channel) = @_;
        my $cc = canon_name($channel);
        $me->{buffer}->{$cc};
}

################################################################
# °ú¿ô¤Î $msg ¤Ï euc-jp, $channel ¤Ï jis
sub add_message{
        my($me, $channel, $message, $who) = @_;
        my $cc = canon_name($channel);

        if(length $who){
                $message = sprintf('%s %s> %s', now(), $who, $message);
        }else{
                $message = sprintf('%s %s', now(), $message);
        }

        {
                my @tmp = split("\n", $me->{buffer}->{$cc});
                push @tmp, $message;

                if(@tmp > $me->{history}){
                        $me->{buffer}->{$cc} =
                                CORE::join("\n", splice(@tmp, -$me->{history}));
                }else{
                        $me->{buffer}->{$cc} = CORE::join("\n", @tmp);
                }
        }

        {
                my @tmp = split("\n", $me->{unread}->{$cc});
                push @tmp, $message;

                if(@tmp > $me->{history}){
                        $me->{unread}->{$cc} =
                                CORE::join("\n", @tmp[1 .. $me->{history}]);
                }else{
                        $me->{unread}->{$cc} = CORE::join("\n", @tmp);
                }

                $me->{unread_lines}->{$cc} = scalar(@tmp);
        }

        if($me->{unread_lines}->{$cc} > $me->{history}){
                $me->{unread_lines}->{$cc} = $me->{history};
        }

        $me->{mtime}->{$cc} = time;
}

################################################################
# ¥Á¥ã¥Í¥ë̾¾Î¤òû¤«¤¯¤¹¤ë
sub compact_channel_name{
        my $me = shift;
        my $name = shift;

        $name = decode('jis', $name);

        # #name:*.jp ¤ò %name ¤Ë
        if($name =~ s/:\*\.jp$//){
                $name =~ s/^#/%/;
        }

        # ËöÈø¤ÎñÆȤΠ@ ¤Ï¼è¤ë (plum¥×¥é¥°¥¤¥ó¤Îmulticast.plmÂкö)
        $name =~ s/\@$//;

        encode('shiftjis', $name);
}

################################################################
sub simple_escape{
        my $me = shift;
        local($_) = shift;
        s/&/&amp;/g;
        s/>/&gt;/g;
        s/</&lt;/g;
        $_;
}

1;