qtcreator.pri

   1 !isEmpty(QTCREATOR_PRI_INCLUDED):error("qtcreator.pri already included")
   2 QTCREATOR_PRI_INCLUDED = 1
   3
   4 QTCREATOR_VERSION = 2.3.82
   5
   6 defineReplace(cleanPath) {
   7     win32:1 ~= s|\\\\|/|g
   8     contains(1, ^/.*):pfx = /
   9     else:pfx =
  10     segs = $$split(1, /)
  11     out =
  12     for(seg, segs) {
  13         equals(seg, ..):out = $$member(out, 0, -2)
  14         else:!equals(seg, .):out += $$seg
  15     }
  16     return($$join(out, /, $$pfx))
  17 }
  18
  19 defineReplace(targetPath) {
  20     return($$replace(1, /, $$QMAKE_DIR_SEP))
  21 }
  22
  23 defineReplace(qtLibraryName) {
  24    unset(LIBRARY_NAME)
  25    LIBRARY_NAME = $$1
  26    CONFIG(debug, debug|release) {
  27       !debug_and_release|build_pass {
  28           mac:RET = $$member(LIBRARY_NAME, 0)_debug
  29               else:win32:RET = $$member(LIBRARY_NAME, 0)d
  30       }
  31    }
  32    isEmpty(RET):RET = $$LIBRARY_NAME
  33    return($$RET)
  34 }
  35
  36 defineTest(minQtVersion) {
  37     maj = $$1
  38     min = $$2
  39     patch = $$3
  40     isEqual(QT_MAJOR_VERSION, $$maj) {
  41         isEqual(QT_MINOR_VERSION, $$min) {
  42             isEqual(QT_PATCH_VERSION, $$patch) {
  43                 return(true)
  44             }
  45             greaterThan(QT_PATCH_VERSION, $$patch) {
  46                 return(true)
  47             }
  48         }
  49         greaterThan(QT_MINOR_VERSION, $$min) {
  50             return(true)
  51         }
  52     }
  53     return(false)
  54 }
  55
  56 # For use in custom compilers which just copy files
  57 win32:i_flag = i
  58 defineReplace(stripSrcDir) {
  59     win32 {
  60         !contains(1, ^.:.*):1 = $$OUT_PWD/$$1
  61     } else {
  62         !contains(1, ^/.*):1 = $$OUT_PWD/$$1
  63     }
  64     out = $$cleanPath($$1)
  65     out ~= s|^$$re_escape($$PWD/)||$$i_flag
  66     return($$out)
  67 }
  68
  69 isEmpty(TEST):CONFIG(debug, debug|release) {
  70     !debug_and_release|build_pass {
  71         TEST = 1
  72     }
  73 }
  74
  75 isEmpty(IDE_LIBRARY_BASENAME) {
  76     IDE_LIBRARY_BASENAME = lib
  77 }
  78 win32-msvc* {
  79     DEFINES += IDE_LIBRARY_BASENAME=\"$$IDE_LIBRARY_BASENAME\"
  80 } else {
  81     DEFINES += IDE_LIBRARY_BASENAME=\\\"$$IDE_LIBRARY_BASENAME\\\"
  82 }
  83
  84 equals(TEST, 1) {
  85     QT +=testlib
  86     DEFINES += WITH_TESTS
  87 }
  88
  89 IDE_SOURCE_TREE = $$PWD
  90 isEmpty(IDE_BUILD_TREE) {
  91     sub_dir = $$_PRO_FILE_PWD_
  92     sub_dir ~= s,^$$re_escape($$PWD),,
  93     IDE_BUILD_TREE = $$cleanPath($$OUT_PWD)
  94     IDE_BUILD_TREE ~= s,$$re_escape($$sub_dir)$,,
  95 }
  96 IDE_APP_PATH = $$IDE_BUILD_TREE/bin
  97 macx {
  98     IDE_APP_TARGET   = "Qt Creator"
  99     IDE_LIBRARY_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/PlugIns
 100     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH
 101     IDE_LIBEXEC_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
 102     IDE_DATA_PATH    = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
 103     IDE_DOC_PATH     = $$IDE_DATA_PATH/doc
 104     IDE_BIN_PATH     = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/MacOS
 105     contains(QT_CONFIG, ppc):CONFIG += ppc x86
 106     copydata = 1
 107     isEmpty(TIGER_COMPAT_MODE):TIGER_COMPAT_MODE=$$(QTC_TIGER_COMPAT)
 108     isEmpty(TIGER_COMPAT_MODE) {
 109         QMAKE_CXXFLAGS *= -mmacosx-version-min=10.5
 110         QMAKE_LFLAGS *= -mmacosx-version-min=10.5
 111     }
 112 } else {
 113     win32 {
 114         contains(TEMPLATE, vc.*)|contains(TEMPLATE_PREFIX, vc):vcproj = 1
 115         IDE_APP_TARGET   = qtcreator
 116     } else {
 117         IDE_APP_TARGET   = qtcreator
 118     }
 119     IDE_LIBRARY_PATH = $$IDE_BUILD_TREE/$$IDE_LIBRARY_BASENAME/qtcreator
 120     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH/plugins
 121     IDE_LIBEXEC_PATH = $$IDE_APP_PATH # FIXME
 122     IDE_DATA_PATH    = $$IDE_BUILD_TREE/share/qtcreator
 123     IDE_DOC_PATH     = $$IDE_BUILD_TREE/share/doc/qtcreator
 124     IDE_BIN_PATH     = $$IDE_APP_PATH
 125     !isEqual(IDE_SOURCE_TREE, $$IDE_BUILD_TREE):copydata = 1
 126 }
 127
 128 INCLUDEPATH += \
 129     $$IDE_BUILD_TREE/src \ # for <app/app_version.h>
 130     $$IDE_SOURCE_TREE/src/libs \
 131     $$IDE_SOURCE_TREE/tools \
 132     $$IDE_SOURCE_TREE/src/plugins
 133
 134 CONFIG += depend_includepath
 135
 136 LIBS += -L$$IDE_LIBRARY_PATH
 137
 138 #DEFINES += QT_NO_CAST_FROM_ASCII
 139 DEFINES += QT_NO_CAST_TO_ASCII
 140 !macx:DEFINES += QT_USE_FAST_OPERATOR_PLUS QT_USE_FAST_CONCATENATION
 141
 142 unix {
 143     CONFIG(debug, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
 144     CONFIG(release, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
 145
 146     CONFIG(debug, debug|release):MOC_DIR = $${OUT_PWD}/.moc/debug-shared
 147     CONFIG(release, debug|release):MOC_DIR = $${OUT_PWD}/.moc/release-shared
 148
 149     RCC_DIR = $${OUT_PWD}/.rcc
 150     UI_DIR = $${OUT_PWD}/.uic
 151 }
 152
 153 win32-msvc* {
 154     #Don't warn about sprintf, fopen etc being 'unsafe'
 155     DEFINES += _CRT_SECURE_NO_WARNINGS
 156 }