www/jm_www.m4

   1 m4_divert(-1)
   2
   3 m4_define(`_Copyleft',
   4 `Copyright (C) 1997 Bob Hepple
   5
   6 This program is free software; you can redistribute it
   7 and/or modify it under the terms of the GNU General Public
   8 License as published by the Free Software Foundation; either
   9 version 2 of the License, or (at your option) any later
  10 version.
  11
  12 This program is distributed in the hope that it will be
  13 useful, but WITHOUT ANY WARRANTY; without even the implied
  14 warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 PURPOSE.  See the GNU General Public License for more
  16 details.
  17
  18 You should have received a copy of the GNU General Public
  19 License along with this program; if not, write to the Free
  20 Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  21 02139, USA.')
  22
  23 m4_changecom(`[[[[')
  24
  25 m4_dnl define(`_LOCAL',1)
  26
  27 m4_ifdef(`_SUB_ONE',
  28   `m4_define(`_CSS',`../jm.css')',
  29   `m4_define(`_CSS',`jm.css')')
  30
  31 m4_ifdef(`_SUB_ONE',
  32   `m4_define(`_IMAGEDIR',`../images')',
  33   `m4_define(`_IMAGEDIR',`images')')
  34
  35 m4_ifdef(`_SUB_ONE',
  36   `m4_define(`_HOMEPAGE',`../')',
  37   `m4_define(`_HOMEPAGE',`./')')
  38
  39
  40
  41 m4_define(`_EDIT_WARNING',`
  42 <!--
  43   ====================================================================
  44     DO NOT EDIT THIS FILE.  EDIT M4 SOURCE FILE OR M4 INCLUDE FILE.
  45     このファイルは編集しないでください. M4 のソース または include
  46     されているファイルを編集してください.
  47   ====================================================================
  48  -->')
  49
  50
  51 m4_define(`_MANCGI',`http://linuxjm.osdn.jp/cgi-bin/man.cgi')
  52 m4_define(`_NAMAZU',`http://linuxjm.osdn.jp/cgi-bin/namazu.cgi')
  53
  54 m4_define(`_EMAIL_ADDRESS',linuxjm-discuss@lists.osdn.me)
  55
  56 m4_define(`_JM_',`JM Project')
  57
  58 m4_define(`_GREY_ICON',`<IMG SRC="_IMAGEDIR/grey.png" WIDTH="14" ALT="* " HEIGHT="14">')
  59
  60 m4_define(`_MAILTO',<A HREF="mailto:$1">$2</A>)
  61
  62 m4_define(`_EMAILME',_MAILTO(_EMAIL_ADDRESS,$1))
  63
  64 m4_define(`_CODEQUOTE',<BLOCKQUOTE><PRE><CODE>$1</CODE></PRE></BLOCKQUOTE>)
  65
  66 m4_dnl Logical markup:
  67
  68 m4_define(`_EM',<EM>$1</EM>)
  69 m4_define(`_STRONG',<STRONG>$1</STRONG>)
  70 m4_define(`_CITE',<CITE>$1</CITE>)
  71 m4_define(`_PRE',<BLOCKQUOTE><PRE>$1</PRE></BLOCKQUOTE>)
  72 m4_define(`_CODE',<CODE>$1</CODE>)
  73
  74 m4_dnl Physical markup:
  75
  76 m4_define(`_BOLD',<B>$1</B>)
  77 m4_define(`_ITALICS',<I>$1</I>)
  78 m4_define(`_STRIKE',<S>$1</S>)
  79 m4_define(`_SUBSCRIPT',<SUB>$1</SUB>)
  80 m4_define(`_SUPERSCRIPT',<SUP>$1</SUP>)
  81 m4_define(`_COURIER',<TT>$1</TT>)
  82 m4_define(`_UNDERLINE',<U>$1</U>)
  83 m4_define(`_SMALL',<SMALL>$1</SMALL>)
  84 m4_define(`_BIG',<BIG>$1</BIG>)
  85
  86 m4_define(`_CENTER',<CENTER>$1</CENTER>)
  87
  88 m4_define(`_LIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3>)
  89
  90 m4_define(`_RIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3 ALIGN="right">)
  91
  92 m4_define(`_IMAGE', <P><CENTER><IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3></CENTER><P>)
  93
  94 m4_define(`_IMAGE2',<P><CENTER>
  95 <IMG SRC="$1" ALT="[$1]" ALIGN=TOP WIDTH=$2 HEIGHT=$3>
  96 <IMG SRC="$4" ALT="[$4]" ALIGN=TOP WIDTH=$5 HEIGHT=$6>
  97 </CENTER><P>)
  98
  99 m4_define(`_FTP',<A HREF="http:$1">$2</A>)
 100
 101 m4_define(`_HEAD1', <H2>$1</H2>)
 102
 103 m4_define(`_HEAD2', <H3>$1</H3>)
 104
 105 m4_define(`_LINK', <A HREF="$1">$2</A>)
 106
 107 m4_define(`_SELFLINK', _LINK($1,$1))
 108
 109 m4_define(`_LOCALLINK',<A HREF="#$1">$2</A>)
 110
 111 m4_define(`_LABEL',<A NAME="$1"><H2>$1</H2></A>)
 112
 113 m4_define(`_LINK_TO_LABEL', _LOCALLINK($1,$1))
 114
 115 m4_define(`_PLUG',
 116   _LINK(http://www.ssc.com/linux/,
 117     _IMAGE(_HOMEPAGE/powered.gif,196,49))<BR>
 118 `If you are wondering, Linux is a free, non-commercial
 119 operating system for computers. It happens to be a hobby of
 120 mine and might well interest other hackers. Click on the logo
 121 to learn more...')
 122
 123 m4_define(`_HEADER', `
 124 <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN"
 125   "http://www.w3.org/TR/REC-html40/loose.dtd">
 126 <HTML LANG="ja" DIR="LTR">
 127 <HEAD>
 128  <META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=UTF-8">
 129  <TITLE>$1 (Japanese)</TITLE>
 130  <META NAME="DESCRIPTION" CONTENT="JM: $1">
 131  <META NAME="author" LANG="en" CONTENT="JM Project Members">
 132  <META NAME="copyright" CONTENT="(C) 1999 JM Project.">
 133  <META NAME="keywords" CONTENT="JM, Linux, Japanese, Manual">
 134  <LINK REV="made" HREF="mailto:linuxjm-discuss@lists.osdn.me">
 135  <LINK REL="stylesheet" TYPE="text/css" HREF="_CSS">
 136 </HEAD>
 137
 138 <BODY>
 139
 140  <H1>$1</H1>
 141 ')
 142
 143 m4_define(`_MIRROR_LIST',`
 144  <DIV CLASS="mirror-navigator">mirror server: [
 145   <A HREF="http://www.linux.or.jp/JM/$1">primary</A> |
 146   <A HREF="http://ktarn.www.linux.or.jp/JM/$1">ktarn</A> |
 147   <A HREF="http://osaka-sandai.www.linux.or.jp/JM/$1">osaka-sandai</A>
 148   ]</DIV>
 149 ')
 150
 151 m4_define(`_CREDITS',`
 152  <HR><!-- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -->
 153  <ADDRESS>
 154   _JM_ や配布マニュアルページに関わるご意見ご要望は
 155   _EMAILME(linuxjm-discuss@lists.osdn.me)
 156   までお願いします。
 157  </ADDRESS>
 158  <HR><!-- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -->
 159 ')
 160
 161 m4_define(`_BACK_TO_HOME',`
 162  <P>
 163   _GREY_ICON
 164   _LINK(_HOMEPAGE,JM Project のメインページへ戻る)
 165  </P>
 166 ')
 167
 168 m4_define(`_BUILD_DATE',`
 169  <DIV CLASS="copyright">
 170   m4_esyscmd(`env -u LANG date')
 171  </DIV>
 172 ')
 173
 174 m4_dnl ----------------------------------------------
 175 m4_dnl TABLE OF CONTENTS
 176
 177 m4_define(`_Start_TOC',`<UL><P>m4_divert(-1)
 178   m4_define(`_H1_num',0)
 179   m4_define(`_H2_num',0)
 180   m4_define(`_H3_num',0)
 181   m4_define(`_H4_num',0)
 182   m4_divert(1)')
 183
 184 m4_define(`_H1', `m4_divert(-1)
 185   m4_define(`_H1_num',m4_incr(_H1_num))
 186   m4_define(`_H2_num',0)
 187   m4_define(`_H3_num',0)
 188   m4_define(`_H4_num',0)
 189   m4_define(`_TOC_label',`_H1_num. $1')
 190   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 191   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 192
 193 m4_define(`_H2', `m4_divert(-1)
 194   m4_define(`_H2_num',m4_incr(_H2_num))
 195   m4_define(`_H3_num',0)
 196   m4_define(`_H4_num',0)
 197   m4_define(`_TOC_label',`_H1_num._H2_num $1')
 198   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 199   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 200
 201 m4_define(`_H3', `m4_divert(-1)
 202   m4_define(`_H3_num',m4_incr(_H3_num))
 203   m4_define(`_H4_num',0)
 204   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num $1')
 205   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 206   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 207
 208 m4_define(`_H4', `m4_divert(-1)
 209   m4_define(`_H4_num',m4_incr(_H4_num))
 210   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num._H4_num $1')
 211   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 212   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 213
 214 m4_define(`_End_TOC',`m4_divert(0)</UL><P>')
 215
 216 m4_dnl ----------------------------------------------
 217 m4_dnl TABLES
 218
 219 m4_dnl _Start_Table(Columns,TABLE parameters)
 220 m4_dnl defaults are BORDER=1 CELLPADDING="1" CELLSPACING="1"
 221 m4_dnl WIDTH="n" pixels or "n%" of screen width
 222 m4_define(`_Start_Table',`<TABLE $1>')
 223
 224 m4_define(`_Table_Hdr_Item', `<th>$1</th>m4_ifelse($#,1,,`_Table_Hdr_Item(m4_shift($@))')')
 225
 226 m4_define(`_Table_Row_Item', `<td>$1</td>m4_ifelse($#,1,,`_Table_Row_Item(m4_shift($@))')')
 227
 228 m4_define(`_Table_Hdr',`<tr>_Table_Hdr_Item($@)</tr>')
 229 m4_define(`_Table_Row',`<tr>_Table_Row_Item($@)</tr>')
 230
 231 m4_define(`_End_Table',</TABLE>)
 232
 233 m4_divert