bitcoin-qt.pro

   1 TEMPLATE = app
   2 TARGET = monacoin-qt
   3 macx:TARGET = "Monacoin-Qt"
   4 VERSION = 0.8.6.2
   5 INCLUDEPATH += src src/json src/qt
   6 QT += core gui network
   7 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
   8 DEFINES += QT_GUI BOOST_THREAD_USE_LIB BOOST_SPIRIT_THREADSAFE
   9 CONFIG += no_include_pwd
  10 CONFIG += thread
  11 CONFIG += qt
  12
  13 # for boost 1.37, add -mt to the boost libraries
  14 # use: qmake BOOST_LIB_SUFFIX=-mt
  15 # for boost thread win32 with _win32 sufix
  16 # use: BOOST_THREAD_LIB_SUFFIX=_win32-...
  17 # or when linking against a specific BerkelyDB version: BDB_LIB_SUFFIX=-4.8
  18
  19 # Dependency library locations can be customized with:
  20 #    BOOST_INCLUDE_PATH, BOOST_LIB_PATH, BDB_INCLUDE_PATH,
  21 #    BDB_LIB_PATH, OPENSSL_INCLUDE_PATH and OPENSSL_LIB_PATH respectively
  22
  23
  24
  25 OBJECTS_DIR = build
  26 MOC_DIR = build
  27 UI_DIR = build
  28
  29 # use: qmake "RELEASE=1"
  30 contains(RELEASE, 1) {
  31     # Mac: compile for maximum compatibility (10.5, 32-bit)
  32     macx:QMAKE_CXXFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  33     macx:QMAKE_CFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  34     macx:QMAKE_OBJECTIVE_CFLAGS += -mmacosx-version-min=10.5 -arch i386 -isysroot /Developer/SDKs/MacOSX10.5.sdk
  35
  36     !win32:!macx {
  37         # Linux: static link and extra security (see: https://wiki.debian.org/Hardening)
  38         LIBS += -Wl,-Bstatic -Wl,-z,relro -Wl,-z,now
  39     }
  40 }
  41
  42 !win32 {
  43     # for extra security against potential buffer overflows: enable GCCs Stack Smashing Protection
  44     QMAKE_CXXFLAGS *= -fstack-protector-all
  45     QMAKE_LFLAGS *= -fstack-protector-all
  46     # Exclude on Windows cross compile with MinGW 4.2.x, as it will result in a non-working executable!
  47     # This can be enabled for Windows, when we switch to MinGW >= 4.4.x.
  48 }
  49 # for extra security (see: https://wiki.debian.org/Hardening): this flag is GCC compiler-specific
  50 QMAKE_CXXFLAGS += -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2
  51 # for extra security on Windows: enable ASLR and DEP via GCC linker flags
  52 win32:QMAKE_LFLAGS *= -Wl,--dynamicbase -Wl,--nxcompat
  53 # on Windows: enable GCC large address aware linker flag
  54 win32:QMAKE_LFLAGS *= -Wl,--large-address-aware
  55 # i686-w64-mingw32
  56 win32:QMAKE_LFLAGS *= -static-libgcc -static-libstdc++
  57
  58 # use: qmake "USE_QRCODE=1"
  59 # libqrencode (http://fukuchi.org/works/qrencode/index.en.html) must be installed for support
  60 contains(USE_QRCODE, 1) {
  61     message(Building with QRCode support)
  62     DEFINES += USE_QRCODE
  63     LIBS += -lqrencode
  64 }
  65
  66 # use: qmake "USE_UPNP=1" ( enabled by default; default)
  67 #  or: qmake "USE_UPNP=0" (disabled by default)
  68 #  or: qmake "USE_UPNP=-" (not supported)
  69 # miniupnpc (http://miniupnp.free.fr/files/) must be installed for support
  70 contains(USE_UPNP, -) {
  71     message(Building without UPNP support)
  72 } else {
  73     message(Building with UPNP support)
  74     count(USE_UPNP, 0) {
  75         USE_UPNP=1
  76     }
  77     DEFINES += USE_UPNP=$$USE_UPNP STATICLIB
  78     INCLUDEPATH += $$MINIUPNPC_INCLUDE_PATH
  79     LIBS += $$join(MINIUPNPC_LIB_PATH,,-L,) -lminiupnpc
  80     win32:LIBS += -liphlpapi
  81 }
  82
  83 # use: qmake "USE_DBUS=1"
  84 contains(USE_DBUS, 1) {
  85     message(Building with DBUS (Freedesktop notifications) support)
  86     DEFINES += USE_DBUS
  87     QT += dbus
  88 }
  89
  90 # use: qmake "USE_IPV6=1" ( enabled by default; default)
  91 #  or: qmake "USE_IPV6=0" (disabled by default)
  92 #  or: qmake "USE_IPV6=-" (not supported)
  93 contains(USE_IPV6, -) {
  94     message(Building without IPv6 support)
  95 } else {
  96     count(USE_IPV6, 0) {
  97         USE_IPV6=1
  98     }
  99     DEFINES += USE_IPV6=$$USE_IPV6
 100 }
 101
 102 contains(BITCOIN_NEED_QT_PLUGINS, 1) {
 103     DEFINES += BITCOIN_NEED_QT_PLUGINS
 104     QTPLUGIN += qcncodecs qjpcodecs qtwcodecs qkrcodecs qtaccessiblewidgets
 105 }
 106
 107 INCLUDEPATH += src/leveldb/include src/leveldb/helpers
 108 LIBS += $$PWD/src/leveldb/libleveldb.a $$PWD/src/leveldb/libmemenv.a
 109 !win32 {
 110     # we use QMAKE_CXXFLAGS_RELEASE even without RELEASE=1 because we use RELEASE to indicate linking preferences not -O preferences
 111     genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a
 112 } else {
 113     # make an educated guess about what the ranlib command is called
 114     isEmpty(QMAKE_RANLIB) {
 115         QMAKE_RANLIB = $$replace(QMAKE_STRIP, strip, ranlib)
 116     }
 117     LIBS += -lshlwapi
 118     genleveldb.commands = cd $$PWD/src/leveldb && CC=$$QMAKE_CC CXX=$$QMAKE_CXX TARGET_OS=OS_WINDOWS_CROSSCOMPILE $(MAKE) OPT=\"$$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_RELEASE\" libleveldb.a libmemenv.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libleveldb.a && $$QMAKE_RANLIB $$PWD/src/leveldb/libmemenv.a
 119 }
 120 genleveldb.target = $$PWD/src/leveldb/libleveldb.a
 121 genleveldb.depends = FORCE
 122 PRE_TARGETDEPS += $$PWD/src/leveldb/libleveldb.a
 123 QMAKE_EXTRA_TARGETS += genleveldb
 124 # Gross ugly hack that depends on qmake internals, unfortunately there is no other way to do it.
 125 QMAKE_CLEAN += $$PWD/src/leveldb/libleveldb.a; cd $$PWD/src/leveldb ; $(MAKE) clean
 126
 127 # regenerate src/build.h
 128 !win32|contains(USE_BUILD_INFO, 1) {
 129     genbuild.depends = FORCE
 130     genbuild.commands = cd $$PWD; /bin/sh share/genbuild.sh $$OUT_PWD/build/build.h
 131     genbuild.target = $$OUT_PWD/build/build.h
 132     PRE_TARGETDEPS += $$OUT_PWD/build/build.h
 133     QMAKE_EXTRA_TARGETS += genbuild
 134     DEFINES += HAVE_BUILD_INFO
 135 }
 136
 137 QMAKE_CXXFLAGS_WARN_ON = -fdiagnostics-show-option -Wall -Wextra -Wformat -Wformat-security -Wno-unused-parameter -Wstack-protector
 138
 139 # Input
 140 DEPENDPATH += src src/json src/qt
 141 HEADERS += src/qt/bitcoingui.h \
 142     src/qt/transactiontablemodel.h \
 143     src/qt/addresstablemodel.h \
 144     src/qt/optionsdialog.h \
 145     src/qt/sendcoinsdialog.h \
 146     src/qt/coincontroldialog.h \
 147     src/qt/coincontroltreewidget.h \
 148     src/qt/addressbookpage.h \
 149     src/qt/signverifymessagedialog.h \
 150     src/qt/aboutdialog.h \
 151     src/qt/editaddressdialog.h \
 152     src/qt/bitcoinaddressvalidator.h \
 153     src/alert.h \
 154     src/addrman.h \
 155     src/base58.h \
 156     src/bignum.h \
 157     src/checkpoints.h \
 158     src/coincontrol.h \
 159     src/compat.h \
 160     src/sync.h \
 161     src/util.h \
 162     src/hash.h \
 163     src/uint256.h \
 164     src/serialize.h \
 165     src/main.h \
 166     src/net.h \
 167     src/key.h \
 168     src/db.h \
 169     src/walletdb.h \
 170     src/script.h \
 171     src/init.h \
 172     src/bloom.h \
 173     src/mruset.h \
 174     src/checkqueue.h \
 175     src/json/json_spirit_writer_template.h \
 176     src/json/json_spirit_writer.h \
 177     src/json/json_spirit_value.h \
 178     src/json/json_spirit_utils.h \
 179     src/json/json_spirit_stream_reader.h \
 180     src/json/json_spirit_reader_template.h \
 181     src/json/json_spirit_reader.h \
 182     src/json/json_spirit_error_position.h \
 183     src/json/json_spirit.h \
 184     src/qt/clientmodel.h \
 185     src/qt/guiutil.h \
 186     src/qt/transactionrecord.h \
 187     src/qt/guiconstants.h \
 188     src/qt/optionsmodel.h \
 189     src/qt/monitoreddatamapper.h \
 190     src/qt/transactiondesc.h \
 191     src/qt/transactiondescdialog.h \
 192     src/qt/bitcoinamountfield.h \
 193     src/wallet.h \
 194     src/keystore.h \
 195     src/qt/transactionfilterproxy.h \
 196     src/qt/transactionview.h \
 197     src/qt/walletmodel.h \
 198     src/qt/walletview.h \
 199     src/qt/walletstack.h \
 200     src/qt/walletframe.h \
 201     src/bitcoinrpc.h \
 202     src/qt/overviewpage.h \
 203     src/qt/csvmodelwriter.h \
 204     src/crypter.h \
 205     src/qt/sendcoinsentry.h \
 206     src/qt/qvalidatedlineedit.h \
 207     src/qt/bitcoinunits.h \
 208     src/qt/qvaluecombobox.h \
 209     src/qt/askpassphrasedialog.h \
 210     src/protocol.h \
 211     src/qt/notificator.h \
 212     src/qt/paymentserver.h \
 213     src/allocators.h \
 214     src/ui_interface.h \
 215     src/qt/rpcconsole.h \
 216     src/scrypt.h \
 217     src/version.h \
 218     src/netbase.h \
 219     src/clientversion.h \
 220     src/txdb.h \
 221     src/leveldb.h \
 222     src/threadsafety.h \
 223     src/limitedmap.h \
 224     src/qt/macnotificationhandler.h \
 225     src/qt/splashscreen.h
 226
 227 SOURCES += src/qt/bitcoin.cpp \
 228     src/qt/bitcoingui.cpp \
 229     src/qt/transactiontablemodel.cpp \
 230     src/qt/addresstablemodel.cpp \
 231     src/qt/optionsdialog.cpp \
 232     src/qt/sendcoinsdialog.cpp \
 233     src/qt/coincontroldialog.cpp \
 234     src/qt/coincontroltreewidget.cpp \
 235     src/qt/addressbookpage.cpp \
 236     src/qt/signverifymessagedialog.cpp \
 237     src/qt/aboutdialog.cpp \
 238     src/qt/editaddressdialog.cpp \
 239     src/qt/bitcoinaddressvalidator.cpp \
 240     src/alert.cpp \
 241     src/version.cpp \
 242     src/sync.cpp \
 243     src/util.cpp \
 244     src/hash.cpp \
 245     src/netbase.cpp \
 246     src/key.cpp \
 247     src/script.cpp \
 248     src/main.cpp \
 249     src/init.cpp \
 250     src/net.cpp \
 251     src/bloom.cpp \
 252     src/checkpoints.cpp \
 253     src/addrman.cpp \
 254     src/db.cpp \
 255     src/walletdb.cpp \
 256     src/qt/clientmodel.cpp \
 257     src/qt/guiutil.cpp \
 258     src/qt/transactionrecord.cpp \
 259     src/qt/optionsmodel.cpp \
 260     src/qt/monitoreddatamapper.cpp \
 261     src/qt/transactiondesc.cpp \
 262     src/qt/transactiondescdialog.cpp \
 263     src/qt/bitcoinstrings.cpp \
 264     src/qt/bitcoinamountfield.cpp \
 265     src/wallet.cpp \
 266     src/keystore.cpp \
 267     src/qt/transactionfilterproxy.cpp \
 268     src/qt/transactionview.cpp \
 269     src/qt/walletmodel.cpp \
 270     src/qt/walletview.cpp \
 271     src/qt/walletstack.cpp \
 272     src/qt/walletframe.cpp \
 273     src/bitcoinrpc.cpp \
 274     src/rpcdump.cpp \
 275     src/rpcnet.cpp \
 276     src/rpcmining.cpp \
 277     src/rpcwallet.cpp \
 278     src/rpcblockchain.cpp \
 279     src/rpcrawtransaction.cpp \
 280     src/qt/overviewpage.cpp \
 281     src/qt/csvmodelwriter.cpp \
 282     src/crypter.cpp \
 283     src/qt/sendcoinsentry.cpp \
 284     src/qt/qvalidatedlineedit.cpp \
 285     src/qt/bitcoinunits.cpp \
 286     src/qt/qvaluecombobox.cpp \
 287     src/qt/askpassphrasedialog.cpp \
 288     src/protocol.cpp \
 289     src/qt/notificator.cpp \
 290     src/qt/paymentserver.cpp \
 291     src/qt/rpcconsole.cpp \
 292     src/scrypt.cpp \
 293     src/noui.cpp \
 294     src/leveldb.cpp \
 295     src/txdb.cpp \
 296     src/qt/splashscreen.cpp
 297
 298 RESOURCES += src/qt/bitcoin.qrc
 299
 300 FORMS += src/qt/forms/sendcoinsdialog.ui \
 301     src/qt/forms/coincontroldialog.ui \
 302     src/qt/forms/addressbookpage.ui \
 303     src/qt/forms/signverifymessagedialog.ui \
 304     src/qt/forms/aboutdialog.ui \
 305     src/qt/forms/editaddressdialog.ui \
 306     src/qt/forms/transactiondescdialog.ui \
 307     src/qt/forms/overviewpage.ui \
 308     src/qt/forms/sendcoinsentry.ui \
 309     src/qt/forms/askpassphrasedialog.ui \
 310     src/qt/forms/rpcconsole.ui \
 311     src/qt/forms/optionsdialog.ui
 312
 313 contains(USE_QRCODE, 1) {
 314 HEADERS += src/qt/qrcodedialog.h
 315 SOURCES += src/qt/qrcodedialog.cpp
 316 FORMS += src/qt/forms/qrcodedialog.ui
 317 }
 318
 319 contains(BITCOIN_QT_TEST, 1) {
 320 SOURCES += src/qt/test/test_main.cpp \
 321     src/qt/test/uritests.cpp
 322 HEADERS += src/qt/test/uritests.h
 323 DEPENDPATH += src/qt/test
 324 QT += testlib
 325 TARGET = monacoin-qt_test
 326 DEFINES += BITCOIN_QT_TEST
 327   macx: CONFIG -= app_bundle
 328 }
 329
 330 contains(USE_SSE2, 1) {
 331 DEFINES += USE_SSE2
 332 gccsse2.input  = SOURCES_SSE2
 333 gccsse2.output = $$PWD/build/${QMAKE_FILE_BASE}.o
 334 gccsse2.commands = $(CXX) -c $(CXXFLAGS) $(INCPATH) -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME} -msse2 -mstackrealign
 335 QMAKE_EXTRA_COMPILERS += gccsse2
 336 SOURCES_SSE2 += src/scrypt-sse2.cpp
 337 }
 338
 339 # Todo: Remove this line when switching to Qt5, as that option was removed
 340 CODECFORTR = UTF-8
 341
 342 # for lrelease/lupdate
 343 # also add new translations to src/qt/bitcoin.qrc under translations/
 344 TRANSLATIONS = $$files(src/qt/locale/bitcoin_*.ts)
 345
 346 isEmpty(QMAKE_LRELEASE) {
 347     win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
 348     else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 349 }
 350 isEmpty(QM_DIR):QM_DIR = $$PWD/src/qt/locale
 351 # automatically build translations, so they can be included in resource file
 352 TSQM.name = lrelease ${QMAKE_FILE_IN}
 353 TSQM.input = TRANSLATIONS
 354 TSQM.output = $$QM_DIR/${QMAKE_FILE_BASE}.qm
 355 TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
 356 TSQM.CONFIG = no_link
 357 QMAKE_EXTRA_COMPILERS += TSQM
 358
 359 # "Other files" to show in Qt Creator
 360 OTHER_FILES += README.md \
 361     doc/*.rst \
 362     doc/*.txt \
 363     doc/*.md \
 364     src/qt/res/bitcoin-qt.rc \
 365     src/test/*.cpp \
 366     src/test/*.h \
 367     src/qt/test/*.cpp \
 368     src/qt/test/*.h
 369
 370 # platform specific defaults, if not overridden on command line
 371 isEmpty(BOOST_LIB_SUFFIX) {
 372     macx:BOOST_LIB_SUFFIX = -mt
 373     win32:BOOST_LIB_SUFFIX = -mgw44-mt-s-1_50
 374 }
 375
 376 isEmpty(BOOST_THREAD_LIB_SUFFIX) {
 377     BOOST_THREAD_LIB_SUFFIX = $$BOOST_LIB_SUFFIX
 378 }
 379
 380 isEmpty(BDB_LIB_PATH) {
 381     macx:BDB_LIB_PATH = /opt/local/lib/db48
 382 }
 383
 384 isEmpty(BDB_LIB_SUFFIX) {
 385     macx:BDB_LIB_SUFFIX = -4.8
 386 }
 387
 388 isEmpty(BDB_INCLUDE_PATH) {
 389     macx:BDB_INCLUDE_PATH = /opt/local/include/db48
 390 }
 391
 392 isEmpty(BOOST_LIB_PATH) {
 393     macx:BOOST_LIB_PATH = /opt/local/lib
 394 }
 395
 396 isEmpty(BOOST_INCLUDE_PATH) {
 397     macx:BOOST_INCLUDE_PATH = /opt/local/include
 398 }
 399
 400 win32:DEFINES += WIN32
 401 win32:RC_FILE = src/qt/res/bitcoin-qt.rc
 402
 403 win32:!contains(MINGW_THREAD_BUGFIX, 0) {
 404     # At least qmake's win32-g++-cross profile is missing the -lmingwthrd
 405     # thread-safety flag. GCC has -mthreads to enable this, but it doesn't
 406     # work with static linking. -lmingwthrd must come BEFORE -lmingw, so
 407     # it is prepended to QMAKE_LIBS_QT_ENTRY.
 408     # It can be turned off with MINGW_THREAD_BUGFIX=0, just in case it causes
 409     # any problems on some untested qmake profile now or in the future.
 410     DEFINES += _MT
 411     QMAKE_LIBS_QT_ENTRY = -lmingwthrd $$QMAKE_LIBS_QT_ENTRY
 412 }
 413
 414 !win32:!macx {
 415     DEFINES += LINUX
 416     LIBS += -lrt
 417     # _FILE_OFFSET_BITS=64 lets 32-bit fopen transparently support large files.
 418     DEFINES += _FILE_OFFSET_BITS=64
 419 }
 420
 421 macx:HEADERS += src/qt/macdockiconhandler.h src/qt/macnotificationhandler.h
 422 macx:OBJECTIVE_SOURCES += src/qt/macdockiconhandler.mm src/qt/macnotificationhandler.mm
 423 macx:LIBS += -framework Foundation -framework ApplicationServices -framework AppKit -framework CoreServices
 424 macx:DEFINES += MAC_OSX MSG_NOSIGNAL=0
 425 macx:ICON = src/qt/res/icons/monacoin.icns
 426 macx:QMAKE_CFLAGS_THREAD += -pthread
 427 macx:QMAKE_LFLAGS_THREAD += -pthread
 428 macx:QMAKE_CXXFLAGS_THREAD += -pthread
 429 macx:QMAKE_INFO_PLIST = share/qt/Info.plist
 430
 431 # Set libraries and includes at end, to use platform-defined defaults if not overridden
 432 INCLUDEPATH += $$BOOST_INCLUDE_PATH $$BDB_INCLUDE_PATH $$OPENSSL_INCLUDE_PATH $$QRENCODE_INCLUDE_PATH
 433 LIBS += $$join(BOOST_LIB_PATH,,-L,) $$join(BDB_LIB_PATH,,-L,) $$join(OPENSSL_LIB_PATH,,-L,) $$join(QRENCODE_LIB_PATH,,-L,)
 434 LIBS += -lssl -lcrypto -ldb_cxx$$BDB_LIB_SUFFIX
 435 # -lgdi32 has to happen after -lcrypto (see  #681)
 436 win32:LIBS += -lws2_32 -lshlwapi -lmswsock -lole32 -loleaut32 -luuid -lgdi32
 437 LIBS += -lboost_system$$BOOST_LIB_SUFFIX -lboost_filesystem$$BOOST_LIB_SUFFIX -lboost_program_options$$BOOST_LIB_SUFFIX -lboost_thread$$BOOST_THREAD_LIB_SUFFIX
 438 win32:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
 439 macx:LIBS += -lboost_chrono$$BOOST_LIB_SUFFIX
 440
 441 contains(RELEASE, 1) {
 442     !win32:!macx {
 443         # Linux: turn dynamic linking back on for c/c++ runtime libraries
 444         LIBS += -Wl,-Bdynamic
 445     }
 446 }
 447
 448 system($$QMAKE_LRELEASE -silent $$TRANSLATIONS)