aclocal.m4

   1 # aclocal.m4 -*- autoconf -*- vim: filetype=config
   2 #
   3 # $Id$
   4 #
   5 # Written by Keith Marshall <keithmarshall@users.sourceforge.net>
   6 # Copyright (C) 2009, 2010, 2013, MinGW.org Project
   7 #
   8 #
   9 # Configuration script for mingw-get
  10 #
  11 #
  12 # This is free software.  Permission is granted to copy, modify and
  13 # redistribute this software, under the provisions of the GNU General
  14 # Public License, Version 3, (or, at your option, any later version),
  15 # as published by the Free Software Foundation; see the file COPYING
  16 # for licensing details.
  17 #
  18 # Note, in particular, that this software is provided "as is", in the
  19 # hope that it may prove useful, but WITHOUT WARRANTY OF ANY KIND; not
  20 # even an implied WARRANTY OF MERCHANTABILITY, nor of FITNESS FOR ANY
  21 # PARTICULAR PURPOSE.  Under no circumstances will the author, or the
  22 # MinGW Project, accept liability for any damages, however caused,
  23 # arising from the use of this software.
  24 #
  25 m4_include([build-aux/m4/missing.m4])
  26 m4_include([build-aux/m4/makeopts.m4])
  27
  28 # MINGW_AC_PACKAGE_DIST_URL( DOMAIN, PATH )
  29 # -----------------------------------------
  30 # Provides a mechanism for specifying the internet DOMAIN, and the
  31 # directory PATH relative to that DOMAIN, whence project packages are
  32 # to be offered for download.  Precious variables PACKAGE_DIST_DOMAIN
  33 # and PACKAGE_DIST_DIR are assigned the default values as specified
  34 # for DOMAIN and PATH respectively; AC_SUBST is called for each.
  35 #
  36 AC_DEFUN([MINGW_AC_PACKAGE_DIST_URL],
  37 [: ${PACKAGE_DIST_DOMAIN="$1"} ${PACKAGE_DIST_DIR="$2"}dnl
  38  AC_ARG_VAR([PACKAGE_DIST_DOMAIN],[Package download domain url [$1]])dnl
  39  AC_ARG_VAR([PACKAGE_DIST_DIR],[Package download host directory [$2]])dnl
  40 ])# MINGW_AC_PACKAGE_DIST_URL
  41
  42 # MINGW_AC_OUTPUT
  43 # ---------------
  44 # A wrapper for AC_OUTPUT itself, to ensure that missing prerequisite
  45 # checks are completed, before the final output stage.
  46 #
  47 AC_DEFUN([MINGW_AC_OUTPUT],
  48 [AC_REQUIRE([_MINGW_AC_ABORT_IF_MISSING_PREREQ])dnl
  49  AC_OUTPUT($@)dnl
  50 ])# MINGW_AC_OUTPUT
  51
  52 # MINGW_AC_PROG_LEX
  53 # -----------------
  54 # A wrapper for AC_PROG_LEX; it causes configure to abort, issuing a
  55 # missing lex diagnostic, when building from SCM sources, (as indicated
  56 # by absence of ${srcdir}/src/pkginfo/pkginfo.c), when no lex processor
  57 # appears to be available.  Furthermore, if AC_PROG_LEX fails to assign
  58 # a sane value to LEX_OUTPUT_ROOT, this provides lex.yy as default.
  59 #
  60 AC_DEFUN([MINGW_AC_PROG_LEX],
  61 [AC_REQUIRE([AC_PROG_LEX])dnl
  62  AS_IF([test x${LEX_OUTPUT_ROOT} = x],[LEX_OUTPUT_ROOT=lex.yy])
  63  AS_IF([test x${LEX} != x:],,[test -f ${srcdir}/src/pkginfo/pkginfo.c],,
  64  [MINGW_AC_ASSERT_MISSING([lex (or for preference, flex)],
  65   [flex-2.5.35-2-msys-1.0.13-bin.tar.lzma (or equivalent)])dnl
  66  ])dnl
  67 ])# MINGW_AC_PROG_LEX
  68 #
  69 # $RCSfile$: end of file