tools/misc/nettel2520.gdb

   1 #
   2 # GDB Init script for the NETtel ColdFire 5307 board.
   3 #
   4 # The main purpose of this script is to configure the
   5 # DRAM controller so code can be loaded.
   6 #
   7
   8 define addresses
   9
  10 set $mbar  = 0x10000001
  11 set $rsr   = $mbar - 1 + 0x000
  12 set $sypcr = $mbar - 1 + 0x001
  13 set $swivr = $mbar - 1 + 0x002
  14 set $swsr  = $mbar - 1 + 0x003
  15 set $simr  = $mbar - 1 + 0x003
  16 set $par   = $mbar - 1 + 0x004
  17 set $irqpar= $mbar - 1 + 0x006
  18 set $pllcr = $mbar - 1 + 0x008
  19 set $mpark = $mbar - 1 + 0x00c
  20 set $ipr   = $mbar - 1 + 0x040
  21 set $imr   = $mbar - 1 + 0x044
  22
  23 set $icr0  = $mbar - 1 + 0x04c
  24 set $icr1  = $mbar - 1 + 0x04d
  25 set $icr2  = $mbar - 1 + 0x04e
  26 set $icr3  = $mbar - 1 + 0x04f
  27 set $icr4  = $mbar - 1 + 0x050
  28 set $icr5  = $mbar - 1 + 0x051
  29 set $icr6  = $mbar - 1 + 0x052
  30 set $icr7  = $mbar - 1 + 0x053
  31 set $icr8  = $mbar - 1 + 0x054
  32 set $icr9  = $mbar - 1 + 0x055
  33 set $icr10 = $mbar - 1 + 0x056
  34 set $icr11 = $mbar - 1 + 0x057
  35
  36 set $csar0 = $mbar - 1 + 0x080
  37 set $csmr0 = $mbar - 1 + 0x084
  38 set $cscr0 = $mbar - 1 + 0x08a
  39 set $csar1 = $mbar - 1 + 0x08c
  40 set $csmr1 = $mbar - 1 + 0x090
  41 set $cscr1 = $mbar - 1 + 0x096
  42 set $csar2 = $mbar - 1 + 0x098
  43 set $csmr2 = $mbar - 1 + 0x09c
  44 set $cscr2 = $mbar - 1 + 0x0a2
  45 set $csar3 = $mbar - 1 + 0x0a4
  46 set $csmr3 = $mbar - 1 + 0x0a8
  47 set $cscr3 = $mbar - 1 + 0x0ae
  48 set $csar4 = $mbar - 1 + 0x0b0
  49 set $csmr4 = $mbar - 1 + 0x0b4
  50 set $cscr4 = $mbar - 1 + 0x0ba
  51 set $csar5 = $mbar - 1 + 0x0bc
  52 set $csmr5 = $mbar - 1 + 0x0c0
  53 set $cscr5 = $mbar - 1 + 0x0c6
  54 set $csar6 = $mbar - 1 + 0x0c8
  55 set $csmr6 = $mbar - 1 + 0x0cc
  56 set $cscr6 = $mbar - 1 + 0x0d2
  57 set $csar7 = $mbar - 1 + 0x0d4
  58 set $csmr7 = $mbar - 1 + 0x0d8
  59 set $cscr7 = $mbar - 1 + 0x0de
  60
  61 set $dcr   = $mbar - 1 + 0x100
  62 set $dacr0 = $mbar - 1 + 0x108
  63 set $dmr0  = $mbar - 1 + 0x10c
  64 set $dacr1 = $mbar - 1 + 0x110
  65 set $dmr1  = $mbar - 1 + 0x114
  66
  67 set $tmr1  = $mbar - 1 + 0x140
  68 set $trr1  = $mbar - 1 + 0x144
  69 set $tcr1  = $mbar - 1 + 0x148
  70 set $tcn1  = $mbar - 1 + 0x14C
  71 set $ter1  = $mbar - 1 + 0x151
  72 set $tmr2  = $mbar - 1 + 0x180
  73 set $trr2  = $mbar - 1 + 0x184
  74 set $tcr2  = $mbar - 1 + 0x188
  75 set $tcn2  = $mbar - 1 + 0x18C
  76 set $ter2  = $mbar - 1 + 0x191
  77
  78 set $paddr = $mbar - 1 + 0x244
  79 set $padat = $mbar - 1 + 0x248
  80
  81 end
  82
  83 #
  84 #  Setup RAMBAR for the internal SRAM.
  85 #
  86
  87 define setup-sram
  88 set $rambar  = 0x20000001
  89 end
  90
  91
  92 #
  93 #       Setup Parallel I/O ports...
  94 #
  95
  96 define setup-pp
  97 set *((unsigned short *) $par) = 0x0000
  98 set *((unsigned short *) $paddr) = 0x00ec
  99 set *((unsigned short *) $padat) = 0x0000
 100 end
 101
 102
 103 #
 104 #  Setup chip selects...
 105 #
 106 #  These are defined so that they are compatible with both the
 107 #  old and new mask 5307 chips, so be carefull if you modify.
 108 #
 109
 110 define setup-cs
 111
 112 # CS0 -- FLASH ROM
 113 set *((unsigned short *) $csar0) = 0xf000
 114 set *((unsigned long *) $csmr0)  = 0x001f0001
 115 set *((unsigned short *) $cscr0) = 0x3d80
 116
 117 # CS1 -- Optional 2nd FLASH ROM.
 118 set *((unsigned short *) $csar1) = 0xf020
 119 set *((unsigned long *) $csmr1)  = 0x001f0001
 120 set *((unsigned short *) $cscr1) = 0x3d80
 121
 122 # CS2 -- LED bank is on address=0x30400000
 123 set *((unsigned short *) $csar2) = 0x3040
 124 set *((unsigned long *) $csmr2)  = 0x000f0001
 125 set *((unsigned short *) $cscr2) = 0x3d40
 126
 127 # CS3 -- Ethernet, address=0x30600000
 128 set *((unsigned short *) $csar3) = 0x3060
 129 set *((unsigned long *) $csmr3)  = 0x000f0001
 130 set *((unsigned short *) $cscr3) = 0x1180
 131
 132 # CS4 -- Nothing, address=0x30800000
 133 set *((unsigned short *) $csar4) = 0x3080
 134 set *((unsigned long *) $csmr4)  = 0x000f0001
 135 set *((unsigned short *) $cscr4) = 0x3d40
 136
 137 # CS5 -- Nothing, address=0x30a00000
 138 set *((unsigned short *) $csar5) = 0x30a0
 139 set *((unsigned long *) $csmr5)  = 0x000f0001
 140 set *((unsigned short *) $cscr5) = 0x3d40
 141
 142 # CS6 -- Optional Hifn 7901, address=0x30c00000
 143 set *((unsigned short *) $csar6) = 0x30c0
 144 set *((unsigned long *) $csmr6)  = 0x000f0001
 145 set *((unsigned short *) $cscr6) = 0x3d00
 146
 147 # CS7 -- Nothing, address=0x30e00000
 148 set *((unsigned short *) $csar7) = 0x30e0
 149 set *((unsigned long *) $csmr7)  = 0x000f0001
 150 set *((unsigned short *) $cscr7) = 0x3d40
 151
 152 end
 153
 154
 155 #
 156 #       GDB boot loader
 157 #
 158 define bootload
 159 cont
 160 load boot/etherboot/ethboot-bdm.elf
 161 load boot/boot-bdm.elf
 162 symbol-file boot/boot-bdm.elf
 163 set $pc=_start
 164 add-symbol-file boot/etherboot/ethboot-bdm.elf &etherboot_addr
 165 echo \nType 'cont' to start bootloader...\n
 166 end
 167
 168
 169 #
 170 #       NETtel ColdFire 5307 target...
 171 #
 172 target bdm /dev/bdmcf0
 173
 174 addresses
 175 setup-sram
 176 setup-cs
 177 setup-pp
 178 load bin/nettelmem.elf
 179 set $pc = 0x20000000
 180 set $sp = 0x20000400
 181 set $fp = 0x20000400
 182 set $vbr = 0x20000000
 183 set $ps = 0x2700
 184
 185 set print pretty
 186 set print asm-demangle
 187 display/i $pc
 188 select-frame 0
 189