arch/h8300/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3
   4 #define ROMTOP 0x000000
   5 #define RAMTOP CONFIG_RAMBASE
   6
   7 jiffies = jiffies_64 + 4;
   8
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13 #if defined(CONFIG_ROMKERNEL)
  14         . = ROMTOP;
  15         .vectors :
  16         {
  17         _vector = . ;
  18                 *(.vector*)
  19         }
  20 #else
  21         . = RAMTOP;
  22         _ramstart = .;
  23         . = . + CONFIG_OFFSET;
  24 #endif
  25         _text = .;
  26         HEAD_TEXT_SECTION
  27         .text : {
  28         _stext = . ;
  29                 TEXT_TEXT
  30                 SCHED_TEXT
  31                 LOCK_TEXT
  32 #if defined(CONFIG_ROMKERNEL)
  33                 *(.int_redirect)
  34 #endif
  35         _etext = . ;
  36         }
  37         EXCEPTION_TABLE(16)
  38         NOTES
  39         RO_DATA(4)
  40 #if defined(CONFIG_ROMKERNEL)
  41         .init.text : {
  42                 _sinittext = .;
  43                 INIT_TEXT
  44                 _einittext = .;
  45         }
  46         SECURITY_INIT
  47 #endif
  48         ROMEND = .;
  49 #if defined(CONFIG_ROMKERNEL)
  50         . = RAMTOP;
  51         _ramstart = .;
  52         .data : AT(ROMEND)
  53 #else
  54         .data :
  55 #endif
  56         {
  57         _sdata = . ;
  58         __data_start = . ;
  59                 INIT_TASK_DATA(0x2000)
  60                 NOSAVE_DATA
  61                 PAGE_ALIGNED_DATA(0x1000)
  62                 CACHELINE_ALIGNED_DATA(0x0002)
  63                 READ_MOSTLY_DATA(0x0002)
  64                 DATA_DATA
  65                 CONSTRUCTORS
  66         }
  67         . = ALIGN(0x4) ;
  68         __init_begin = .;
  69 #if defined(CONFIG_RAMKERNEL)
  70         INIT_TEXT_SECTION(4)
  71 #endif
  72         INIT_DATA_SECTION(4)
  73 #if defined(CONFIG_RAMKERNEL)
  74         SECURITY_INIT
  75 #endif
  76         __init_end = .;
  77         _edata = . ;
  78         _begin_data = LOADADDR(.data);
  79         _sbss =.;
  80         BSS_SECTION(4,4,4)
  81         _ebss =.;
  82         _ramend = .;
  83         _end = .;
  84         DISCARDS
  85 }