configure.ac

   1 # configure.ac -*- autoconf -*- vim: filetype=config
   2 #
   3 # $Id$
   4 #
   5 # Written by Keith Marshall <keithmarshall@users.sourceforge.net>
   6 # Copyright (C) 2009-2013, MinGW.org Project
   7 #
   8 #
   9 # Configuration script for mingw-get
  10 #
  11 #
  12 # This is free software.  Permission is granted to copy, modify and
  13 # redistribute this software, under the provisions of the GNU General
  14 # Public License, Version 3, (or, at your option, any later version),
  15 # as published by the Free Software Foundation; see the file COPYING
  16 # for licensing details.
  17 #
  18 # Note, in particular, that this software is provided "as is", in the
  19 # hope that it may prove useful, but WITHOUT WARRANTY OF ANY KIND; not
  20 # even an implied WARRANTY OF MERCHANTABILITY, nor of FITNESS FOR ANY
  21 # PARTICULAR PURPOSE.  Under no circumstances will the author, or the
  22 # MinGW.org Project, accept liability for any damages, however caused,
  23 # arising from the use of this software.
  24 #
  25   AC_INIT([mingw-get],[0.5-beta-20120426-1],[http://mingw.org/Reporting_Bugs])
  26
  27   AC_SUBST([COPYRIGHT_HOLDER],["MinGW.org Project"])
  28   AC_SUBST([YEARS_OF_ISSUE],["2009-2013"])
  29
  30 # Override the normal UNIX-centric autoconf default prefix;
  31 # substitute the MinGW standard in its place.
  32 #
  33   AC_PREFIX_DEFAULT([C:/MinGW])
  34
  35 # We need the canonical representation of the intended host platform
  36 # identification triplet, from which to deduce the subsystem designator
  37 # in distributed tarball names.  (Note that we explicitly override any
  38 # user specified "build_alias", because autoconf gets upset if "host"
  39 # is specified without "build", and we need "host" if cross-compiling;
  40 # all we need in this case is "host" != "build", and we don't really
  41 # care what "build" is, but AC_CANONICAL_HOST gets very upset, when it
  42 # calls ${srcdir}/build-aux/config.sub, if the user specifies a short
  43 # form which it cannot resolve -- e.g. "--build=linux" will fail).
  44 #
  45   AC_CONFIG_AUX_DIR([build-aux])
  46   build_alias=`${srcdir}/build-aux/config.guess`
  47   AC_CANONICAL_HOST
  48
  49 # We need both C and C++ compilers; check how to invoke them
  50 #
  51   AC_PROG_CC
  52   AC_PROG_CXX
  53
  54 # We also need a Windows resource compiler,
  55 # and a lexical analyser generator
  56 #
  57   AC_CHECK_TOOL([WINDRES],[windres],[windres])
  58   AC_PROG_LEX
  59
  60 # Ensure that (at least the headers for) prerequisite libraries,
  61 # zlib, libbz2 and liblzma are available
  62 #
  63   AC_CHECK_HEADER([zlib.h],,MINGW_AC_ASSERT_MISSING([zlib-dev],
  64     [libz-1.2.3-1-mingw32-dev.tar.gz]))
  65   AC_CHECK_HEADER([bzlib.h],,MINGW_AC_ASSERT_MISSING([libbz2-dev],
  66     [bzip2-1.0.5-2-mingw32-dev.tar.gz]))
  67   AC_CHECK_HEADER([lzma.h],,MINGW_AC_ASSERT_MISSING([liblzma-dev],
  68     [liblzma-4.999.9beta_20091209-3-mingw32-dev.tar.bz2]))
  69
  70 # Set up the archive librarian, to match our compiler settings
  71 #
  72   AC_CHECK_TOOL([AR],[ar],[ar])
  73   AC_SUBST([ARFLAGS],[${ARFLAGS-rcs}])
  74
  75 # Identify tools required for product installation
  76 #
  77   AC_PROG_MKDIR_P
  78   AC_PROG_INSTALL
  79   AC_PROG_LN_S
  80
  81 # As for the archive librarian, we need to ensure that the tool
  82 # for stripping binaries is compatible with the compiler
  83 #
  84   AC_CHECK_TOOL([STRIP],[strip],[strip])
  85
  86 # Identify features to be traced to facilitate debugging; make
  87 # it precious, to avoid introducing accidental inconsistencies.
  88 #
  89   AC_ARG_VAR([DEBUGLEVEL],[tracing flags to facilitate debugging])
  90   AC_SUBST([DEBUGLEVEL],[${DEBUGLEVEL-0}])
  91
  92 # Establish the product version banner, and create a makefile
  93 #
  94   AC_CONFIG_FILES([version.c Makefile])
  95   MINGW_AC_OUTPUT
  96 #
  97 # $RCSfile$: end of file