configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.2devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2011, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61 dragonfly*) template=netbsd ;;
  62     dgux*) template=dgux ;;
  63  freebsd*) template=freebsd ;;
  64     hpux*) template=hpux ;;
  65     irix*) template=irix ;;
  66  linux*|gnu*|k*bsd*-gnu)
  67            template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-bugs@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Initialize default assumption that we do not need separate assembly code
 107 # for TAS (test-and-set).  This can be overridden by the template file
 108 # when it's executed.
 109 need_tas=no
 110 tas_file=dummy.s
 111
 112
 113
 114 ##
 115 ## Command line options
 116 ##
 117
 118 #
 119 # Add non-standard directories to the include path
 120 #
 121 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 122
 123
 124 #
 125 # Add non-standard directories to the library search path
 126 #
 127 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 128              [LIBRARY_DIRS=$withval])
 129
 130 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 131              [LIBRARY_DIRS=$withval])
 132
 133
 134 #
 135 # 64-bit integer date/time storage: enabled by default.
 136 #
 137 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 138 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 139               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 140                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 141 AC_MSG_RESULT([$enable_integer_datetimes])
 142
 143
 144 #
 145 # NLS
 146 #
 147 AC_MSG_CHECKING([whether NLS is wanted])
 148 PGAC_ARG_OPTARG(enable, nls,
 149                 [LANGUAGES], [enable Native Language Support],
 150                 [],
 151                 [WANTED_LANGUAGES=$enableval],
 152                 [AC_DEFINE(ENABLE_NLS, 1,
 153                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 154 AC_MSG_RESULT([$enable_nls])
 155 AC_SUBST(enable_nls)
 156 AC_SUBST(WANTED_LANGUAGES)
 157
 158 #
 159 # Default port number (--with-pgport), default 5432
 160 #
 161 AC_MSG_CHECKING([for default port number])
 162 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 163              [default_port=$withval],
 164              [default_port=5432])
 165 AC_MSG_RESULT([$default_port])
 166 # Need both of these because some places want an integer and some a string
 167 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 168 [Define to the default TCP port number on which the server listens and
 169 to which clients will try to connect.  This can be overridden at run-time,
 170 but it's convenient if your clients have the right default compiled in.
 171 (--with-pgport=PORTNUM)])
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 173                    [Define to the default TCP port number as a string constant.])
 174 AC_SUBST(default_port)
 175
 176 #
 177 # Option to disable shared libraries
 178 #
 179 PGAC_ARG_BOOL(enable, shared, yes,
 180               [do not build shared libraries])
 181 AC_SUBST(enable_shared)
 182
 183 #
 184 # '-rpath'-like feature can be disabled
 185 #
 186 PGAC_ARG_BOOL(enable, rpath, yes,
 187               [do not embed shared library search path in executables])
 188 AC_SUBST(enable_rpath)
 189
 190 #
 191 # Spinlocks
 192 #
 193 PGAC_ARG_BOOL(enable, spinlocks, yes,
 194               [do not use spinlocks])
 195
 196 #
 197 # --enable-debug adds -g to compiler flags
 198 #
 199 PGAC_ARG_BOOL(enable, debug, no,
 200               [build with debugging symbols (-g)])
 201 AC_SUBST(enable_debug)
 202
 203 #
 204 # --enable-profiling enables gcc profiling
 205 #
 206 PGAC_ARG_BOOL(enable, profiling, no,
 207               [build with profiling enabled ])
 208 AC_SUBST(enable_profiling)
 209
 210 #
 211 # --enable-coverage enables generation of code coverage metrics with gcov
 212 #
 213 PGAC_ARG_BOOL(enable, coverage, no,
 214               [build with coverage testing instrumentation],
 215 [AC_CHECK_PROGS(GCOV, gcov)
 216 if test -z "$GCOV"; then
 217   AC_MSG_ERROR([gcov not found])
 218 fi
 219 AC_CHECK_PROGS(LCOV, lcov)
 220 if test -z "$LCOV"; then
 221   AC_MSG_ERROR([lcov not found])
 222 fi
 223 AC_CHECK_PROGS(GENHTML, genhtml)
 224 if test -z "$GENHTML"; then
 225   AC_MSG_ERROR([genhtml not found])
 226 fi])
 227 AC_SUBST(enable_coverage)
 228
 229 #
 230 # DTrace
 231 #
 232 PGAC_ARG_BOOL(enable, dtrace, no,
 233               [build with DTrace support],
 234 [AC_DEFINE([ENABLE_DTRACE], 1,
 235            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 236 AC_CHECK_PROGS(DTRACE, dtrace)
 237 if test -z "$DTRACE"; then
 238   AC_MSG_ERROR([dtrace not found])
 239 fi
 240 AC_SUBST(DTRACEFLAGS)])
 241 AC_SUBST(enable_dtrace)
 242
 243 #
 244 # Block size
 245 #
 246 AC_MSG_CHECKING([for block size])
 247 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 248              [blocksize=$withval],
 249              [blocksize=8])
 250 case ${blocksize} in
 251   1) BLCKSZ=1024;;
 252   2) BLCKSZ=2048;;
 253   4) BLCKSZ=4096;;
 254   8) BLCKSZ=8192;;
 255  16) BLCKSZ=16384;;
 256  32) BLCKSZ=32768;;
 257   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 258 esac
 259 AC_MSG_RESULT([${blocksize}kB])
 260
 261 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 262  Size of a disk block --- this also limits the size of a tuple.  You
 263  can set it bigger if you need bigger tuples (although TOAST should
 264  reduce the need to have large tuples, since fields can be spread
 265  across multiple tuples).
 266
 267  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 268  is currently 2^15 (32768).  This is determined by the 15-bit widths
 269  of the lp_off and lp_len fields in ItemIdData (see
 270  include/storage/itemid.h).
 271
 272  Changing BLCKSZ requires an initdb.
 273 ])
 274
 275 #
 276 # Relation segment size
 277 #
 278 AC_MSG_CHECKING([for segment size])
 279 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 280              [segsize=$withval],
 281              [segsize=1])
 282 # this expression is set up to avoid unnecessary integer overflow
 283 # blocksize is already guaranteed to be a factor of 1024
 284 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 285 test $? -eq 0 || exit 1
 286 AC_MSG_RESULT([${segsize}GB])
 287
 288 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 289  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 290  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 291  relations bigger than that are divided into multiple files.
 292
 293  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 294  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 295  have large file support enabled.  By default, we make the limit 1 GB
 296  to avoid any possible integer-overflow problems within the OS.
 297  A limit smaller than necessary only means we divide a large
 298  relation into more chunks than necessary, so it seems best to err
 299  in the direction of a small limit.
 300
 301  A power-of-2 value is recommended to save a few cycles in md.c,
 302  but is not absolutely required.
 303
 304  Changing RELSEG_SIZE requires an initdb.
 305 ])
 306
 307 #
 308 # WAL block size
 309 #
 310 AC_MSG_CHECKING([for WAL block size])
 311 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 312              [wal_blocksize=$withval],
 313              [wal_blocksize=8])
 314 case ${wal_blocksize} in
 315   1) XLOG_BLCKSZ=1024;;
 316   2) XLOG_BLCKSZ=2048;;
 317   4) XLOG_BLCKSZ=4096;;
 318   8) XLOG_BLCKSZ=8192;;
 319  16) XLOG_BLCKSZ=16384;;
 320  32) XLOG_BLCKSZ=32768;;
 321  64) XLOG_BLCKSZ=65536;;
 322   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 323 esac
 324 AC_MSG_RESULT([${wal_blocksize}kB])
 325
 326 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 327  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 328  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 329  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 330  buffers, else direct I/O may fail.
 331
 332  Changing XLOG_BLCKSZ requires an initdb.
 333 ])
 334
 335 #
 336 # WAL segment size
 337 #
 338 AC_MSG_CHECKING([for WAL segment size])
 339 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 340              [wal_segsize=$withval],
 341              [wal_segsize=16])
 342 case ${wal_segsize} in
 343   1) ;;
 344   2) ;;
 345   4) ;;
 346   8) ;;
 347  16) ;;
 348  32) ;;
 349  64) ;;
 350   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 351 esac
 352 AC_MSG_RESULT([${wal_segsize}MB])
 353
 354 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 355  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 356  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 357  XLOG_BLCKSZ).
 358
 359  Changing XLOG_SEG_SIZE requires an initdb.
 360 ])
 361
 362 #
 363 # C compiler
 364 #
 365
 366 # For historical reasons you can also use --with-CC to specify the C compiler
 367 # to use, although the standard way to do this is to set the CC environment
 368 # variable.
 369 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 370
 371 case $template in
 372   aix) pgac_cc_list="gcc xlc";;
 373  irix) pgac_cc_list="cc";; # no gcc
 374     *) pgac_cc_list="gcc cc";;
 375 esac
 376
 377 AC_PROG_CC([$pgac_cc_list])
 378
 379 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 380 # but has idiosyncrasies of its own.  We assume icc will define
 381 # __INTEL_COMPILER regardless of CFLAGS.
 382 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 383 choke me
 384 @%:@endif], [ICC=[yes]], [ICC=[no]])
 385
 386 # Check if it's Sun Studio compiler. We assume that
 387 # __SUNPRO_C will be defined for Sun Studio compilers
 388 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 389 choke me
 390 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 391
 392 AC_SUBST(SUN_STUDIO_CC)
 393
 394 unset CFLAGS
 395
 396 #
 397 # Read the template
 398 #
 399 . "$srcdir/src/template/$template" || exit
 400
 401 # CFLAGS are selected so:
 402 # If the user specifies something in the environment, that is used.
 403 # else:  If the template file set something, that is used.
 404 # else:  If coverage was enabled, don't set anything.
 405 # else:  If the compiler is GCC, then we use -O2.
 406 # else:  If the compiler is something else, then we use -O, unless debugging.
 407
 408 if test "$ac_env_CFLAGS_set" = set; then
 409   CFLAGS=$ac_env_CFLAGS_value
 410 elif test "${CFLAGS+set}" = set; then
 411   : # (keep what template set)
 412 elif test "$enable_coverage" = yes; then
 413   : # no optimization by default
 414 elif test "$GCC" = yes; then
 415   CFLAGS="-O2"
 416 else
 417   # if the user selected debug mode, don't use -O
 418   if test "$enable_debug" != yes; then
 419     CFLAGS="-O"
 420   fi
 421 fi
 422
 423 # Some versions of GCC support some additional useful warning flags.
 424 # Check whether they are supported, and add them to CFLAGS if so.
 425 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 426 # but has its own.  Also check other compiler-specific flags here.
 427
 428 if test "$GCC" = yes -a "$ICC" = no; then
 429   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 430   # These work in some but not all gcc versions
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 432   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 433   # This was included in -Wall/-Wformat in older GCC versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 435   # Disable strict-aliasing rules; needed for gcc 3.3+
 436   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 437   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 438   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 439 elif test "$ICC" = yes; then
 440   # Intel's compiler has a bug/misoptimization in checking for
 441   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 442   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 443   # Make sure strict aliasing is off (though this is said to be the default)
 444   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 445 elif test "$PORTNAME" = "aix"; then
 446   # AIX's xlc has to have strict aliasing turned off too
 447   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 448 elif test "$PORTNAME" = "hpux"; then
 449   # On some versions of HP-UX, libm functions do not set errno by default.
 450   # Fix that by using +Olibmerrno if the compiler recognizes it.
 451   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 452 fi
 453
 454 # supply -g if --enable-debug
 455 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 456   CFLAGS="$CFLAGS -g"
 457 fi
 458
 459 # enable code coverage if --enable-coverage
 460 if test "$enable_coverage" = yes; then
 461   if test "$GCC" = yes; then
 462     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 463   else
 464     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 465   fi
 466 fi
 467
 468 # enable profiling if --enable-profiling
 469 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 470   if test "$GCC" = yes; then
 471     AC_DEFINE([PROFILE_PID_DIR], 1,
 472            [Define to 1 to allow profiling output to be saved separately for each process.])
 473     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 474   else
 475     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 476   fi
 477 fi
 478
 479 # We already have this in Makefile.win32, but configure needs it too
 480 if test "$PORTNAME" = "win32"; then
 481   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 482 fi
 483
 484 # Check if the compiler still works with the template settings
 485 AC_MSG_CHECKING([whether the C compiler still works])
 486 AC_TRY_LINK([], [return 0;],
 487   [AC_MSG_RESULT(yes)],
 488   [AC_MSG_RESULT(no)
 489    AC_MSG_ERROR([cannot proceed])])
 490
 491 # Defend against gcc -ffast-math
 492 if test "$GCC" = yes; then
 493 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 494 choke me
 495 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 496 fi
 497
 498 AC_PROG_CPP
 499 AC_SUBST(GCC)
 500
 501
 502 #
 503 # Set up TAS assembly code if needed; the template file has now had its
 504 # chance to request this.
 505 #
 506 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 507
 508 if test "$need_tas" = yes ; then
 509   TAS=tas.o
 510 else
 511   TAS=""
 512 fi
 513 AC_SUBST(TAS)
 514
 515
 516 #
 517 # Automatic dependency tracking
 518 #
 519 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 520               [autodepend=yes])
 521 AC_SUBST(autodepend)
 522
 523
 524 #
 525 # Enable assert checks
 526 #
 527 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 528               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 529                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 530
 531
 532 #
 533 # Include directories
 534 #
 535 ac_save_IFS=$IFS
 536 IFS="${IFS}${PATH_SEPARATOR}"
 537 # SRCH_INC comes from the template file
 538 for dir in $with_includes $SRCH_INC; do
 539   if test -d "$dir"; then
 540     INCLUDES="$INCLUDES -I$dir"
 541   else
 542     AC_MSG_WARN([*** Include directory $dir does not exist.])
 543   fi
 544 done
 545 IFS=$ac_save_IFS
 546 AC_SUBST(INCLUDES)
 547
 548
 549 #
 550 # Library directories
 551 #
 552 ac_save_IFS=$IFS
 553 IFS="${IFS}${PATH_SEPARATOR}"
 554 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 555 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 556   if test -d "$dir"; then
 557     LIBDIRS="$LIBDIRS -L$dir"
 558   else
 559     AC_MSG_WARN([*** Library directory $dir does not exist.])
 560   fi
 561 done
 562 IFS=$ac_save_IFS
 563
 564 #
 565 # Enable thread-safe client libraries
 566 #
 567 AC_MSG_CHECKING([allow thread-safe client libraries])
 568 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 569 if test "$enable_thread_safety" = yes; then
 570   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 571           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 572 fi
 573 AC_MSG_RESULT([$enable_thread_safety])
 574 AC_SUBST(enable_thread_safety)
 575
 576 #
 577 # Optionally build Tcl modules (PL/Tcl)
 578 #
 579 AC_MSG_CHECKING([whether to build with Tcl])
 580 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 581 AC_MSG_RESULT([$with_tcl])
 582 AC_SUBST([with_tcl])
 583
 584 # We see if the path to the Tcl/Tk configuration scripts is specified.
 585 # This will override the use of tclsh to find the paths to search.
 586
 587 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 588
 589 #
 590 # Optionally build Perl modules (PL/Perl)
 591 #
 592 AC_MSG_CHECKING([whether to build Perl modules])
 593 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 594 AC_MSG_RESULT([$with_perl])
 595 AC_SUBST(with_perl)
 596
 597 #
 598 # Optionally build Python modules (PL/Python)
 599 #
 600 AC_MSG_CHECKING([whether to build Python modules])
 601 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 602 AC_MSG_RESULT([$with_python])
 603 AC_SUBST(with_python)
 604
 605 #
 606 # GSSAPI
 607 #
 608 AC_MSG_CHECKING([whether to build with GSSAPI support])
 609 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 610 [
 611   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 612   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 613 ])
 614 AC_MSG_RESULT([$with_gssapi])
 615 AC_SUBST(with_gssapi)
 616
 617 #
 618 # Kerberos 5
 619 #
 620 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 621 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 622 [
 623   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 624   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 625 ])
 626 AC_MSG_RESULT([$with_krb5])
 627 AC_SUBST(with_krb5)
 628
 629
 630 AC_SUBST(krb_srvtab)
 631
 632
 633 #
 634 # Kerberos configuration parameters
 635 #
 636 PGAC_ARG_REQ(with, krb-srvnam,
 637              [NAME], [default service principal name in Kerberos [postgres]],
 638              [],
 639              [with_krb_srvnam="postgres"])
 640 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 641                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 642
 643
 644 #
 645 # PAM
 646 #
 647 AC_MSG_CHECKING([whether to build with PAM support])
 648 PGAC_ARG_BOOL(with, pam, no,
 649               [build with PAM support],
 650               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 651 AC_MSG_RESULT([$with_pam])
 652 AC_SUBST(with_pam)
 653
 654
 655 #
 656 # LDAP
 657 #
 658 AC_MSG_CHECKING([whether to build with LDAP support])
 659 PGAC_ARG_BOOL(with, ldap, no,
 660               [build with LDAP support],
 661               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 662 AC_MSG_RESULT([$with_ldap])
 663 AC_SUBST(with_ldap)
 664
 665
 666 #
 667 # Bonjour
 668 #
 669 AC_MSG_CHECKING([whether to build with Bonjour support])
 670 PGAC_ARG_BOOL(with, bonjour, no,
 671               [build with Bonjour support],
 672               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 673 AC_MSG_RESULT([$with_bonjour])
 674 AC_SUBST(with_bonjour)
 675
 676
 677 #
 678 # OpenSSL
 679 #
 680 AC_MSG_CHECKING([whether to build with OpenSSL support])
 681 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 682               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 683 AC_MSG_RESULT([$with_openssl])
 684 AC_SUBST(with_openssl)
 685
 686 #
 687 # SELinux
 688 #
 689 AC_MSG_CHECKING([whether to build with SELinux support])
 690 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 691 AC_SUBST(with_selinux)
 692 AC_MSG_RESULT([$with_selinux])
 693
 694 #
 695 # Readline
 696 #
 697 PGAC_ARG_BOOL(with, readline, yes,
 698               [do not use GNU Readline nor BSD Libedit for editing])
 699 # readline on MinGW has problems with backslashes in psql and other bugs.
 700 # This is particularly a problem with non-US code pages.
 701 # Therefore disable its use until we understand the cause. 2004-07-20
 702 if test "$PORTNAME" = "win32"; then
 703   if test "$with_readline" = yes; then
 704     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 705     with_readline=no
 706   fi
 707 fi
 708
 709
 710 #
 711 # Prefer libedit
 712 #
 713 PGAC_ARG_BOOL(with, libedit-preferred, no,
 714               [prefer BSD Libedit over GNU Readline])
 715
 716
 717 #
 718 # OSSP UUID library
 719 #
 720 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 721 AC_SUBST(with_ossp_uuid)
 722
 723
 724 #
 725 # XML
 726 #
 727 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 728               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 729
 730 if test "$with_libxml" = yes ; then
 731   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 732   if test -n "$XML2_CONFIG"; then
 733     for pgac_option in `$XML2_CONFIG --cflags`; do
 734       case $pgac_option in
 735         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 736       esac
 737     done
 738     for pgac_option in `$XML2_CONFIG --libs`; do
 739       case $pgac_option in
 740         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 741       esac
 742     done
 743   fi
 744 fi
 745
 746 AC_SUBST(with_libxml)
 747
 748 #
 749 # XSLT
 750 #
 751 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 752               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 753
 754
 755 AC_SUBST(with_libxslt)
 756
 757 #
 758 # tzdata
 759 #
 760 PGAC_ARG_REQ(with, system-tzdata,
 761              [DIR], [use system time zone data in DIR])
 762 AC_SUBST(with_system_tzdata)
 763
 764 #
 765 # Zlib
 766 #
 767 PGAC_ARG_BOOL(with, zlib, yes,
 768               [do not use Zlib])
 769 AC_SUBST(with_zlib)
 770
 771 #
 772 # Elf
 773 #
 774
 775 # Assume system is ELF if it predefines __ELF__ as 1,
 776 # otherwise believe host_os based default.
 777 case $host_os in
 778     freebsd1*|freebsd2*) elf=no;;
 779     freebsd3*|freebsd4*) elf=yes;;
 780 esac
 781
 782 AC_EGREP_CPP(yes,
 783 [#if __ELF__
 784   yes
 785 #endif
 786 ],
 787 [ELF_SYS=true],
 788 [if test "X$elf" = "Xyes" ; then
 789   ELF_SYS=true
 790 else
 791   ELF_SYS=
 792 fi])
 793 AC_SUBST(ELF_SYS)
 794
 795 #
 796 # Assignments
 797 #
 798
 799 CPPFLAGS="$CPPFLAGS $INCLUDES"
 800 LDFLAGS="$LDFLAGS $LIBDIRS"
 801
 802 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 803 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 804
 805 PGAC_PROG_LD
 806 AC_SUBST(LD)
 807 AC_SUBST(with_gnu_ld)
 808 case $host_os in sysv5*)
 809   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 810   [
 811     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 812     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 813     LDFLAGS=$pgac_save_LDFLAGS
 814   ])
 815   ld_R_works=$pgac_cv_prog_ld_R
 816   AC_SUBST(ld_R_works)
 817 esac
 818 AC_PROG_RANLIB
 819 PGAC_CHECK_STRIP
 820 AC_CHECK_TOOL(AR, ar, ar)
 821 if test "$PORTNAME" = "win32"; then
 822   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 823   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 824   AC_CHECK_TOOL(WINDRES, windres, windres)
 825 fi
 826
 827 AC_PATH_PROG(TAR, tar)
 828 AC_PROG_LN_S
 829 AC_PROG_AWK
 830 AC_PROG_MKDIR_P
 831 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 832 # a relative path to it in each makefile where it subsitutes it. This clashes
 833 # with our Makefile.global concept. This workaround helps.
 834 case $MKDIR_P in
 835   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 836 esac
 837
 838 PGAC_PATH_BISON
 839 PGAC_PATH_FLEX
 840
 841 PGAC_PATH_PERL
 842 if test "$with_perl" = yes; then
 843   if test -z "$PERL"; then
 844     AC_MSG_ERROR([Perl not found])
 845   fi
 846   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 847   PGAC_CHECK_PERL_EMBED_LDFLAGS
 848 fi
 849
 850 if test "$with_python" = yes; then
 851   PGAC_PATH_PYTHON
 852   PGAC_CHECK_PYTHON_EMBED_SETUP
 853 fi
 854
 855 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 856   AC_PATH_PROG(ZIC, zic)
 857   if test -z "$ZIC"; then
 858     AC_MSG_ERROR([
 859 When cross-compiling, either use the option --with-system-tzdata to use
 860 existing time-zone data, or set the environment variable ZIC to a zic
 861 program to use during the build.])
 862   fi
 863 fi
 864
 865
 866 ##
 867 ## Libraries
 868 ##
 869 ## Most libraries are included only if they demonstrably provide a function
 870 ## we need, but libm is an exception: always include it, because there are
 871 ## too many compilers that play cute optimization games that will break
 872 ## probes for standard functions such as pow().
 873 ##
 874
 875 AC_CHECK_LIB(m, main)
 876 AC_SEARCH_LIBS(setproctitle, util)
 877 AC_SEARCH_LIBS(dlopen, dl)
 878 AC_SEARCH_LIBS(socket, [socket wsock32])
 879 AC_SEARCH_LIBS(shl_load, dld)
 880 # We only use libld in port/dynloader/aix.c
 881 case $host_os in
 882      aix*)
 883         AC_SEARCH_LIBS(ldopen, ld)
 884         ;;
 885 esac
 886 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 887 AC_SEARCH_LIBS(crypt, crypt)
 888 # Solaris:
 889 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 890 # Required for thread_test.c on Solaris 2.5:
 891 # Other ports use it too (HP-UX) so test unconditionally
 892 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 893 # Cygwin:
 894 AC_SEARCH_LIBS(shmget, cygipc)
 895
 896 if test "$with_readline" = yes; then
 897   PGAC_CHECK_READLINE
 898   if test x"$pgac_cv_check_readline" = x"no"; then
 899     AC_MSG_ERROR([readline library not found
 900 If you have readline already installed, see config.log for details on the
 901 failure.  It is possible the compiler isn't looking in the proper directory.
 902 Use --without-readline to disable readline support.])
 903   fi
 904 fi
 905
 906 if test "$with_zlib" = yes; then
 907   AC_CHECK_LIB(z, inflate, [],
 908                [AC_MSG_ERROR([zlib library not found
 909 If you have zlib already installed, see config.log for details on the
 910 failure.  It is possible the compiler isn't looking in the proper directory.
 911 Use --without-zlib to disable zlib support.])])
 912 fi
 913
 914 if test "$enable_spinlocks" = yes; then
 915   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 916 else
 917   AC_MSG_WARN([
 918 *** Not using spinlocks will cause poor performance.])
 919 fi
 920
 921 if test "$with_gssapi" = yes ; then
 922   if test "$PORTNAME" != "win32"; then
 923     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 924                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 925   else
 926     LIBS="$LIBS -lgssapi32"
 927   fi
 928 fi
 929
 930 if test "$with_krb5" = yes ; then
 931   if test "$PORTNAME" != "win32"; then
 932      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 933                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 934      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 935                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 936   else
 937      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 938                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 939   fi
 940 fi
 941
 942 if test "$with_openssl" = yes ; then
 943   dnl Order matters!
 944   if test "$PORTNAME" != "win32"; then
 945      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 946      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 947   else
 948      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 949      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 950   fi
 951 fi
 952
 953 if test "$with_pam" = yes ; then
 954   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 955 fi
 956
 957 if test "$with_libxml" = yes ; then
 958   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 959 fi
 960
 961 if test "$with_libxslt" = yes ; then
 962   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 963 fi
 964
 965 # for contrib/sepgsql
 966 if test "$with_selinux" = yes; then
 967   AC_CHECK_LIB(selinux, selinux_sepgsql_context_path, [],
 968                [AC_MSG_ERROR([library 'libselinux', version 2.0.93 or newer, is required for SELinux support])])
 969 fi
 970
 971 # for contrib/uuid-ossp
 972 if test "$with_ossp_uuid" = yes ; then
 973   AC_CHECK_LIB(ossp-uuid, uuid_export,
 974     [OSSP_UUID_LIBS="-lossp-uuid"],
 975     [AC_CHECK_LIB(uuid, uuid_export,
 976       [OSSP_UUID_LIBS="-luuid"],
 977       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 978 fi
 979 AC_SUBST(OSSP_UUID_LIBS)
 980
 981
 982 ##
 983 ## Header files
 984 ##
 985
 986 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 987 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/ucred.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 988
 989 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 990 # is included first.
 991 AC_CHECK_HEADERS(net/if.h, [], [],
 992 [AC_INCLUDES_DEFAULT
 993 #ifdef HAVE_SYS_SOCKET_H
 994 #include <sys/socket.h>
 995 #endif
 996 ])
 997
 998 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 999 # netinet/in.h is included first.
1000 AC_CHECK_HEADERS(netinet/in.h)
1001 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1002 [AC_INCLUDES_DEFAULT
1003 #ifdef HAVE_NETINET_IN_H
1004 #include <netinet/in.h>
1005 #endif
1006 ])
1007
1008 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1009   AC_CHECK_HEADERS(readline/readline.h, [],
1010         [AC_CHECK_HEADERS(readline.h, [],
1011                 [AC_MSG_ERROR([readline header not found
1012 If you have readline already installed, see config.log for details on the
1013 failure.  It is possible the compiler isn't looking in the proper directory.
1014 Use --without-readline to disable readline support.])])])
1015   AC_CHECK_HEADERS(readline/history.h, [],
1016         [AC_CHECK_HEADERS(history.h, [],
1017                 [AC_MSG_ERROR([history header not found
1018 If you have readline already installed, see config.log for details on the
1019 failure.  It is possible the compiler isn't looking in the proper directory.
1020 Use --without-readline to disable readline support.])])])
1021 fi
1022
1023 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1024 # Some installations of libedit usurp /usr/include/readline/, which seems
1025 # bad practice, since in combined installations readline will have its headers
1026 # there.  We might have to resort to AC_EGREP checks to make sure we found
1027 # the proper header...
1028   AC_CHECK_HEADERS(editline/readline.h, [],
1029         [AC_CHECK_HEADERS(readline.h, [],
1030                 [AC_CHECK_HEADERS(readline/readline.h, [],
1031                         [AC_MSG_ERROR([readline header not found
1032 If you have libedit already installed, see config.log for details on the
1033 failure.  It is possible the compiler isn't looking in the proper directory.
1034 Use --without-readline to disable libedit support.])])])])
1035 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1036 # not be there at all.  Hence, don't complain if not found.  We must check
1037 # though, since in yet other versions it is an independent header.
1038   AC_CHECK_HEADERS(editline/history.h, [],
1039         [AC_CHECK_HEADERS(history.h, [],
1040                 [AC_CHECK_HEADERS(readline/history.h)])])
1041 fi
1042
1043 if test "$with_zlib" = yes; then
1044   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1045 If you have zlib already installed, see config.log for details on the
1046 failure.  It is possible the compiler isn't looking in the proper directory.
1047 Use --without-zlib to disable zlib support.])])
1048 fi
1049
1050 if test "$with_gssapi" = yes ; then
1051   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1052         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1053 fi
1054
1055 if test "$with_krb5" = yes ; then
1056   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1057 fi
1058
1059 if test "$with_openssl" = yes ; then
1060   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1061   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1062   AC_CHECK_FUNCS([ERR_set_mark])
1063 fi
1064
1065 if test "$with_pam" = yes ; then
1066   AC_CHECK_HEADERS(security/pam_appl.h, [],
1067                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1068                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1069 fi
1070
1071 if test "$with_libxml" = yes ; then
1072   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1073 fi
1074
1075 if test "$with_libxslt" = yes ; then
1076   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1077 fi
1078
1079 if test "$with_ldap" = yes ; then
1080   if test "$PORTNAME" != "win32"; then
1081      AC_CHECK_HEADERS(ldap.h, [],
1082                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1083   else
1084      AC_CHECK_HEADERS(winldap.h, [],
1085                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1086                       [AC_INCLUDES_DEFAULT
1087 #include <windows.h>
1088                       ])
1089   fi
1090 fi
1091
1092 if test "$with_bonjour" = yes ; then
1093   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1094 fi
1095
1096 # for contrib/uuid-ossp
1097 if test "$with_ossp_uuid" = yes ; then
1098   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1099     AC_CHECK_HEADERS(uuid.h, [],
1100       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1101 fi
1102
1103
1104 ##
1105 ## Types, structures, compiler characteristics
1106 ##
1107
1108 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1109 AC_C_BIGENDIAN
1110 AC_C_CONST
1111 PGAC_C_INLINE
1112 AC_C_STRINGIZE
1113 AC_C_FLEXIBLE_ARRAY_MEMBER
1114 PGAC_C_SIGNED
1115 AC_C_VOLATILE
1116 PGAC_C_FUNCNAME_SUPPORT
1117 PGAC_STRUCT_TIMEZONE
1118 PGAC_UNION_SEMUN
1119 PGAC_STRUCT_SOCKADDR_UN
1120 PGAC_STRUCT_SOCKADDR_STORAGE
1121 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1122 PGAC_STRUCT_ADDRINFO
1123 AC_TYPE_INTPTR_T
1124 AC_TYPE_UINTPTR_T
1125 AC_TYPE_LONG_LONG_INT
1126
1127 PGAC_TYPE_LOCALE_T
1128
1129 AC_CHECK_TYPES([struct cmsgcred], [], [],
1130 [#include <sys/socket.h>
1131 #ifdef HAVE_SYS_UCRED_H
1132 #include <sys/ucred.h>
1133 #endif])
1134
1135 AC_CHECK_TYPES([struct option], [], [],
1136 [#ifdef HAVE_GETOPT_H
1137 #include <getopt.h>
1138 #endif])
1139
1140 if test "$with_zlib" = yes; then
1141   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1142   # did not).  While we could work around the lack of z_streamp, it
1143   # seems unwise to encourage people to use such old zlib versions...
1144   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1145 Use --without-zlib to disable zlib support.])],
1146                 [#include <zlib.h>])
1147 fi
1148
1149 if test "$with_krb5" = yes; then
1150 # Check for differences between MIT and Heimdal (KTH) releases
1151   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1152                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1153                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1154                                      [#include <krb5.h>])],
1155                    [#include <krb5.h>])
1156   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1157                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1158                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1159                                      [#include <krb5.h>])],
1160                    [#include <krb5.h>])
1161
1162 # Win32 requires headers to be loaded for __stdcall, so can't use
1163 # AC_CHECK_FUNCS here.
1164   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1165   AC_TRY_LINK([#include <krb5.h>],
1166               [krb5_free_unparsed_name(NULL,NULL);],
1167               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1168 AC_MSG_RESULT(yes)],
1169               [AC_MSG_RESULT(no)])
1170 fi
1171
1172 # Check largefile support.  You might think this is a system service not a
1173 # compiler characteristic, but you'd be wrong.  We must check this before
1174 # probing existence of related functions such as fseeko, since the largefile
1175 # defines can affect what is generated for that.
1176 AC_SYS_LARGEFILE
1177
1178 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1179 AC_CHECK_SIZEOF([off_t])
1180
1181 # If we don't have largefile support, can't handle segsize >= 2GB.
1182 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1183    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1184 fi
1185
1186
1187 ##
1188 ## Functions, global variables
1189 ##
1190
1191 PGAC_VAR_INT_TIMEZONE
1192 AC_FUNC_ACCEPT_ARGTYPES
1193 PGAC_FUNC_GETTIMEOFDAY_1ARG
1194
1195 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeerucred getrlimit memmove poll pstat readlink scandir setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs wcstombs_l])
1196
1197 AC_REPLACE_FUNCS(fseeko)
1198 case $host_os in
1199         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1200         # Mingw uses macros to access Win32 API calls
1201         bsdi*|netbsd*|mingw*)
1202                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1203                 ac_cv_func_fseeko=yes;;
1204         *)
1205                 AC_FUNC_FSEEKO;;
1206 esac
1207
1208 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1209 # by calling it, 2009-04-02
1210 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1211 if test "$PORTNAME" != "solaris"; then
1212 AC_CHECK_FUNCS(posix_fadvise)
1213 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1214 fi
1215
1216 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1217 AC_CHECK_DECLS([strlcat, strlcpy])
1218 # This is probably only present on Darwin, but may as well check always
1219 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1220
1221 HAVE_IPV6=no
1222 AC_CHECK_TYPE([struct sockaddr_in6],
1223         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1224          HAVE_IPV6=yes],
1225         [],
1226 [$ac_includes_default
1227 #include <netinet/in.h>])
1228 AC_SUBST(HAVE_IPV6)
1229
1230 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1231 [AC_TRY_LINK(
1232 [#include <machine/vmparam.h>
1233 #include <sys/exec.h>
1234 ],
1235 [PS_STRINGS->ps_nargvstr = 1;
1236 PS_STRINGS->ps_argvstr = "foo";],
1237 [pgac_cv_var_PS_STRINGS=yes],
1238 [pgac_cv_var_PS_STRINGS=no])])
1239 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1240   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1241 fi
1242
1243
1244 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1245 # is missing.  Yes, there are machines that have only one.  We may
1246 # also decide to use snprintf.c if snprintf() is present but does not
1247 # have all the features we need --- see below.
1248
1249 if test "$PORTNAME" = "win32"; then
1250   # Win32 gets snprintf.c built unconditionally.
1251   #
1252   # To properly translate all NLS languages strings, we must support the
1253   # *printf() %$ format, which allows *printf() arguments to be selected
1254   # by position in the translated string.
1255   #
1256   # libintl versions < 0.13 use the native *printf() functions, and Win32
1257   # *printf() doesn't understand %$, so we must use our /port versions,
1258   # which do understand %$. libintl versions >= 0.13 include their own
1259   # *printf versions on Win32.  The libintl 0.13 release note text is:
1260   #
1261   #   C format strings with positions, as they arise when a translator
1262   #   needs to reorder a sentence, are now supported on all platforms.
1263   #   On those few platforms (NetBSD and Woe32) for which the native
1264   #   printf()/fprintf()/... functions don't support such format
1265   #   strings, replacements are provided through <libintl.h>.
1266   #
1267   # We could use libintl >= 0.13's *printf() if we were sure that we had
1268   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1269   # to guarantee that, it is best to just use our own, so we are sure to
1270   # get %$ support. In include/port.h we disable the *printf() macros
1271   # that might have been defined by libintl.
1272   #
1273   # We do this unconditionally whether NLS is used or not so we are sure
1274   # that all Win32 libraries and binaries behave the same.
1275   pgac_need_repl_snprintf=yes
1276 else
1277   pgac_need_repl_snprintf=no
1278   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1279   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1280 fi
1281
1282
1283 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1284 # include/c.h will provide declarations.  Note this is a separate test
1285 # from whether the functions exist in the C library --- there are
1286 # systems that have the functions but don't bother to declare them :-(
1287
1288 AC_CHECK_DECLS([snprintf, vsnprintf])
1289
1290
1291 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1292 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1293 [AC_TRY_LINK([
1294 #include <math.h>
1295 double glob_double;
1296 ],
1297 [return isinf(glob_double) ? 0 : 1;],
1298 [ac_cv_func_isinf=yes],
1299 [ac_cv_func_isinf=no])])
1300
1301 if test $ac_cv_func_isinf = yes ; then
1302   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1303 else
1304   AC_LIBOBJ(isinf)
1305   # Look for a way to implement a substitute for isinf()
1306   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1307 fi
1308
1309 # Some versions of libedit contain strlcpy(); so disregard that library while
1310 # checking for these standard libc functions.
1311 pgac_save_LIBS="$LIBS"
1312 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1313
1314 AC_REPLACE_FUNCS([crypt erand48 getopt getpeereid getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul])
1315
1316 case $host_os in
1317
1318         # Windows uses a specialised env handler
1319         mingw*)
1320                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1321                 ac_cv_func_unsetenv=yes;;
1322         *)
1323                 AC_REPLACE_FUNCS([unsetenv])
1324                 ;;
1325 esac
1326
1327
1328 LIBS="$pgac_save_LIBS"
1329
1330 # System's version of getaddrinfo(), if any, may be used only if we found
1331 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1332 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1333 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1334 # because we want to use our own getaddrinfo.c on Windows anyway.)
1335 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1336   AC_REPLACE_FUNCS([getaddrinfo])
1337 else
1338   AC_LIBOBJ(getaddrinfo)
1339 fi
1340
1341 # Similarly, use system's getopt_long() only if system provides struct option.
1342 if test x"$ac_cv_type_struct_option" = xyes ; then
1343   AC_REPLACE_FUNCS([getopt_long])
1344 else
1345   AC_LIBOBJ(getopt_long)
1346 fi
1347
1348 # Solaris' getopt() doesn't do what we want for long options, so always use
1349 # our version on that platform.
1350 if test "$PORTNAME" = "solaris"; then
1351   AC_LIBOBJ(getopt)
1352 fi
1353
1354 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1355 # so always use our version on Windows.
1356 if test "$PORTNAME" = "win32"; then
1357   AC_LIBOBJ(getopt)
1358   AC_LIBOBJ(getopt_long)
1359 fi
1360
1361 # Cygwin's erand48() is broken (always returns zero) in some releases,
1362 # so force use of ours.
1363 if test "$PORTNAME" = "cygwin"; then
1364   AC_LIBOBJ(erand48)
1365 fi
1366
1367 # Win32 support
1368 if test "$PORTNAME" = "win32"; then
1369   AC_REPLACE_FUNCS(gettimeofday)
1370   AC_LIBOBJ(kill)
1371   AC_LIBOBJ(open)
1372   AC_LIBOBJ(win32env)
1373   AC_LIBOBJ(win32error)
1374   AC_DEFINE([HAVE_SYMLINK], 1,
1375             [Define to 1 if you have the `symlink' function.])
1376   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1377 #define WIN32_LEAN_AND_MEAN
1378 #include <windows.h>
1379 #include <string.h>
1380 #include <dbghelp.h>])
1381 fi
1382 if test x"$pgac_minidump_type" = x"yes" ; then
1383   AC_SUBST(have_win32_dbghelp,yes)
1384 else
1385   AC_SUBST(have_win32_dbghelp,no)
1386 fi
1387
1388 if test "$with_readline" = yes; then
1389   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1390   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1391   AC_CHECK_FUNCS([append_history history_truncate_file])
1392 fi
1393
1394
1395 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1396 dnl (especially on GNU libc)
1397 dnl See also comments in c.h.
1398 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1399 [AC_TRY_LINK([#include <setjmp.h>],
1400             [sigjmp_buf x; sigsetjmp(x, 1);],
1401             [pgac_cv_func_sigsetjmp=yes],
1402             [pgac_cv_func_sigsetjmp=no])])
1403 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1404   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1405 fi
1406
1407 AC_DECL_SYS_SIGLIST
1408
1409 AC_CHECK_FUNC(syslog,
1410               [AC_CHECK_HEADER(syslog.h,
1411                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1412
1413 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1414 [AC_TRY_LINK([#include <unistd.h>],
1415   [extern int opterr; opterr = 1;],
1416   [pgac_cv_var_int_opterr=yes],
1417   [pgac_cv_var_int_opterr=no])])
1418 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1419   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1420 fi
1421
1422 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1423 [AC_TRY_LINK([#include <unistd.h>],
1424   [extern int optreset; optreset = 1;],
1425   [pgac_cv_var_int_optreset=yes],
1426   [pgac_cv_var_int_optreset=no])])
1427 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1428   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1429 fi
1430
1431 AC_CHECK_FUNCS([strtoll strtoq], [break])
1432 AC_CHECK_FUNCS([strtoull strtouq], [break])
1433
1434 # Check for one of atexit() or on_exit()
1435 AC_CHECK_FUNCS(atexit, [],
1436                [AC_CHECK_FUNCS(on_exit, [],
1437                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1438
1439
1440 #
1441 # Pthreads
1442 #
1443 # For each platform, we need to know about any special compile and link
1444 # libraries, and whether the normal C function names are thread-safe.
1445 # See the comment at the top of src/port/thread.c for more information.
1446 # WIN32 doesn't need the pthread tests;  it always uses threads
1447 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1448 ACX_PTHREAD     # set thread flags
1449
1450 # Some platforms use these, so just define them.  They can't hurt if they
1451 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1452 # enables 5-arg getpwuid_r, among other things.
1453 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1454
1455
1456 # At this point, we don't want to muck with the compiler name for threading.
1457 # Let's see who fails, perhaps AIX.  2004-04-23
1458 if test "$PTHREAD_CC" != "$CC"; then
1459 AC_MSG_ERROR([
1460 PostgreSQL does not support platforms that require a special compiler
1461 for thread safety;  use --disable-thread-safety to disable thread safety.])
1462 fi
1463
1464 # Check for *_r functions
1465 _CFLAGS="$CFLAGS"
1466 _LIBS="$LIBS"
1467 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1468 LIBS="$LIBS $PTHREAD_LIBS"
1469
1470 if test "$PORTNAME" != "win32"; then
1471 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1472 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1473 fi
1474
1475 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1476
1477 # Do test here with the proper thread flags
1478 PGAC_FUNC_GETPWUID_R_5ARG
1479 PGAC_FUNC_STRERROR_R_INT
1480
1481 CFLAGS="$_CFLAGS"
1482 LIBS="$_LIBS"
1483
1484 else
1485 # do not use values from template file
1486 PTHREAD_CFLAGS=
1487 PTHREAD_LIBS=
1488 fi
1489
1490 AC_SUBST(PTHREAD_CFLAGS)
1491 AC_SUBST(PTHREAD_LIBS)
1492
1493
1494 # We can test for libldap_r only after we know PTHREAD_LIBS
1495 if test "$with_ldap" = yes ; then
1496   _LIBS="$LIBS"
1497   if test "$PORTNAME" != "win32"; then
1498     AC_CHECK_LIB(ldap, ldap_bind, [],
1499                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1500                  [$EXTRA_LDAP_LIBS])
1501     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1502     if test "$enable_thread_safety" = yes; then
1503       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1504       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1505                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1506                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1507       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1508     else
1509       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1510     fi
1511   else
1512     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1513     LDAP_LIBS_FE="-lwldap32"
1514     LDAP_LIBS_BE="-lwldap32"
1515   fi
1516   LIBS="$_LIBS"
1517 fi
1518 AC_SUBST(LDAP_LIBS_FE)
1519 AC_SUBST(LDAP_LIBS_BE)
1520
1521
1522 # This test makes sure that run tests work at all.  Sometimes a shared
1523 # library is found by the linker, but the runtime linker can't find it.
1524 # This check should come after all modifications of compiler or linker
1525 # variables, and before any other run tests.
1526 AC_MSG_CHECKING([test program])
1527 AC_TRY_RUN([int main() { return 0; }],
1528 [AC_MSG_RESULT(ok)],
1529 [AC_MSG_RESULT(failed)
1530 AC_MSG_ERROR([[
1531 Could not execute a simple test program.  This may be a problem
1532 related to locating shared libraries.  Check the file 'config.log'
1533 for the exact reason.]])],
1534 [AC_MSG_RESULT([cross-compiling])])
1535
1536 # --------------------
1537 # Run tests below here
1538 # --------------------
1539
1540 # Force use of our snprintf if system's doesn't do arg control
1541 # See comment above at snprintf test for details.
1542 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1543   PGAC_FUNC_PRINTF_ARG_CONTROL
1544   if test $pgac_cv_printf_arg_control != yes ; then
1545     pgac_need_repl_snprintf=yes
1546   fi
1547 fi
1548
1549
1550 dnl Check to see if we have a working 64-bit integer type.
1551 dnl This breaks down into two steps:
1552 dnl (1) figure out if the compiler has a 64-bit int type with working
1553 dnl arithmetic, and if so
1554 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1555 dnl snprintf is the only library routine we really need for int8 support.)
1556 dnl It's entirely possible to have a compiler that handles a 64-bit type
1557 dnl when the C library doesn't; this is fairly likely when using gcc on
1558 dnl an older platform, for example.
1559 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1560 dnl we force our own version of snprintf() to be used instead.
1561 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1562
1563 dnl As of Postgres 8.4, we no longer support compilers without a working
1564 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1565
1566 PGAC_TYPE_64BIT_INT([long int])
1567
1568 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1569   PGAC_TYPE_64BIT_INT([long long int])
1570   if test x"$HAVE_LONG_LONG_INT_64" = x"no" ; then
1571     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1572   fi
1573 fi
1574
1575
1576 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1577
1578 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1579   AC_TRY_COMPILE([
1580 #define INT64CONST(x)  x##LL
1581 long long int foo = INT64CONST(0x1234567890123456);
1582 ],
1583         [],
1584         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1585         [])
1586 fi
1587
1588
1589 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1590 # we found we need to use "long long int", better check.  We cope with
1591 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1592 # work, fall back to our own snprintf emulation (which we know uses %lld).
1593
1594 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1595   if test $pgac_need_repl_snprintf = no; then
1596     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1597     if test "$LONG_LONG_INT_FORMAT" = ""; then
1598       # Force usage of our own snprintf, since system snprintf is broken
1599       pgac_need_repl_snprintf=yes
1600       LONG_LONG_INT_FORMAT='%lld'
1601     fi
1602   else
1603     # Here if we previously decided we needed to use our own snprintf
1604     LONG_LONG_INT_FORMAT='%lld'
1605   fi
1606   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1607   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1608   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1609 else
1610   # Here if we are not using 'long long int' at all
1611   INT64_FORMAT='"%ld"'
1612   UINT64_FORMAT='"%lu"'
1613 fi
1614
1615 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1616                    [Define to the appropriate snprintf format for 64-bit ints.])
1617
1618 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1619                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1620
1621 # Now we have checked all the reasons to replace snprintf
1622 if test $pgac_need_repl_snprintf = yes; then
1623   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1624   AC_LIBOBJ(snprintf)
1625 fi
1626
1627 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1628 AC_CHECK_SIZEOF([void *])
1629 AC_CHECK_SIZEOF([size_t])
1630 AC_CHECK_SIZEOF([long])
1631
1632 # Decide whether float4 is passed by value: user-selectable, enabled by default
1633 AC_MSG_CHECKING([whether to build with float4 passed by value])
1634 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1635               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1636                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1637                float4passbyval=true],
1638               [float4passbyval=false])
1639 AC_MSG_RESULT([$enable_float4_byval])
1640 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1641
1642 # Decide whether float8 is passed by value.
1643 # Note: this setting also controls int8 and related types such as timestamp.
1644 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1645 # If not, trying to select it is an error.
1646 AC_MSG_CHECKING([whether to build with float8 passed by value])
1647 if test $ac_cv_sizeof_void_p -ge 8 ; then
1648   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1649 else
1650   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1651   if test "$enable_float8_byval" = yes ; then
1652     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1653   fi
1654 fi
1655 if test "$enable_float8_byval" = yes ; then
1656   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1657             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1658   float8passbyval=true
1659 else
1660   float8passbyval=false
1661 fi
1662 AC_MSG_RESULT([$enable_float8_byval])
1663 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1664
1665 # Determine memory alignment requirements for the basic C data types.
1666
1667 AC_CHECK_ALIGNOF(short)
1668 AC_CHECK_ALIGNOF(int)
1669 AC_CHECK_ALIGNOF(long)
1670 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1671   AC_CHECK_ALIGNOF(long long int)
1672 fi
1673 AC_CHECK_ALIGNOF(double)
1674
1675 # Compute maximum alignment of any basic type.
1676 # We assume long's alignment is at least as strong as char, short, or int;
1677 # but we must check long long (if it exists) and double.
1678
1679 MAX_ALIGNOF=$ac_cv_alignof_long
1680 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1681   MAX_ALIGNOF=$ac_cv_alignof_double
1682 fi
1683 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1684   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1685 fi
1686 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1687
1688
1689 # Some platforms predefine the types int8, int16, etc.  Only check
1690 # a (hopefully) representative subset.
1691 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1692 [#include <stdio.h>
1693 #ifdef HAVE_SUPPORTDEFS_H
1694 #include <SupportDefs.h>
1695 #endif])
1696
1697 # We also check for sig_atomic_t, which *should* be defined per ANSI
1698 # C, but is missing on some old platforms.
1699 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1700
1701
1702 if test "$PORTNAME" != "win32"
1703 then
1704 PGAC_FUNC_POSIX_SIGNALS
1705 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1706   AC_MSG_ERROR([
1707 Thread-safety requires POSIX signals, which are not supported by this
1708 operating system;  use --disable-thread-safety to disable thread safety.])
1709 fi
1710 fi
1711
1712 # SunOS doesn't handle negative byte comparisons properly with +/- return
1713 AC_FUNC_MEMCMP
1714
1715
1716 # Select semaphore implementation type.
1717 if test "$PORTNAME" != "win32"; then
1718   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1719     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1720     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1721   else
1722     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1723       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1724       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1725     else
1726       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1727       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1728     fi
1729   fi
1730 else
1731   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1732   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1733 fi
1734
1735
1736 # Select shared-memory implementation type.
1737 if test "$PORTNAME" != "win32"; then
1738   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1739   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1740 else
1741   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1742   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1743 fi
1744
1745 # Select latch implementation type.
1746 if test "$PORTNAME" != "win32"; then
1747   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1748 else
1749   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1750 fi
1751
1752 # If not set in template file, set bytes to use libc memset()
1753 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1754   MEMSET_LOOP_LIMIT=1024
1755 fi
1756 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1757
1758
1759 if test "$enable_nls" = yes ; then
1760   PGAC_CHECK_GETTEXT
1761 fi
1762
1763 # Check for Tcl configuration script tclConfig.sh
1764 if test "$with_tcl" = yes; then
1765     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1766     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1767                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1768     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1769     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1770     ac_save_CPPFLAGS=$CPPFLAGS
1771     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1772     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1773     CPPFLAGS=$ac_save_CPPFLAGS
1774 fi
1775
1776 # check for <Python.h>
1777 if test "$with_python" = yes; then
1778   ac_save_CPPFLAGS=$CPPFLAGS
1779   CPPFLAGS="$python_includespec $CPPFLAGS"
1780   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1781   CPPFLAGS=$ac_save_CPPFLAGS
1782 fi
1783
1784 #
1785 # Check for DocBook and tools
1786 #
1787 PGAC_PROG_NSGMLS
1788 PGAC_PROG_JADE
1789 PGAC_CHECK_DOCBOOK(4.2)
1790 PGAC_PATH_DOCBOOK_STYLESHEETS
1791 PGAC_PATH_COLLATEINDEX
1792 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1793 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1794
1795 # Thread testing
1796
1797 # We have to run the thread test near the end so we have all our symbols
1798 # defined.  Cross compiling throws a warning.
1799 #
1800 if test "$enable_thread_safety" = yes; then
1801 if test "$PORTNAME" != "win32"
1802 then
1803 AC_MSG_CHECKING([thread safety of required library functions])
1804
1805 _CFLAGS="$CFLAGS"
1806 _LIBS="$LIBS"
1807 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1808 LIBS="$LIBS $PTHREAD_LIBS"
1809 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1810   [AC_MSG_RESULT(yes)],
1811   [AC_MSG_RESULT(no)
1812   AC_MSG_ERROR([thread test program failed
1813 This platform is not thread-safe.  Check the file 'config.log' or compile
1814 and run src/test/thread/thread_test for the exact reason.
1815 Use --disable-thread-safety to disable thread safety.])],
1816   [AC_MSG_RESULT(maybe)
1817   AC_MSG_WARN([
1818 *** Skipping thread test program because of cross-compile build.
1819 *** Run the program in src/test/thread on the target machine.
1820 ])])
1821 CFLAGS="$_CFLAGS"
1822 LIBS="$_LIBS"
1823 else
1824 AC_MSG_WARN([*** skipping thread test on Win32])
1825 fi
1826 fi
1827
1828 # If compiler will take -Wl,--as-needed (or various platform-specific
1829 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1830 # trying to filter LIBS to the minimum for each executable.
1831 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1832 # libreadline; therefore we postpone testing it until we know what library
1833 # dependencies readline has.  The test code will try to link with $LIBS.
1834 if test "$with_readline" = yes; then
1835   link_test_func=readline
1836 else
1837   link_test_func=exit
1838 fi
1839
1840 if test "$PORTNAME" = "darwin"; then
1841   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1842 elif test "$PORTNAME" = "openbsd"; then
1843   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1844 else
1845   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1846 fi
1847
1848
1849 # Begin output steps
1850
1851 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1852 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1853 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1854
1855 # Create compiler version string
1856 if test x"$GCC" = x"yes" ; then
1857   cc_string=`${CC} --version | sed q`
1858   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1859 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1860   cc_string=`${CC} -V 2>&1 | sed q`
1861 else
1862   cc_string=$CC
1863 fi
1864
1865 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1866                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1867                    [A string containing the version number, platform, and C compiler])
1868
1869 # Supply a numeric version string for use by 3rd party add-ons
1870 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1871 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1872 tr '.' '        ' |
1873 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1874 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1875
1876
1877 # prepare build tree if outside source tree
1878 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1879 # Note 2: /bin/pwd might be better than shell's built-in at getting
1880 #         a symlink-free name.
1881 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1882   vpath_build=no
1883 else
1884   vpath_build=yes
1885   if test "$no_create" != yes; then
1886     _AS_ECHO_N([preparing build tree... ])
1887     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1888     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1889       || AC_MSG_ERROR(failed)
1890     AC_MSG_RESULT(done)
1891   fi
1892 fi
1893 AC_SUBST(vpath_build)
1894
1895
1896 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1897
1898 AC_CONFIG_LINKS([
1899   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1900   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1901   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1902   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1903   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1904   src/include/pg_config_os.h:src/include/port/${template}.h
1905   src/Makefile.port:src/makefiles/Makefile.${template}
1906 ])
1907
1908 if test "$PORTNAME" = "win32"; then
1909 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1910 # Links sometimes fail undetected on Mingw -
1911 # so here we detect it and warn the user
1912 for FILE in $CONFIG_LINKS
1913  do
1914         # test -e works for symlinks in the MinGW console
1915         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1916  done
1917 ])
1918 fi
1919
1920 AC_CONFIG_HEADERS([src/include/pg_config.h],
1921 [
1922 # Update timestamp for pg_config.h (see Makefile.global)
1923 echo >src/include/stamp-h
1924 ])
1925
1926 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1927                   [echo >src/interfaces/ecpg/include/stamp-h])
1928
1929 AC_OUTPUT