hirado/kernel/config/m68k/start.S

   1 /*
   2  *  TOPPERS/JSP Kernel
   3  *      Toyohashi Open Platform for Embedded Real-Time Systems/
   4  *      Just Standard Profile Kernel
   5  *
   6  *  Copyright (C) 2000-2003 by Embedded and Real-Time Systems Laboratory
   7  *                              Toyohashi Univ. of Technology, JAPAN
   8  *
   9  *  上記著作権者は，以下の (1)〜(4) の条件か，Free Software Foundation
  10  *  によって公表されている GNU General Public License の Version 2 に記
  11  *  述されている条件を満たす場合に限り，本ソフトウェア（本ソフトウェア
  12  *  を改変したものを含む．以下同じ）を使用・複製・改変・再配布（以下，
  13  *  利用と呼ぶ）することを無償で許諾する．
  14  *  (1) 本ソフトウェアをソースコードの形で利用する場合には，上記の著作
  15  *      権表示，この利用条件および下記の無保証規定が，そのままの形でソー
  16  *      スコード中に含まれていること．
  17  *  (2) 本ソフトウェアを，ライブラリ形式など，他のソフトウェア開発に使
  18  *      用できる形で再配布する場合には，再配布に伴うドキュメント（利用
  19  *      者マニュアルなど）に，上記の著作権表示，この利用条件および下記
  20  *      の無保証規定を掲載すること．
  21  *  (3) 本ソフトウェアを，機器に組み込むなど，他のソフトウェア開発に使
  22  *      用できない形で再配布する場合には，次のいずれかの条件を満たすこ
  23  *      と．
  24  *    (a) 再配布に伴うドキュメント（利用者マニュアルなど）に，上記の著
  25  *        作権表示，この利用条件および下記の無保証規定を掲載すること．
  26  *    (b) 再配布の形態を，別に定める方法によって，TOPPERSプロジェクトに
  27  *        報告すること．
  28  *  (4) 本ソフトウェアの利用により直接的または間接的に生じるいかなる損
  29  *      害からも，上記著作権者およびTOPPERSプロジェクトを免責すること．
  30  *
  31  *  本ソフトウェアは，無保証で提供されているものである．上記著作権者お
  32  *  よびTOPPERSプロジェクトは，本ソフトウェアに関して，その適用可能性も
  33  *  含めて，いかなる保証も行わない．また，本ソフトウェアの利用により直
  34  *  接的または間接的に生じたいかなる損害に関しても，その責任を負わない．
  35  *
  36  *  @(#) $Id: start.S,v 1.1 2009/01/31 05:27:37 suikan Exp $
  37  */
  38
  39 /*
  40  *  カーネル用のスタートアップモジュール（M68040用）
  41  */
  42
  43 #define _MACRO_ONLY
  44 #include <t_config.h>
  45
  46     .text
  47     .globl start
  48 start:
  49     /*
  50      *  プロセッサモードとスタックポインタの初期化
  51      */
  52     cinva %bc           /* すべてのキャッシュを無効化 */
  53     move.l #0x80008000, %d0     /* 両方のキャッシュを ON */
  54     movec.l %d0, %cacr
  55
  56     move.w %sr, %d0
  57     or.w #0x2700, %d0       /* スーパバイザモード，IPM=7に設定 */
  58     and.w #0xefff ,%d0      /* 割込みモードに設定 */
  59     move.w %d0, %sr
  60
  61     movea.l #STACKTOP, %sp      /* スタックポインタ（SPI）の初期化 */
  62     movea.l #0, %fp         /* フレームポインタの初期化 */
  63
  64     /*
  65      *  hardware_init_hook の呼出し（0 でない場合）
  66      *
  67      *  ターゲットハードウェアに依存して必要な初期化処理がある場合
  68      *  は，hardware_init_hook という関数を用意する．
  69      */
  70     move.l #hardware_init_hook, %a0
  71     cmp.l #0, %a0
  72     jbeq start_1
  73     jsr (%a0)
  74
  75     /*
  76      *  bssセクションのクリア
  77      */
  78 start_1:
  79     move.l #__bss_start, %a0
  80     move.l #_end, %d0
  81     sub.l %a0, %d0
  82     jbeq start_3
  83 start_2:
  84     clr.b (%a0)+
  85     dbra %d0, start_2
  86     clr.w %d0
  87     subq.l #1, %d0
  88     jbcc start_2
  89
  90     /*
  91      *  dataセクションの初期化（ROM化対応）
  92      *
  93      *  __idata_start から __idata_end までを，__data_start 以降に
  94      *  コピーする．
  95      */
  96 start_3:
  97     move.l #__idata_end, %d0
  98     sub.l #__idata_start, %d0
  99     jbls start_5
 100     move.l #__idata_start, %a0
 101     move.l #__data_start, %a1
 102 start_4:
 103     move.b (%a0)+, (%a1)+
 104     dbra %d0, start_4
 105     clr.w %d0
 106     subq.l #1, %d0
 107     jbcc start_4
 108
 109     /*
 110      *  software_init_hook を呼出し（0 でない場合）
 111      *
 112      *  ソフトウェア環境（特にライブラリ）に依存して必要な初期化処
 113      *  理がある場合は，software_init_hook という関数を用意すれば
 114      *  よい．
 115      */
 116 start_5:
 117     move.l #software_init_hook, %a0
 118     cmp.l #0, %a0
 119     jbeq start_6
 120     jsr (%a0)
 121
 122     /*
 123      *  カーネルを起動する．
 124      */
 125 start_6:
 126     jmp kernel_start