configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.558 2008/05/02 01:08:26 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage: enabled by default.
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [  --disable-integer-datetimes  disable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   set default port number [[5432]]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [  --disable-shared        do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [  --disable-rpath         do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [  --disable-spinlocks     do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [  --enable-debug          build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [  --enable-profiling      build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # DTrace
 208 #
 209 PGAC_ARG_BOOL(enable, dtrace, no,
 210               [  --enable-dtrace         build with DTrace support],
 211 [AC_DEFINE([ENABLE_DTRACE], 1,
 212            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 213 AC_CHECK_PROGS(DTRACE, dtrace)
 214 if test -z "$DTRACE"; then
 215   AC_MSG_ERROR([dtrace not found])
 216 fi
 217 AC_SUBST(DTRACEFLAGS)])
 218 AC_SUBST(enable_dtrace)
 219
 220 #
 221 # Block size
 222 #
 223 AC_MSG_CHECKING([for block size])
 224 PGAC_ARG_REQ(with, blocksize, [  --with-blocksize=BLOCKSIZE  set block size in kB [[8]]],
 225              [blocksize=$withval],
 226              [blocksize=8])
 227 case ${blocksize} in
 228   1) BLCKSZ=1024;;
 229   2) BLCKSZ=2048;;
 230   4) BLCKSZ=4096;;
 231   8) BLCKSZ=8192;;
 232  16) BLCKSZ=16384;;
 233  32) BLCKSZ=32768;;
 234   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 235 esac
 236 AC_MSG_RESULT([${blocksize}kB])
 237
 238 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 239  Size of a disk block --- this also limits the size of a tuple.  You
 240  can set it bigger if you need bigger tuples (although TOAST should
 241  reduce the need to have large tuples, since fields can be spread
 242  across multiple tuples).
 243
 244  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 245  is currently 2^15 (32768).  This is determined by the 15-bit widths
 246  of the lp_off and lp_len fields in ItemIdData (see
 247  include/storage/itemid.h).
 248
 249  Changing BLCKSZ requires an initdb.
 250 ])
 251
 252 #
 253 # File segment size
 254 #
 255 AC_MSG_CHECKING([for segment size])
 256 PGAC_ARG_REQ(with, segsize, [  --with-segsize=SEGSIZE  set segment size in GB [[1]]],
 257              [segsize=$withval],
 258              [segsize=1])
 259 # this expression is set up to avoid unnecessary integer overflow
 260 RELSEG_SIZE=`expr '(' 1024 '*' ${segsize} / ${blocksize} ')' '*' 1024`
 261 test $? -eq 0 || exit 1
 262 AC_MSG_RESULT([${segsize}GB])
 263
 264 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 265  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 266  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 267  relations bigger than that are divided into multiple files.
 268
 269  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 270  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 271  have large file support enabled.  By default, we make the limit 1 GB
 272  to avoid any possible integer-overflow problems within the OS.
 273  A limit smaller than necessary only means we divide a large
 274  relation into more chunks than necessary, so it seems best to err
 275  in the direction of a small limit.
 276
 277  A power-of-2 value is recommended to save a few cycles in md.c,
 278  but is not absolutely required.
 279
 280  Changing RELSEG_SIZE requires an initdb.
 281 ])
 282
 283 #
 284 # C compiler
 285 #
 286
 287 # For historical reasons you can also use --with-CC to specify the C compiler
 288 # to use, although the standard way to do this is to set the CC environment
 289 # variable.
 290 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 291
 292 case $template in
 293   aix) pgac_cc_list="gcc xlc";;
 294  irix) pgac_cc_list="cc";; # no gcc
 295     *) pgac_cc_list="gcc cc";;
 296 esac
 297
 298 AC_PROG_CC([$pgac_cc_list])
 299
 300 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 301 # but has idiosyncrasies of its own.  We assume icc will define
 302 # __INTEL_COMPILER regardless of CFLAGS.
 303 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 304 choke me
 305 @%:@endif], [ICC=[yes]], [ICC=[no]])
 306
 307 unset CFLAGS
 308
 309 #
 310 # Read the template
 311 #
 312 . "$srcdir/src/template/$template" || exit
 313
 314 # CFLAGS are selected so:
 315 # If the user specifies something in the environment, that is used.
 316 # else:  If the template file set something, that is used.
 317 # else:  If the compiler is GCC, then we use -O2.
 318 # else:  If the compiler is something else, then we use -0.
 319
 320 if test "$ac_env_CFLAGS_set" = set; then
 321   CFLAGS=$ac_env_CFLAGS_value
 322 elif test "${CFLAGS+set}" = set; then
 323   : # (keep what template set)
 324 elif test "$GCC" = yes; then
 325   CFLAGS="-O2"
 326 else
 327   # if the user selected debug mode, don't use -O
 328   if test "$enable_debug" != yes; then
 329     CFLAGS="-O"
 330   fi
 331 fi
 332
 333 # Some versions of GCC support some additional useful warning flags.
 334 # Check whether they are supported, and add them to CFLAGS if so.
 335 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 336
 337 if test "$GCC" = yes -a "$ICC" = no; then
 338   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 339   # These work in some but not all gcc versions
 340   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 341   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 342   # Disable strict-aliasing rules; needed for gcc 3.3+
 343   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 344   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 345   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 346 elif test "$ICC" = yes; then
 347   # Intel's compiler has a bug/misoptimization in checking for
 348   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 349   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 350   # Make sure strict aliasing is off (though this is said to be the default)
 351   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 352 elif test x"${CC}" = x"xlc"; then
 353   # AIX xlc has to have strict aliasing turned off too
 354   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 355 fi
 356
 357 # supply -g if --enable-debug
 358 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 359   CFLAGS="$CFLAGS -g"
 360 fi
 361
 362 # enable profiling if --enable-profiling
 363 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 364   if test "$GCC" = yes; then
 365     AC_DEFINE([PROFILE_PID_DIR], 1,
 366            [Define to 1 to allow profiling output to be saved separately for each process.])
 367     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 368   else
 369     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 370   fi
 371 fi
 372
 373 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 374
 375 # We already have this in Makefile.win32, but configure needs it too
 376 if test "$PORTNAME" = "win32"; then
 377   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 378 fi
 379
 380 # Check if the compiler still works with the template settings
 381 AC_MSG_CHECKING([whether the C compiler still works])
 382 AC_TRY_LINK([], [return 0;],
 383   [AC_MSG_RESULT(yes)],
 384   [AC_MSG_RESULT(no)
 385    AC_MSG_ERROR([cannot proceed])])
 386
 387 # Defend against gcc -ffast-math
 388 if test "$GCC" = yes; then
 389 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 390 choke me
 391 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 392 fi
 393
 394 AC_PROG_CPP
 395 AC_SUBST(GCC)
 396
 397 # Create compiler version string
 398 if test x"$GCC" = x"yes" ; then
 399   cc_string="GCC `${CC} --version | sed q`"
 400 else
 401   cc_string=$CC
 402 fi
 403 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 404                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 405                    [A string containing the version number, platform, and C compiler])
 406
 407
 408 #
 409 # Set up TAS assembly code if needed; the template file has now had its
 410 # chance to request this.
 411 #
 412 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 413
 414 if test "$need_tas" = yes ; then
 415   TAS=tas.o
 416 else
 417   TAS=""
 418 fi
 419 AC_SUBST(TAS)
 420
 421
 422 #
 423 # Automatic dependency tracking
 424 #
 425 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 426               [autodepend=yes])
 427 AC_SUBST(autodepend)
 428
 429
 430 #
 431 # Enable assert checks
 432 #
 433 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 434               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 435                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 436
 437
 438 #
 439 # Include directories
 440 #
 441 ac_save_IFS=$IFS
 442 IFS="${IFS}${PATH_SEPARATOR}"
 443 # SRCH_INC comes from the template file
 444 for dir in $with_includes $SRCH_INC; do
 445   if test -d "$dir"; then
 446     INCLUDES="$INCLUDES -I$dir"
 447   else
 448     AC_MSG_WARN([*** Include directory $dir does not exist.])
 449   fi
 450 done
 451 IFS=$ac_save_IFS
 452 AC_SUBST(INCLUDES)
 453
 454
 455 #
 456 # Library directories
 457 #
 458 ac_save_IFS=$IFS
 459 IFS="${IFS}${PATH_SEPARATOR}"
 460 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 461 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 462   if test -d "$dir"; then
 463     LIBDIRS="$LIBDIRS -L$dir"
 464   else
 465     AC_MSG_WARN([*** Library directory $dir does not exist.])
 466   fi
 467 done
 468 IFS=$ac_save_IFS
 469
 470 #
 471 # Enable thread-safe client libraries
 472 #
 473 AC_MSG_CHECKING([allow thread-safe client libraries])
 474 if test "$PORTNAME" != "win32"; then
 475 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 476 else
 477 # Win32 should always use threads
 478 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 479 fi
 480
 481 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 482 if test "$enable_thread_safety" = yes -o \
 483         "$enable_thread_safety_force" = yes; then
 484   enable_thread_safety="yes"    # for 'force'
 485   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 486           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 487 fi
 488 AC_MSG_RESULT([$enable_thread_safety])
 489 AC_SUBST(enable_thread_safety)
 490
 491 #
 492 # Optionally build Tcl modules (PL/Tcl)
 493 #
 494 AC_MSG_CHECKING([whether to build with Tcl])
 495 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 496 AC_MSG_RESULT([$with_tcl])
 497 AC_SUBST([with_tcl])
 498
 499 # We see if the path to the Tcl/Tk configuration scripts is specified.
 500 # This will override the use of tclsh to find the paths to search.
 501
 502 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 503
 504 #
 505 # Optionally build Perl modules (PL/Perl)
 506 #
 507 AC_MSG_CHECKING([whether to build Perl modules])
 508 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 509 AC_MSG_RESULT([$with_perl])
 510 AC_SUBST(with_perl)
 511
 512 #
 513 # Optionally build Python modules (PL/Python)
 514 #
 515 AC_MSG_CHECKING([whether to build Python modules])
 516 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 517 AC_MSG_RESULT([$with_python])
 518 AC_SUBST(with_python)
 519
 520 #
 521 # GSSAPI
 522 #
 523 AC_MSG_CHECKING([whether to build with GSSAPI support])
 524 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 525 [
 526   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 527   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 528 ])
 529 AC_MSG_RESULT([$with_gssapi])
 530 AC_SUBST(with_gssapi)
 531
 532 #
 533 # Kerberos 5
 534 #
 535 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 536 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 537 [
 538   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 539   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 540 ])
 541 AC_MSG_RESULT([$with_krb5])
 542 AC_SUBST(with_krb5)
 543
 544
 545 AC_SUBST(krb_srvtab)
 546
 547
 548 #
 549 # Kerberos configuration parameters
 550 #
 551 PGAC_ARG_REQ(with, krb-srvnam,
 552              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 553              [],
 554              [with_krb_srvnam="postgres"])
 555 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 556                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 557
 558
 559 #
 560 # PAM
 561 #
 562 AC_MSG_CHECKING([whether to build with PAM support])
 563 PGAC_ARG_BOOL(with, pam, no,
 564               [  --with-pam              build with PAM support],
 565               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 566 AC_MSG_RESULT([$with_pam])
 567 AC_SUBST(with_pam)
 568
 569
 570 #
 571 # LDAP
 572 #
 573 AC_MSG_CHECKING([whether to build with LDAP support])
 574 PGAC_ARG_BOOL(with, ldap, no,
 575               [  --with-ldap             build with LDAP support],
 576               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 577 AC_MSG_RESULT([$with_ldap])
 578 AC_SUBST(with_ldap)
 579
 580
 581 #
 582 # Bonjour
 583 #
 584 AC_MSG_CHECKING([whether to build with Bonjour support])
 585 PGAC_ARG_BOOL(with, bonjour, no,
 586               [  --with-bonjour          build with Bonjour support],
 587               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 588 AC_MSG_RESULT([$with_bonjour])
 589 AC_SUBST(with_bonjour)
 590
 591
 592 #
 593 # OpenSSL
 594 #
 595 AC_MSG_CHECKING([whether to build with OpenSSL support])
 596 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 597               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 598 AC_MSG_RESULT([$with_openssl])
 599 AC_SUBST(with_openssl)
 600
 601
 602 #
 603 # Readline
 604 #
 605 PGAC_ARG_BOOL(with, readline, yes,
 606               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 607 # readline on MinGW has problems with backslashes in psql and other bugs.
 608 # This is particularly a problem with non-US code pages.
 609 # Therefore disable its use until we understand the cause. 2004-07-20
 610 if test "$PORTNAME" = "win32"; then
 611   if test "$with_readline" = yes; then
 612     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 613     with_readline=no
 614   fi
 615 fi
 616
 617
 618 #
 619 # Prefer libedit
 620 #
 621 PGAC_ARG_BOOL(with, libedit-preferred, no,
 622               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 623
 624
 625 #
 626 # OSSP UUID library
 627 #
 628 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 629 AC_SUBST(with_ossp_uuid)
 630
 631
 632 #
 633 # XML
 634 #
 635 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 636               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 637
 638 if test "$with_libxml" = yes ; then
 639   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 640   if test -n "$XML2_CONFIG"; then
 641     for pgac_option in `$XML2_CONFIG --cflags`; do
 642       case $pgac_option in
 643         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 644       esac
 645     done
 646     for pgac_option in `$XML2_CONFIG --libs`; do
 647       case $pgac_option in
 648         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 649       esac
 650     done
 651   fi
 652 fi
 653
 654 AC_SUBST(with_libxml)
 655
 656 #
 657 # XSLT
 658 #
 659 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 660               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 661
 662
 663 AC_SUBST(with_libxslt)
 664
 665 #
 666 # tzdata
 667 #
 668 PGAC_ARG_REQ(with, system-tzdata,
 669              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 670 AC_SUBST(with_system_tzdata)
 671
 672 #
 673 # Zlib
 674 #
 675 PGAC_ARG_BOOL(with, zlib, yes,
 676               [  --without-zlib          do not use Zlib])
 677 AC_SUBST(with_zlib)
 678
 679 #
 680 # Elf
 681 #
 682
 683 # Assume system is ELF if it predefines __ELF__ as 1,
 684 # otherwise believe host_os based default.
 685 case $host_os in
 686     freebsd1*|freebsd2*) elf=no;;
 687     freebsd3*|freebsd4*) elf=yes;;
 688 esac
 689
 690 AC_EGREP_CPP(yes,
 691 [#if __ELF__
 692   yes
 693 #endif
 694 ],
 695 [ELF_SYS=true],
 696 [if test "X$elf" = "Xyes" ; then
 697   ELF_SYS=true
 698 else
 699   ELF_SYS=
 700 fi])
 701 AC_SUBST(ELF_SYS)
 702
 703 #
 704 # Assignments
 705 #
 706
 707 CPPFLAGS="$CPPFLAGS $INCLUDES"
 708 LDFLAGS="$LDFLAGS $LIBDIRS"
 709
 710 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 711 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 712
 713 AC_ARG_VAR(LDFLAGS_SL)
 714
 715 PGAC_PROG_LD
 716 AC_SUBST(LD)
 717 AC_SUBST(with_gnu_ld)
 718 case $host_os in sysv5*)
 719   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 720   [
 721     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 722     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 723     LDFLAGS=$pgac_save_LDFLAGS
 724   ])
 725   ld_R_works=$pgac_cv_prog_ld_R
 726   AC_SUBST(ld_R_works)
 727 esac
 728 AC_PROG_RANLIB
 729 PGAC_CHECK_STRIP
 730
 731 AC_PATH_PROG(TAR, tar)
 732 AC_PROG_LN_S
 733 AC_PROG_AWK
 734
 735 PGAC_PATH_YACC
 736 PGAC_PATH_FLEX
 737
 738 PGAC_PATH_PERL
 739 if test "$with_perl" = yes; then
 740   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 741   PGAC_CHECK_PERL_EMBED_LDFLAGS
 742 fi
 743
 744 if test "$with_python" = yes; then
 745   PGAC_PATH_PYTHON
 746   PGAC_CHECK_PYTHON_EMBED_SETUP
 747 fi
 748
 749 # Supply a numeric version string for use by 3rd party add-ons
 750 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 751 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 752 tr '.' '        ' |
 753 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 754 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 755
 756 ##
 757 ## Libraries
 758 ##
 759 ## Most libraries are included only if they demonstrably provide a function
 760 ## we need, but libm is an exception: always include it, because there are
 761 ## too many compilers that play cute optimization games that will break
 762 ## probes for standard functions such as pow().
 763 ##
 764
 765 AC_CHECK_LIB(m, main)
 766 AC_SEARCH_LIBS(setproctitle, util)
 767 AC_SEARCH_LIBS(dlopen, dl)
 768 AC_SEARCH_LIBS(socket, [socket wsock32])
 769 AC_SEARCH_LIBS(shl_load, dld)
 770 # We only use libld in port/dynloader/aix.c
 771 case $host_os in
 772      aix*)
 773         AC_SEARCH_LIBS(ldopen, ld)
 774         ;;
 775 esac
 776 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 777 AC_SEARCH_LIBS(crypt, crypt)
 778 # Solaris:
 779 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 780 # Cygwin:
 781 AC_SEARCH_LIBS(shmget, cygipc)
 782
 783 if test "$with_readline" = yes; then
 784   PGAC_CHECK_READLINE
 785   if test x"$pgac_cv_check_readline" = x"no"; then
 786     AC_MSG_ERROR([readline library not found
 787 If you have readline already installed, see config.log for details on the
 788 failure.  It is possible the compiler isn't looking in the proper directory.
 789 Use --without-readline to disable readline support.])
 790   fi
 791 fi
 792
 793 if test "$with_zlib" = yes; then
 794   AC_CHECK_LIB(z, inflate, [],
 795                [AC_MSG_ERROR([zlib library not found
 796 If you have zlib already installed, see config.log for details on the
 797 failure.  It is possible the compiler isn't looking in the proper directory.
 798 Use --without-zlib to disable zlib support.])])
 799 fi
 800
 801 if test "$enable_spinlocks" = yes; then
 802   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 803 else
 804   AC_MSG_WARN([
 805 *** Not using spinlocks will cause poor performance.])
 806 fi
 807
 808 if test "$with_gssapi" = yes ; then
 809   if test "$PORTNAME" != "win32"; then
 810     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 811                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 812   else
 813     LIBS="$LIBS -lgssapi32"
 814   fi
 815 fi
 816
 817 if test "$with_krb5" = yes ; then
 818   if test "$PORTNAME" != "win32"; then
 819      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 820                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 821      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 822                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 823   else
 824      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 825                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 826   fi
 827 fi
 828
 829 if test "$with_openssl" = yes ; then
 830   dnl Order matters!
 831   if test "$PORTNAME" != "win32"; then
 832      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 833      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 834   else
 835      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 836      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 837   fi
 838 fi
 839
 840 if test "$with_pam" = yes ; then
 841   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 842 fi
 843
 844 if test "$with_libxml" = yes ; then
 845   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 846 fi
 847
 848 if test "$with_libxslt" = yes ; then
 849   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 850 fi
 851
 852 # for contrib/uuid-ossp
 853 if test "$with_ossp_uuid" = yes ; then
 854   AC_CHECK_LIB(ossp-uuid, uuid_export,
 855     [OSSP_UUID_LIBS="-lossp-uuid"],
 856     [AC_CHECK_LIB(uuid, uuid_export,
 857       [OSSP_UUID_LIBS="-luuid"],
 858       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 859 fi
 860 AC_SUBST(OSSP_UUID_LIBS)
 861
 862
 863 ##
 864 ## Header files
 865 ##
 866
 867 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 868 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 869
 870 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 871 # netinet/in.h is included first.
 872 AC_CHECK_HEADERS(netinet/in.h)
 873 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 874 [AC_INCLUDES_DEFAULT
 875 #ifdef HAVE_NETINET_IN_H
 876 #include <netinet/in.h>
 877 #endif
 878 ])
 879
 880 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 881   AC_CHECK_HEADERS(readline/readline.h, [],
 882         [AC_CHECK_HEADERS(readline.h, [],
 883                 [AC_MSG_ERROR([readline header not found
 884 If you have readline already installed, see config.log for details on the
 885 failure.  It is possible the compiler isn't looking in the proper directory.
 886 Use --without-readline to disable readline support.])])])
 887   AC_CHECK_HEADERS(readline/history.h, [],
 888         [AC_CHECK_HEADERS(history.h, [],
 889                 [AC_MSG_ERROR([history header not found
 890 If you have readline already installed, see config.log for details on the
 891 failure.  It is possible the compiler isn't looking in the proper directory.
 892 Use --without-readline to disable readline support.])])])
 893 fi
 894
 895 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 896 # Some installations of libedit usurp /usr/include/readline/, which seems
 897 # bad practice, since in combined installations readline will have its headers
 898 # there.  We might have to resort to AC_EGREP checks to make sure we found
 899 # the proper header...
 900   AC_CHECK_HEADERS(editline/readline.h, [],
 901         [AC_CHECK_HEADERS(readline.h, [],
 902                 [AC_CHECK_HEADERS(readline/readline.h, [],
 903                         [AC_MSG_ERROR([readline header not found
 904 If you have libedit already installed, see config.log for details on the
 905 failure.  It is possible the compiler isn't looking in the proper directory.
 906 Use --without-readline to disable libedit support.])])])])
 907 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 908 # not be there at all.  Hence, don't complain if not found.  We must check
 909 # though, since in yet other versions it is an independent header.
 910   AC_CHECK_HEADERS(editline/history.h, [],
 911         [AC_CHECK_HEADERS(history.h, [],
 912                 [AC_CHECK_HEADERS(readline/history.h)])])
 913 fi
 914
 915 if test "$with_zlib" = yes; then
 916   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 917 If you have zlib already installed, see config.log for details on the
 918 failure.  It is possible the compiler isn't looking in the proper directory.
 919 Use --without-zlib to disable zlib support.])])
 920 fi
 921
 922 if test "$with_gssapi" = yes ; then
 923   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 924         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 925 fi
 926
 927 if test "$with_krb5" = yes ; then
 928   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 929 fi
 930
 931 if test "$with_openssl" = yes ; then
 932   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 933   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 934   AC_CHECK_FUNCS([ERR_set_mark])
 935 fi
 936
 937 if test "$with_pam" = yes ; then
 938   AC_CHECK_HEADERS(security/pam_appl.h, [],
 939                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 940                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 941 fi
 942
 943 if test "$with_libxml" = yes ; then
 944   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 945 fi
 946
 947 if test "$with_libxslt" = yes ; then
 948   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 949 fi
 950
 951 if test "$with_ldap" = yes ; then
 952   if test "$PORTNAME" != "win32"; then
 953      AC_CHECK_HEADERS(ldap.h, [],
 954                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 955   else
 956      AC_CHECK_HEADERS(winldap.h, [],
 957                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 958                       [AC_INCLUDES_DEFAULT
 959 #include <windows.h>
 960                       ])
 961   fi
 962 fi
 963
 964 if test "$with_bonjour" = yes ; then
 965   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 966 fi
 967
 968 # for contrib/uuid-ossp
 969 if test "$with_ossp_uuid" = yes ; then
 970   AC_CHECK_HEADERS(ossp/uuid.h, [], [
 971     AC_CHECK_HEADERS(uuid.h, [],
 972       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
 973 fi
 974
 975
 976 ##
 977 ## Types, structures, compiler characteristics
 978 ##
 979
 980 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 981 AC_C_BIGENDIAN
 982 AC_C_CONST
 983 AC_C_INLINE
 984 AC_C_STRINGIZE
 985 PGAC_C_SIGNED
 986 AC_C_VOLATILE
 987 PGAC_C_FUNCNAME_SUPPORT
 988 PGAC_STRUCT_TIMEZONE
 989 PGAC_UNION_SEMUN
 990 PGAC_STRUCT_SOCKADDR_UN
 991 PGAC_STRUCT_SOCKADDR_STORAGE
 992 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 993 PGAC_STRUCT_ADDRINFO
 994
 995 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 996 [#include <sys/param.h>
 997 #include <sys/types.h>
 998 #include <sys/socket.h>
 999 #include <sys/ucred.h>])
1000
1001 AC_CHECK_TYPES([struct option], [], [],
1002 [#ifdef HAVE_GETOPT_H
1003 #include <getopt.h>
1004 #endif])
1005
1006 if test "$with_zlib" = yes; then
1007   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1008   # did not).  While we could work around the lack of z_streamp, it
1009   # seems unwise to encourage people to use such old zlib versions...
1010   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1011 Use --without-zlib to disable zlib support.])],
1012                 [#include <zlib.h>])
1013 fi
1014
1015 if test "$with_krb5" = yes; then
1016 # Check for differences between MIT and Heimdal (KTH) releases
1017   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1018                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1019                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1020                                      [#include <krb5.h>])],
1021                    [#include <krb5.h>])
1022   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1023                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1024                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1025                                      [#include <krb5.h>])],
1026                    [#include <krb5.h>])
1027
1028 # Win32 requires headers to be loaded for __stdcall, so can't use
1029 # AC_CHECK_FUNCS here.
1030   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1031   AC_TRY_LINK([#include <krb5.h>],
1032               [krb5_free_unparsed_name(NULL,NULL);],
1033               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1034 AC_MSG_RESULT(yes)],
1035               [AC_MSG_RESULT(no)])
1036 fi
1037
1038
1039 ##
1040 ## Functions, global variables
1041 ##
1042
1043 PGAC_VAR_INT_TIMEZONE
1044 AC_FUNC_ACCEPT_ARGTYPES
1045 PGAC_FUNC_GETTIMEOFDAY_1ARG
1046
1047 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1048
1049 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1050 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1051 AC_CHECK_DECLS([strlcat, strlcpy])
1052 # This is probably only present on Darwin, but may as well check always
1053 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1054
1055 HAVE_IPV6=no
1056 AC_CHECK_TYPE([struct sockaddr_in6],
1057         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1058          HAVE_IPV6=yes],
1059         [],
1060 [$ac_includes_default
1061 #include <netinet/in.h>])
1062 AC_SUBST(HAVE_IPV6)
1063
1064 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1065 [AC_TRY_LINK(
1066 [#include <machine/vmparam.h>
1067 #include <sys/exec.h>
1068 ],
1069 [PS_STRINGS->ps_nargvstr = 1;
1070 PS_STRINGS->ps_argvstr = "foo";],
1071 [pgac_cv_var_PS_STRINGS=yes],
1072 [pgac_cv_var_PS_STRINGS=no])])
1073 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1074   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1075 fi
1076
1077
1078 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1079 # is missing.  Yes, there are machines that have only one.  We may
1080 # also decide to use snprintf.c if snprintf() is present but does not
1081 # have all the features we need --- see below.
1082
1083 if test "$PORTNAME" = "win32"; then
1084   # Win32 gets snprintf.c built unconditionally.
1085   #
1086   # To properly translate all NLS languages strings, we must support the
1087   # *printf() %$ format, which allows *printf() arguments to be selected
1088   # by position in the translated string.
1089   #
1090   # libintl versions < 0.13 use the native *printf() functions, and Win32
1091   # *printf() doesn't understand %$, so we must use our /port versions,
1092   # which do understand %$. libintl versions >= 0.13 include their own
1093   # *printf versions on Win32.  The libintl 0.13 release note text is:
1094   #
1095   #   C format strings with positions, as they arise when a translator
1096   #   needs to reorder a sentence, are now supported on all platforms.
1097   #   On those few platforms (NetBSD and Woe32) for which the native
1098   #   printf()/fprintf()/... functions don't support such format
1099   #   strings, replacements are provided through <libintl.h>.
1100   #
1101   # We could use libintl >= 0.13's *printf() if we were sure that we had
1102   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1103   # to guarantee that, it is best to just use our own, so we are sure to
1104   # get %$ support. In include/port.h we disable the *printf() macros
1105   # that might have been defined by libintl.
1106   #
1107   # We do this unconditionally whether NLS is used or not so we are sure
1108   # that all Win32 libraries and binaries behave the same.
1109   pgac_need_repl_snprintf=yes
1110 else
1111   pgac_need_repl_snprintf=no
1112   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1113   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1114 fi
1115
1116
1117 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1118 # include/c.h will provide declarations.  Note this is a separate test
1119 # from whether the functions exist in the C library --- there are
1120 # systems that have the functions but don't bother to declare them :-(
1121
1122 AC_CHECK_DECLS([snprintf, vsnprintf])
1123
1124
1125 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1126 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1127 [AC_TRY_LINK([
1128 #include <math.h>
1129 double glob_double;
1130 ],
1131 [return isinf(glob_double) ? 0 : 1;],
1132 [ac_cv_func_isinf=yes],
1133 [ac_cv_func_isinf=no])])
1134
1135 if test $ac_cv_func_isinf = yes ; then
1136   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1137 else
1138   AC_LIBOBJ(isinf)
1139   # Look for a way to implement a substitute for isinf()
1140   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1141 fi
1142
1143 # Some versions of libedit contain strlcpy(); so disregard that library while
1144 # checking for these standard libc functions.
1145 pgac_save_LIBS="$LIBS"
1146 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1147
1148 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1149
1150 LIBS="$pgac_save_LIBS"
1151
1152 # System's version of getaddrinfo(), if any, may be used only if we found
1153 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1154 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1155 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1156 # because we want to use our own getaddrinfo.c on Windows anyway.)
1157 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1158   AC_REPLACE_FUNCS([getaddrinfo])
1159 else
1160   AC_LIBOBJ(getaddrinfo)
1161 fi
1162
1163 # Similarly, use system's getopt_long() only if system provides struct option.
1164 # Solaris' getopt() doesn't do what we want for long options, so always use
1165 # our versions on that platform.
1166 if test "$PORTNAME" = "solaris"; then
1167   AC_LIBOBJ(getopt)
1168   AC_LIBOBJ(getopt_long)
1169 elif test x"$ac_cv_type_struct_option" = xyes ; then
1170   AC_REPLACE_FUNCS([getopt_long])
1171 else
1172   AC_LIBOBJ(getopt_long)
1173 fi
1174
1175 # Win32 support
1176 if test "$PORTNAME" = "win32"; then
1177 AC_REPLACE_FUNCS(gettimeofday)
1178 AC_LIBOBJ(kill)
1179 AC_LIBOBJ(open)
1180 AC_LIBOBJ(rand)
1181 AC_LIBOBJ(win32error)
1182 AC_DEFINE([HAVE_SYMLINK], 1,
1183           [Define to 1 if you have the `symlink' function.])
1184 fi
1185
1186 if test "$with_readline" = yes; then
1187   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1188   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1189   AC_CHECK_FUNCS([replace_history_entry])
1190 fi
1191
1192
1193 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1194 dnl (especially on GNU libc)
1195 dnl See also comments in c.h.
1196 AC_MSG_CHECKING(for sigsetjmp)
1197 AC_TRY_LINK([#include <setjmp.h>],
1198             [sigjmp_buf x; sigsetjmp(x, 1);],
1199             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1200 AC_MSG_RESULT(yes)],
1201             [AC_MSG_RESULT(no)])
1202
1203 AC_DECL_SYS_SIGLIST
1204
1205 AC_CHECK_FUNC(syslog,
1206               [AC_CHECK_HEADER(syslog.h,
1207                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1208
1209 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1210 [AC_TRY_LINK([#include <unistd.h>],
1211   [extern int optreset; optreset = 1;],
1212   [pgac_cv_var_int_optreset=yes],
1213   [pgac_cv_var_int_optreset=no])])
1214 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1215   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1216 fi
1217
1218 AC_CHECK_FUNCS([strtoll strtoq], [break])
1219 AC_CHECK_FUNCS([strtoull strtouq], [break])
1220
1221 # Check for one of atexit() or on_exit()
1222 AC_CHECK_FUNCS(atexit, [],
1223                [AC_CHECK_FUNCS(on_exit, [],
1224                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1225
1226 AC_REPLACE_FUNCS(fseeko)
1227 case $host_os in
1228         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1229         bsdi*|netbsd*)
1230                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1231                 ac_cv_func_fseeko=yes;;
1232         *)
1233                 AC_FUNC_FSEEKO;;
1234 esac
1235
1236
1237 #
1238 # Pthreads
1239 #
1240 # For each platform, we need to know about any special compile and link
1241 # libraries, and whether the normal C function names are thread-safe.
1242 # See the comment at the top of src/port/thread.c for more information.
1243 # WIN32 doesn't need the pthread tests;  it always uses threads
1244 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1245 ACX_PTHREAD     # set thread flags
1246
1247 # Some platforms use these, so just defineed them.  They can't hurt if they
1248 # are not supported.
1249 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1250
1251
1252 # At this point, we don't want to muck with the compiler name for threading.
1253 # Let's see who fails, perhaps AIX.  2004-04-23
1254 if test "$PTHREAD_CC" != "$CC"; then
1255 AC_MSG_ERROR([
1256 PostgreSQL does not support platforms that require a special compiler
1257 for thread safety.])
1258 fi
1259
1260 if test "$THREAD_SUPPORT" = no; then
1261 AC_MSG_ERROR([cannot enable threads on this platform
1262 This platform is known to not support thread-safe programs.  For details,
1263 compile and run src/bin/pg_thread_test.])
1264 fi
1265
1266 # Check for *_r functions
1267 _CFLAGS="$CFLAGS"
1268 _LIBS="$LIBS"
1269 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1270 LIBS="$LIBS $PTHREAD_LIBS"
1271
1272 if test "$PORTNAME" != "win32"; then
1273 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1274 fi
1275
1276 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1277
1278 # Do test here with the proper thread flags
1279 PGAC_FUNC_GETPWUID_R_5ARG
1280 PGAC_FUNC_STRERROR_R_INT
1281
1282 CFLAGS="$_CFLAGS"
1283 LIBS="$_LIBS"
1284
1285 else
1286 # do not use values from template file
1287 PTHREAD_CFLAGS=
1288 PTHREAD_LIBS=
1289 fi
1290
1291 AC_SUBST(PTHREAD_CFLAGS)
1292 AC_SUBST(PTHREAD_LIBS)
1293
1294
1295 # We can test for libldap_r only after we know PTHREAD_LIBS
1296 if test "$with_ldap" = yes ; then
1297   _LIBS="$LIBS"
1298   if test "$PORTNAME" != "win32"; then
1299     AC_CHECK_LIB(ldap, ldap_bind, [],
1300                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1301                  [$EXTRA_LDAP_LIBS])
1302     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1303     if test "$enable_thread_safety" = yes; then
1304       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1305       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1306                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1307                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1308       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1309     else
1310       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1311     fi
1312   else
1313     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1314     LDAP_LIBS_FE="-lwldap32"
1315     LDAP_LIBS_BE="-lwldap32"
1316   fi
1317   LIBS="$_LIBS"
1318 fi
1319 AC_SUBST(LDAP_LIBS_FE)
1320 AC_SUBST(LDAP_LIBS_BE)
1321
1322
1323 # This test makes sure that run tests work at all.  Sometimes a shared
1324 # library is found by the linker, but the runtime linker can't find it.
1325 # This check should come after all modifications of compiler or linker
1326 # variables, and before any other run tests.
1327 AC_MSG_CHECKING([test program])
1328 AC_TRY_RUN([int main() { return 0; }],
1329 [AC_MSG_RESULT(ok)],
1330 [AC_MSG_RESULT(failed)
1331 AC_MSG_ERROR([[
1332 Could not execute a simple test program.  This may be a problem
1333 related to locating shared libraries.  Check the file 'config.log'
1334 for the exact reason.]])],
1335 [AC_MSG_RESULT([cross-compiling])])
1336
1337 # --------------------
1338 # Run tests below here
1339 # --------------------
1340
1341 # Force use of our snprintf if system's doesn't do arg control
1342 # See comment above at snprintf test for details.
1343 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1344   PGAC_FUNC_PRINTF_ARG_CONTROL
1345   if test $pgac_cv_printf_arg_control != yes ; then
1346     pgac_need_repl_snprintf=yes
1347   fi
1348 fi
1349
1350
1351 dnl Check to see if we have a working 64-bit integer type.
1352 dnl This breaks down into two steps:
1353 dnl (1) figure out if the compiler has a 64-bit int type with working
1354 dnl arithmetic, and if so
1355 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1356 dnl snprintf is the only library routine we really need for int8 support.)
1357 dnl It's entirely possible to have a compiler that handles a 64-bit type
1358 dnl when the C library doesn't; this is fairly likely when using gcc on
1359 dnl an older platform, for example.
1360 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1361 dnl we force our own version of snprintf() to be used instead.
1362 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1363
1364 PGAC_TYPE_64BIT_INT([long int])
1365
1366 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1367   PGAC_TYPE_64BIT_INT([long long int])
1368 fi
1369
1370
1371 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1372
1373 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1374   AC_TRY_COMPILE([
1375 #define INT64CONST(x)  x##LL
1376 long long int foo = INT64CONST(0x1234567890123456);
1377 ],
1378         [],
1379         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1380         [])
1381 fi
1382
1383
1384 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1385 # we found we need to use "long long int", better check.  We cope with
1386 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1387 # work, fall back to our own snprintf emulation (which we know uses %lld).
1388
1389 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1390   if test $pgac_need_repl_snprintf = no; then
1391     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1392     if test "$LONG_LONG_INT_FORMAT" = ""; then
1393       # Force usage of our own snprintf, since system snprintf is broken
1394       pgac_need_repl_snprintf=yes
1395       LONG_LONG_INT_FORMAT='%lld'
1396     fi
1397   else
1398     # Here if we previously decided we needed to use our own snprintf
1399     LONG_LONG_INT_FORMAT='%lld'
1400   fi
1401   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1402   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1403   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1404 else
1405   # Here if we are not using 'long long int' at all
1406   INT64_FORMAT='"%ld"'
1407   UINT64_FORMAT='"%lu"'
1408 fi
1409
1410 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1411                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1412
1413 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1414                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1415
1416 # Now we have checked all the reasons to replace snprintf
1417 if test $pgac_need_repl_snprintf = yes; then
1418   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1419   AC_LIBOBJ(snprintf)
1420 fi
1421
1422 # Need a #define for the size of Datum (unsigned long)
1423 AC_CHECK_SIZEOF([unsigned long])
1424
1425 # And one for the size of size_t (enables tweaks for > 32bit address space)
1426 AC_CHECK_SIZEOF([size_t])
1427
1428 # Decide whether float4 is passed by value: user-selectable, enabled by default
1429 AC_MSG_CHECKING([whether to build with float4 passed by value])
1430 PGAC_ARG_BOOL(enable, float4-byval, yes, [  --disable-float4-byval  disable float4 passed by value],
1431               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1432                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1433                float4passbyval=true],
1434               [float4passbyval=false])
1435 AC_MSG_RESULT([$enable_float4_byval])
1436 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1437
1438 # Decide whether float8 is passed by value.
1439 # Note: this setting also controls int8 and related types such as timestamp.
1440 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1441 # If not, trying to select it is an error.
1442 AC_MSG_CHECKING([whether to build with float8 passed by value])
1443 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1444   PGAC_ARG_BOOL(enable, float8-byval, yes, [  --disable-float8-byval  disable float8 passed by value])
1445 else
1446   PGAC_ARG_BOOL(enable, float8-byval, no, [  --disable-float8-byval  disable float8 passed by value])
1447   if test "$enable_float8_byval" = yes ; then
1448     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1449   fi
1450 fi
1451 if test "$enable_float8_byval" = yes ; then
1452   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1453             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1454   float8passbyval=true
1455 else
1456   float8passbyval=false
1457 fi
1458 AC_MSG_RESULT([$enable_float8_byval])
1459 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1460
1461 # Determine memory alignment requirements for the basic C data types.
1462
1463 AC_CHECK_ALIGNOF(short)
1464 AC_CHECK_ALIGNOF(int)
1465 AC_CHECK_ALIGNOF(long)
1466 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1467   AC_CHECK_ALIGNOF(long long int)
1468 fi
1469 AC_CHECK_ALIGNOF(double)
1470
1471 # Compute maximum alignment of any basic type.
1472 # We assume long's alignment is at least as strong as char, short, or int;
1473 # but we must check long long (if it exists) and double.
1474
1475 MAX_ALIGNOF=$ac_cv_alignof_long
1476 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1477   MAX_ALIGNOF=$ac_cv_alignof_double
1478 fi
1479 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1480   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1481 fi
1482 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1483
1484
1485 # Some platforms predefine the types int8, int16, etc.  Only check
1486 # a (hopefully) representative subset.
1487 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1488 [#include <stdio.h>
1489 #ifdef HAVE_SUPPORTDEFS_H
1490 #include <SupportDefs.h>
1491 #endif])
1492
1493 # We also check for sig_atomic_t, which *should* be defined per ANSI
1494 # C, but is missing on some old platforms.
1495 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1496
1497
1498 # If the user did not disable integer datetimes, check that
1499 # there is a working 64-bit integral type to use.
1500 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1501    test x"$HAVE_LONG_INT_64" = x"no" &&
1502    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1503    test x"$HAVE_INT64" = x"no" ; then
1504   AC_MSG_ERROR([
1505 Integer-based datetime support requires a 64-bit integer type,
1506 but no such type could be found. The --disable-integer-datetimes
1507 configure option can be used to disable integer-based storage
1508 of datetime values.])
1509 fi
1510
1511
1512 if test "$PORTNAME" != "win32"
1513 then
1514 PGAC_FUNC_POSIX_SIGNALS
1515 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1516   AC_MSG_ERROR([
1517 Thread-safety requires POSIX signals, which are not supported by this
1518 operating system.])
1519 fi
1520 fi
1521
1522 if test $ac_cv_func_fseeko = yes; then
1523 AC_SYS_LARGEFILE
1524 fi
1525
1526 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1527 AC_CHECK_SIZEOF([off_t])
1528
1529 # If we don't have largefile support, can't handle segsize >= 2GB.
1530 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1531    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1532 fi
1533
1534 # SunOS doesn't handle negative byte comparisons properly with +/- return
1535 AC_FUNC_MEMCMP
1536
1537
1538 # Select semaphore implementation type.
1539 if test "$PORTNAME" != "win32"; then
1540   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1541     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1542     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1543   else
1544     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1545       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1546       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1547     else
1548       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1549       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1550     fi
1551   fi
1552 else
1553   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1554   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1555 fi
1556
1557
1558 # Select shared-memory implementation type.
1559 if test "$PORTNAME" != "win32"; then
1560   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1561   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1562 else
1563   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1564   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1565 fi
1566
1567 # If not set in template file, set bytes to use libc memset()
1568 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1569   MEMSET_LOOP_LIMIT=1024
1570 fi
1571 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1572
1573
1574 if test "$enable_nls" = yes ; then
1575   PGAC_CHECK_GETTEXT
1576 fi
1577
1578 # Check for Tcl configuration script tclConfig.sh
1579 if test "$with_tcl" = yes; then
1580     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1581     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1582                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1583     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1584     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1585     ac_save_CPPFLAGS=$CPPFLAGS
1586     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1587     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1588     CPPFLAGS=$ac_save_CPPFLAGS
1589 fi
1590
1591 #
1592 # Check for DocBook and tools
1593 #
1594 PGAC_PROG_NSGMLS
1595 PGAC_PROG_JADE
1596 PGAC_CHECK_DOCBOOK(4.2)
1597 PGAC_PATH_DOCBOOK_STYLESHEETS
1598 PGAC_PATH_COLLATEINDEX
1599 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1600
1601 # Thread testing
1602
1603 # We have to run the thread test near the end so we have all our symbols
1604 # defined.  Cross compiling throws a warning.
1605 #
1606 if test "$enable_thread_safety_force" = yes; then
1607 if test "$PORTNAME" != "win32"
1608 then
1609   AC_MSG_WARN([
1610 *** Skipping thread test program.  --enable-thread-safety-force was used.
1611 *** Run the program in src/test/thread on the your machine and add proper
1612 *** locking function calls to your applications to guarantee thread safety.
1613 ])
1614 else
1615 AC_MSG_WARN([*** skipping thread test on Win32])
1616 fi
1617 elif test "$enable_thread_safety" = yes; then
1618 if test "$PORTNAME" != "win32"
1619 then
1620 AC_MSG_CHECKING([thread safety of required library functions])
1621
1622 _CFLAGS="$CFLAGS"
1623 _LIBS="$LIBS"
1624 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1625 LIBS="$LIBS $PTHREAD_LIBS"
1626 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1627   [AC_MSG_RESULT(yes)],
1628   [AC_MSG_RESULT(no)
1629   AC_MSG_ERROR([thread test program failed
1630 This platform is not thread-safe.  Check the file 'config.log'for the
1631 exact reason.
1632
1633 You can use the configure option --enable-thread-safety-force to force
1634 threads to be enabled.  But you must then run the program in
1635 src/test/thread and add locking function calls to your applications to
1636 guarantee thread safety.])],
1637   [AC_MSG_RESULT(maybe)
1638   AC_MSG_WARN([
1639 *** Skipping thread test program because of cross-compile build.
1640 *** Run the program in src/test/thread on the target machine.
1641 ])])
1642 CFLAGS="$_CFLAGS"
1643 LIBS="$_LIBS"
1644 else
1645 AC_MSG_WARN([*** skipping thread test on Win32])
1646 fi
1647 fi
1648
1649 # prepare build tree if outside source tree
1650 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1651 # Note 2: /bin/pwd might be better than shell's built-in at getting
1652 #         a symlink-free name.
1653 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1654   vpath_build=no
1655 else
1656   vpath_build=yes
1657   if test "$no_create" != yes; then
1658     _AS_ECHO_N([preparing build tree... ])
1659     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1660     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1661       || AC_MSG_ERROR(failed)
1662     AC_MSG_RESULT(done)
1663   fi
1664 fi
1665 AC_SUBST(vpath_build)
1666
1667
1668 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1669
1670 AC_CONFIG_LINKS([
1671   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1672   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1673   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1674   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1675   src/include/pg_config_os.h:src/include/port/${template}.h
1676   src/Makefile.port:src/makefiles/Makefile.${template}
1677 ])
1678
1679 if test "$PORTNAME" = "win32"; then
1680 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1681 # Links sometimes fail undetected on Mingw -
1682 # so here we detect it and warn the user
1683 for FILE in $CONFIG_LINKS
1684  do
1685         # test -e works for symlinks in the MinGW console
1686         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1687  done
1688 ])
1689 fi
1690
1691 AC_CONFIG_HEADERS([src/include/pg_config.h],
1692 [
1693 # Update timestamp for pg_config.h (see Makefile.global)
1694 echo >src/include/stamp-h
1695 ])
1696
1697 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1698
1699 AC_OUTPUT
1700
1701 # Warn about unknown options
1702 PGAC_ARG_CHECK