arch/mips/kernel/r4k_switch.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1994, 1995, 1996, 1998, 1999, 2002, 2003 Ralf Baechle
   7  * Copyright (C) 1996 David S. Miller (davem@davemloft.net)
   8  * Copyright (C) 1994, 1995, 1996, by Andreas Busse
   9  * Copyright (C) 1999 Silicon Graphics, Inc.
  10  * Copyright (C) 2000 MIPS Technologies, Inc.
  11  *    written by Carsten Langgaard, carstenl@mips.com
  12  */
  13 #include <asm/asm.h>
  14 #include <asm/cachectl.h>
  15 #include <asm/fpregdef.h>
  16 #include <asm/mipsregs.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/pgtable-bits.h>
  19 #include <asm/regdef.h>
  20 #include <asm/stackframe.h>
  21 #include <asm/thread_info.h>
  22
  23 #include <asm/asmmacro.h>
  24
  25 /*
  26  * Offset to the current process status flags, the first 32 bytes of the
  27  * stack are not used.
  28  */
  29 #define ST_OFF (_THREAD_SIZE - 32 - PT_SIZE + PT_STATUS)
  30
  31 /*
  32  * task_struct *resume(task_struct *prev, task_struct *next,
  33  *                     struct thread_info *next_ti, s32 fp_save)
  34  */
  35         .align  5
  36         LEAF(resume)
  37         mfc0    t1, CP0_STATUS
  38         LONG_S  t1, THREAD_STATUS(a0)
  39         cpu_save_nonscratch a0
  40         LONG_S  ra, THREAD_REG31(a0)
  41
  42         /*
  43          * Check whether we need to save any FP context. FP context is saved
  44          * iff the process has used the context with the scalar FPU or the MSA
  45          * ASE in the current time slice, as indicated by _TIF_USEDFPU and
  46          * _TIF_USEDMSA respectively. switch_to will have set fp_save
  47          * accordingly to an FP_SAVE_ enum value.
  48          */
  49         beqz    a3, 2f
  50
  51         /*
  52          * We do. Clear the saved CU1 bit for prev, such that next time it is
  53          * scheduled it will start in userland with the FPU disabled. If the
  54          * task uses the FPU then it will be enabled again via the do_cpu trap.
  55          * This allows us to lazily restore the FP context.
  56          */
  57         PTR_L   t3, TASK_THREAD_INFO(a0)
  58         LONG_L  t0, ST_OFF(t3)
  59         li      t1, ~ST0_CU1
  60         and     t0, t0, t1
  61         LONG_S  t0, ST_OFF(t3)
  62
  63         /* Check whether we're saving scalar or vector context. */
  64         bgtz    a3, 1f
  65
  66         /* Save 128b MSA vector context. */
  67         msa_save_all    a0
  68         b       2f
  69
  70 1:      /* Save 32b/64b scalar FP context. */
  71         fpu_save_double a0 t0 t1                # c0_status passed in t0
  72                                                 # clobbers t1
  73 2:
  74
  75 #if defined(CONFIG_CC_STACKPROTECTOR) && !defined(CONFIG_SMP)
  76         PTR_LA  t8, __stack_chk_guard
  77         LONG_L  t9, TASK_STACK_CANARY(a1)
  78         LONG_S  t9, 0(t8)
  79 #endif
  80
  81         /*
  82          * The order of restoring the registers takes care of the race
  83          * updating $28, $29 and kernelsp without disabling ints.
  84          */
  85         move    $28, a2
  86         cpu_restore_nonscratch a1
  87
  88         PTR_ADDU        t0, $28, _THREAD_SIZE - 32
  89         set_saved_sp    t0, t1, t2
  90         mfc0    t1, CP0_STATUS          /* Do we really need this? */
  91         li      a3, 0xff01
  92         and     t1, a3
  93         LONG_L  a2, THREAD_STATUS(a1)
  94         nor     a3, $0, a3
  95         and     a2, a3
  96         or      a2, t1
  97         mtc0    a2, CP0_STATUS
  98         move    v0, a0
  99         jr      ra
 100         END(resume)
 101
 102 /*
 103  * Save a thread's fp context.
 104  */
 105 LEAF(_save_fp)
 106 #if defined(CONFIG_64BIT) || defined(CONFIG_CPU_MIPS32_R2)
 107         mfc0    t0, CP0_STATUS
 108 #endif
 109         fpu_save_double a0 t0 t1                # clobbers t1
 110         jr      ra
 111         END(_save_fp)
 112
 113 /*
 114  * Restore a thread's fp context.
 115  */
 116 LEAF(_restore_fp)
 117 #if defined(CONFIG_64BIT) || defined(CONFIG_CPU_MIPS32_R2)
 118         mfc0    t0, CP0_STATUS
 119 #endif
 120         fpu_restore_double a0 t0 t1             # clobbers t1
 121         jr      ra
 122         END(_restore_fp)
 123
 124 #ifdef CONFIG_CPU_HAS_MSA
 125
 126 /*
 127  * Save a thread's MSA vector context.
 128  */
 129 LEAF(_save_msa)
 130         msa_save_all    a0
 131         jr      ra
 132         END(_save_msa)
 133
 134 /*
 135  * Restore a thread's MSA vector context.
 136  */
 137 LEAF(_restore_msa)
 138         msa_restore_all a0
 139         jr      ra
 140         END(_restore_msa)
 141
 142 #endif
 143
 144 /*
 145  * Load the FPU with signalling NANS.  This bit pattern we're using has
 146  * the property that no matter whether considered as single or as double
 147  * precision represents signaling NANS.
 148  *
 149  * We initialize fcr31 to rounding to nearest, no exceptions.
 150  */
 151
 152 #define FPU_DEFAULT  0x00000000
 153
 154 LEAF(_init_fpu)
 155         mfc0    t0, CP0_STATUS
 156         li      t1, ST0_CU1
 157         or      t0, t1
 158         mtc0    t0, CP0_STATUS
 159         enable_fpu_hazard
 160
 161         li      t1, FPU_DEFAULT
 162         ctc1    t1, fcr31
 163
 164         li      t1, -1                          # SNaN
 165
 166 #ifdef CONFIG_64BIT
 167         sll     t0, t0, 5
 168         bgez    t0, 1f                          # 16 / 32 register mode?
 169
 170         dmtc1   t1, $f1
 171         dmtc1   t1, $f3
 172         dmtc1   t1, $f5
 173         dmtc1   t1, $f7
 174         dmtc1   t1, $f9
 175         dmtc1   t1, $f11
 176         dmtc1   t1, $f13
 177         dmtc1   t1, $f15
 178         dmtc1   t1, $f17
 179         dmtc1   t1, $f19
 180         dmtc1   t1, $f21
 181         dmtc1   t1, $f23
 182         dmtc1   t1, $f25
 183         dmtc1   t1, $f27
 184         dmtc1   t1, $f29
 185         dmtc1   t1, $f31
 186 1:
 187 #endif
 188
 189 #ifdef CONFIG_CPU_MIPS32
 190         mtc1    t1, $f0
 191         mtc1    t1, $f1
 192         mtc1    t1, $f2
 193         mtc1    t1, $f3
 194         mtc1    t1, $f4
 195         mtc1    t1, $f5
 196         mtc1    t1, $f6
 197         mtc1    t1, $f7
 198         mtc1    t1, $f8
 199         mtc1    t1, $f9
 200         mtc1    t1, $f10
 201         mtc1    t1, $f11
 202         mtc1    t1, $f12
 203         mtc1    t1, $f13
 204         mtc1    t1, $f14
 205         mtc1    t1, $f15
 206         mtc1    t1, $f16
 207         mtc1    t1, $f17
 208         mtc1    t1, $f18
 209         mtc1    t1, $f19
 210         mtc1    t1, $f20
 211         mtc1    t1, $f21
 212         mtc1    t1, $f22
 213         mtc1    t1, $f23
 214         mtc1    t1, $f24
 215         mtc1    t1, $f25
 216         mtc1    t1, $f26
 217         mtc1    t1, $f27
 218         mtc1    t1, $f28
 219         mtc1    t1, $f29
 220         mtc1    t1, $f30
 221         mtc1    t1, $f31
 222
 223 #ifdef CONFIG_CPU_MIPS32_R2
 224         .set    push
 225         .set    mips64r2
 226         sll     t0, t0, 5                       # is Status.FR set?
 227         bgez    t0, 1f                          # no: skip setting upper 32b
 228
 229         mthc1   t1, $f0
 230         mthc1   t1, $f1
 231         mthc1   t1, $f2
 232         mthc1   t1, $f3
 233         mthc1   t1, $f4
 234         mthc1   t1, $f5
 235         mthc1   t1, $f6
 236         mthc1   t1, $f7
 237         mthc1   t1, $f8
 238         mthc1   t1, $f9
 239         mthc1   t1, $f10
 240         mthc1   t1, $f11
 241         mthc1   t1, $f12
 242         mthc1   t1, $f13
 243         mthc1   t1, $f14
 244         mthc1   t1, $f15
 245         mthc1   t1, $f16
 246         mthc1   t1, $f17
 247         mthc1   t1, $f18
 248         mthc1   t1, $f19
 249         mthc1   t1, $f20
 250         mthc1   t1, $f21
 251         mthc1   t1, $f22
 252         mthc1   t1, $f23
 253         mthc1   t1, $f24
 254         mthc1   t1, $f25
 255         mthc1   t1, $f26
 256         mthc1   t1, $f27
 257         mthc1   t1, $f28
 258         mthc1   t1, $f29
 259         mthc1   t1, $f30
 260         mthc1   t1, $f31
 261 1:      .set    pop
 262 #endif /* CONFIG_CPU_MIPS32_R2 */
 263 #else
 264         .set    arch=r4000
 265         dmtc1   t1, $f0
 266         dmtc1   t1, $f2
 267         dmtc1   t1, $f4
 268         dmtc1   t1, $f6
 269         dmtc1   t1, $f8
 270         dmtc1   t1, $f10
 271         dmtc1   t1, $f12
 272         dmtc1   t1, $f14
 273         dmtc1   t1, $f16
 274         dmtc1   t1, $f18
 275         dmtc1   t1, $f20
 276         dmtc1   t1, $f22
 277         dmtc1   t1, $f24
 278         dmtc1   t1, $f26
 279         dmtc1   t1, $f28
 280         dmtc1   t1, $f30
 281 #endif
 282         jr      ra
 283         END(_init_fpu)