firm/junk/09/bootload/ld.scr

   1 /* OUTPUT_FORMAT("elf32-h8300") */
   2 OUTPUT_ARCH(h8300h)
   3 ENTRY("_start")
   4
   5 MEMORY
   6 {
   7         /* internal ROM (512KB) */
   8         romall(rx)      : o = 0x000000, l = 0x080000 /* 512KB */
   9         vectors(r)      : o = 0x000000, l = 0x000100 /* top of ROM */
  10         rom(rx)         : o = 0x000100, l = 0x07ff00
  11
  12         /* DRAM (2MB) */
  13         dramall(rwx)    : o = 0x400000, l = 0x200000 /* 2MB */
  14         buffer(rwx)     : o = 0x500000, l = 0x100000 /* 1MB */
  15
  16         /* internal RAM (16KB) */
  17         ramall(rwx)     : o = 0xffbf20, l = 0x004000 /* 16KB */
  18         softvec(rw)     : o = 0xffbf20, l = 0x000040 /* top of RAM */
  19         data(rwx)       : o = 0xffc000, l = 0x003f00
  20         bootstack(rw)   : o = 0xffff00, l = 0x000000
  21         intrstack(rw)   : o = 0xffff00, l = 0x000000 /* end of RAM */
  22 }
  23
  24 SECTIONS
  25 {
  26         .vectors : {
  27                 vector.o(.data)
  28         } > vectors
  29
  30         .text : {
  31                 _text_start = . ;
  32                 *(.text)
  33                 _etext = . ;
  34         } > rom
  35
  36         .rodata : {
  37                 _rodata_start = . ;
  38                 *(.strings)
  39                 *(.rodata)
  40                 *(.rodata.*)
  41                 . = ALIGN(4);
  42                 _erodata = . ;
  43         } > rom
  44
  45         .softvec : {
  46                 _softvec = .;
  47         } > softvec
  48
  49         .buffer : {
  50                 _buffer_start = . ;
  51         } > buffer
  52
  53         .data : {
  54                 _data_start = . ;
  55                 *(.data)
  56                 _edata = . ;
  57         } > data AT> rom
  58
  59         .bss : {
  60                 _bss_start = . ;
  61                 *(.bss)
  62                 *(COMMON)
  63                 _ebss = . ;
  64         } > data AT> rom
  65
  66         . = ALIGN(4);
  67         _end = . ;
  68
  69         .bootstack : {
  70                 _bootstack = .;
  71         } > bootstack
  72
  73         .intrstack : {
  74                 _intrstack = .;
  75         } > intrstack
  76 }