firm/junk/01/bootload/ld.scr

   1 /* OUTPUT_FORMAT("elf32-h8300") */
   2 OUTPUT_ARCH(h8300h)
   3 ENTRY("_start")
   4
   5 MEMORY
   6 {
   7         /* internal ROM (512KB) */
   8         romall(rx)      : o = 0x000000, l = 0x080000 /* 512KB */
   9         vectors(r)      : o = 0x000000, l = 0x000100 /* top of ROM */
  10         rom(rx)         : o = 0x000100, l = 0x07ff00
  11
  12         /* DRAM (2MB) */
  13         dramall(rwx)    : o = 0x400000, l = 0x200000 /* 2MB */
  14         buffer(rwx)     : o = 0x500000, l = 0x100000 /* 1MB */
  15
  16         /* internal RAM (16KB) */
  17         ramall(rwx)     : o = 0xffbf20, l = 0x004000 /* 16KB */
  18         softvec(rw)     : o = 0xffbf20, l = 0x000040 /* top of RAM */
  19         data(rwx)       : o = 0xffc000, l = 0x003f00
  20         bootstack(rw)   : o = 0xffff00, l = 0x000000
  21         intrstack(rw)   : o = 0xffff00, l = 0x000000 /* end of RAM */
  22 }
  23
  24 SECTIONS
  25 {
  26         .vectors : {
  27                 vector.o(.data)
  28         } > vectors
  29
  30         .text : {
  31                 _text_start = . ;
  32                 *(.text)
  33                 _etext = . ;
  34         } > rom
  35
  36         .rodata : {
  37                 _rodata_start = . ;
  38                 *(.strings)
  39                 *(.rodata)
  40                 *(.rodata.*)
  41                 _erodata = . ;
  42         } > rom
  43
  44         .softvec : {
  45                 _softvec = .;
  46         } > softvec
  47
  48         .buffer : {
  49                 _buffer_start = . ;
  50         } > buffer
  51
  52         .data : {
  53                 _data_start = . ;
  54                 *(.data)
  55                 _edata = . ;
  56         } > data AT> rom
  57
  58         .bss : {
  59                 _bss_start = . ;
  60                 *(.bss)
  61                 *(COMMON)
  62                 _ebss = . ;
  63         } > data AT> rom
  64
  65         . = ALIGN(4);
  66         _end = . ;
  67
  68         .bootstack : {
  69                 _bootstack = .;
  70         } > bootstack
  71
  72         .intrstack : {
  73                 _intrstack = .;
  74         } > intrstack
  75 }