user/rsyslog/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.61)
   5 AC_INIT([rsyslog],[3.16.1],[rsyslog@lists.adiscon.com])
   6 AM_INIT_AUTOMAKE
   7 AC_CONFIG_SRCDIR([syslogd.c])
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AC_GNU_SOURCE
  11
  12 # Checks for programs.
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 if test "$GCC" = "yes"
  16 then CFLAGS="$CFLAGS -W -Wall -Wformat-security -Wshadow -Wcast-align -Wpointer-arith -Wmissing-format-attribute -g"
  17 fi
  18 AC_DISABLE_STATIC
  19 AC_PROG_LIBTOOL
  20 AC_CANONICAL_HOST
  21
  22 case "${host}" in
  23   *-*-linux*)
  24   ;;
  25   *-*-*darwin*|*-*-freebsd*|*-*-netbsd*|*-*-openbsd*)
  26     AC_DEFINE([BSD], [1], [Description])
  27   ;;
  28 esac
  29
  30 AC_DEFINE_UNQUOTED([HOSTENV], "$host", [the host environment, can be queried via a system variable])
  31
  32 # Checks for libraries.
  33 save_LIBS=$LIBS
  34 LIBS=
  35 AC_SEARCH_LIBS(clock_gettime, rt)
  36 rt_libs=$LIBS
  37 LIBS=
  38 AC_SEARCH_LIBS(dlopen, dl)
  39 dl_libs=$LIBS
  40 LIBS=$save_LIBS
  41
  42 AC_SUBST(rt_libs)
  43 AC_SUBST(dl_libs)
  44
  45 # Checks for header files.
  46 AC_HEADER_RESOLV
  47 AC_HEADER_STDC
  48 AC_HEADER_SYS_WAIT
  49 AC_CHECK_HEADERS([arpa/inet.h libgen.h fcntl.h locale.h netdb.h netinet/in.h paths.h stddef.h stdlib.h string.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h sys/stat.h syslog.h unistd.h utmp.h])
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_CONST
  53 AC_C_INLINE
  54 AC_TYPE_OFF_T
  55 AC_TYPE_PID_T
  56 AC_TYPE_SIZE_T
  57 AC_TYPE_SSIZE_T
  58 AC_TYPE_MODE_T
  59 AC_TYPE_UID_T
  60 AC_TYPE_UINT8_T
  61 AC_HEADER_TIME
  62 AC_STRUCT_TM
  63 AC_C_VOLATILE
  64
  65 sa_includes="\
  66 $ac_includes_default
  67 #if HAVE_SYS_SOCKET_H
  68 # include <sys/socket.h>
  69 #endif
  70 "
  71 AC_CHECK_MEMBERS([struct sockaddr.sa_len],,,[$sa_includes])
  72
  73 # Checks for library functions.
  74 AC_FUNC_CHOWN
  75 AC_FUNC_FORK
  76 AC_PROG_GCC_TRADITIONAL
  77 AC_FUNC_REALLOC
  78 AC_FUNC_SELECT_ARGTYPES
  79 AC_TYPE_SIGNAL
  80 AC_FUNC_STAT
  81 AC_FUNC_STRERROR_R
  82 AC_FUNC_VPRINTF
  83 AC_CHECK_FUNCS([flock basename alarm clock_gettime gethostbyname gethostname gettimeofday localtime_r memset mkdir regcomp select setid socket strcasecmp strchr strdup strerror strndup strnlen strrchr strstr strtol strtoul uname ttyname_r])
  84
  85
  86 # Large file support
  87 AC_ARG_ENABLE(largefile,
  88         [AS_HELP_STRING([--enable-largefile],[Enable large file support @<:@default=yes@:>@])],
  89         [case "${enableval}" in
  90          yes) enable_largefile="yes" ;;
  91           no) enable_largefile="no" ;;
  92            *) AC_MSG_ERROR(bad value ${enableval} for --enable-largefile) ;;
  93          esac],
  94         [enable_largefile="yes"]
  95 )
  96 if test "$enable_largefile" = "no"; then
  97         AC_DEFINE(NOLARGEFILE, 1, [Defined when large file support is disabled.])
  98 fi
  99
 100 # Regular expressions
 101 AC_ARG_ENABLE(regexp,
 102         [AS_HELP_STRING([--enable-regexp],[Enable regular expressions support @<:@default=yes@:>@])],
 103         [case "${enableval}" in
 104          yes) enable_regexp="yes" ;;
 105           no) enable_regexp="no" ;;
 106            *) AC_MSG_ERROR(bad value ${enableval} for --enable-regexp) ;;
 107          esac],
 108         [enable_regexp=yes]
 109 )
 110 AM_CONDITIONAL(ENABLE_REGEXP, test x$enable_regexp = xyes)
 111 if test "$enable_regexp" = "yes"; then
 112         AC_DEFINE(FEATURE_REGEXP, 1, [Regular expressions support enabled.])
 113 fi
 114
 115 # zlib compression
 116 AC_ARG_ENABLE(zlib,
 117         [AS_HELP_STRING([--enable-zlib],[Enable zlib compression  support @<:@default=yes@:>@])],
 118         [case "${enableval}" in
 119          yes) enable_zlib="yes" ;;
 120           no) enable_zlib="no" ;;
 121            *) AC_MSG_ERROR(bad value ${enableval} for --enable-zlib) ;;
 122          esac],
 123         [enable_zlib=yes]
 124 )
 125 if test "$enable_zlib" = "yes"; then
 126         AC_CHECK_HEADER(zlib.h, [zlib_header="yes"], [zlib_header="no" enable_zlib="false"])
 127         if test "$zlib_header" = "yes"; then
 128                 AC_CHECK_LIB(z, deflate,
 129                         [AC_DEFINE(USE_NETZIP, 1, [Define if you want to enable zlib support])
 130                          zlib_libs="-lz"
 131                          AC_SUBST(zlib_libs)], enable_zlib="false")
 132         fi
 133 fi
 134
 135 #gssapi
 136 AC_ARG_ENABLE(gssapi_krb5,
 137         [AS_HELP_STRING([--enable-gssapi-krb5],[Enable GSSAPI Kerberos 5 support @<:@default=no@:>@])],
 138         [case "${enableval}" in
 139          yes) want_gssapi_krb5="yes" ;;
 140           no) want_gssapi_krb5="no" ;;
 141            *) AC_MSG_ERROR(bad value ${enableval} for --enable-gssapi-krb5) ;;
 142          esac],
 143         [want_gssapi_krb5=no]
 144 )
 145 if test $want_gssapi_krb5 = yes; then
 146         AC_CHECK_LIB(gssapi_krb5, gss_acquire_cred, [
 147                 AC_CHECK_HEADER(gssapi/gssapi.h, [
 148                         AC_DEFINE(USE_GSSAPI,,
 149                                   Define if you want to use GSSAPI)
 150                         gss_libs="-lgssapi_krb5"
 151                         AC_SUBST(gss_libs)
 152                 ])
 153         ])
 154 fi
 155 AM_CONDITIONAL(ENABLE_GSSAPI, test x$want_gssapi_krb5 = xyes)
 156
 157 # multithreading via pthreads
 158 AC_ARG_ENABLE(pthreads,
 159         [AS_HELP_STRING([--enable-pthreads],[Enable multithreading via pthreads @<:@default=yes@:>@])],
 160         [case "${enableval}" in
 161          yes) enable_pthreads="yes" ;;
 162           no) enable_pthreads="no" ;;
 163            *) AC_MSG_ERROR(bad value ${enableval} for --enable-pthreads) ;;
 164          esac],
 165         [enable_pthreads=yes]
 166 )
 167
 168 if test "x$enable_pthreads" = "xno"; then
 169         AC_MSG_ERROR(rsyslog v3 does no longer support single threading mode -- use a previous version for that);
 170 fi
 171
 172 if test "x$enable_pthreads" != "xno"; then
 173   AC_CHECK_HEADERS(
 174     [pthread.h],
 175     [
 176       AC_CHECK_LIB(
 177         [pthread],
 178         [pthread_create],
 179         [
 180           AC_DEFINE([USE_PTHREADS], [1], [Multithreading support enabled.])
 181           pthreads_libs="-lpthread"
 182           pthreads_cflags="-pthread"
 183           AC_SUBST(pthreads_libs)
 184           AC_SUBST(pthreads_cflags)
 185         ],
 186         [AC_MSG_FAILURE([pthread is missing])],
 187         [-lpthread]
 188       )
 189     ],
 190     [AC_MSG_FAILURE([pthread is missing])]
 191   )
 192 fi
 193
 194 # klog
 195 AC_ARG_ENABLE(klog,
 196         [AS_HELP_STRING([--enable-klog],[Integrated klog functionality @<:@default=yes@:>@])],
 197         [case "${enableval}" in
 198          yes) enable_klog="yes" ;;
 199           no) enable_klog="no" ;;
 200            *) AC_MSG_ERROR(bad value ${enableval} for --enable-klog) ;;
 201          esac],
 202         [enable_klog="yes"]
 203 )
 204 AM_CONDITIONAL(ENABLE_IMKLOGD, test x$enable_klog = xyes)
 205
 206 #
 207 # SYSLOG_UNIXAF
 208 #
 209 AC_MSG_CHECKING(for SYSLOG_UNIXAF support)
 210 AC_ARG_ENABLE([unix],
 211   [AS_HELP_STRING([--disable-unix], [Disable support for unix])],
 212   [
 213     if test "x${enableval}" = "xyes"; then
 214       AC_MSG_RESULT([yes])
 215       AC_DEFINE([SYSLOG_UNIXAF], [1], [Description])
 216     else
 217       AC_MSG_RESULT([no])
 218     fi
 219   ],
 220   [
 221     # enabled by default
 222     AC_MSG_RESULT([yes])
 223     AC_DEFINE([SYSLOG_UNIXAF], [1], [Description])
 224   ])
 225
 226 # inet
 227 AC_ARG_ENABLE(inet,
 228         [AS_HELP_STRING([--enable-inet],[Enable networking support @<:@default=yes@:>@])],
 229         [case "${enableval}" in
 230          yes) enable_inet="yes" ;;
 231           no) enable_inet="no" ;;
 232            *) AC_MSG_ERROR(bad value ${enableval} for --enable-inet) ;;
 233          esac],
 234         [enable_inet="yes"]
 235 )
 236 AM_CONDITIONAL(ENABLE_INET, test x$enable_inet = xyes)
 237 if test "$enable_inet" = "yes"; then
 238         AC_DEFINE(SYSLOG_INET, 1, [network support is integrated.])
 239 fi
 240
 241 #
 242 # The following define determines whether the package adheres to the
 243 # file system standard.
 244 #
 245 AC_MSG_CHECKING(for FSSTND support)
 246 AC_ARG_ENABLE([fsstnd],
 247   [AS_HELP_STRING([--disable-fsstnd], [Disable support for FSSTND])],
 248   [
 249     if test "x${enableval}" = "xyes"; then
 250       AC_MSG_RESULT([yes])
 251       AC_DEFINE([FSSTND], [1], [Description])
 252     else
 253       AC_MSG_RESULT([no])
 254     fi
 255   ],
 256   [
 257     # enabled by default
 258     AC_MSG_RESULT([yes])
 259     AC_DEFINE([FSSTND], [1], [Description])
 260   ])
 261
 262 # debug
 263 AC_ARG_ENABLE(debug,
 264         [AS_HELP_STRING([--enable-debug],[Enable debug mode @<:@default=no@:>@])],
 265         [case "${enableval}" in
 266          yes) enable_debug="yes" ;;
 267           no) enable_debug="no" ;;
 268            *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 269          esac],
 270         [enable_debug="no"]
 271 )
 272 if test "$enable_debug" = "yes"; then
 273         AC_DEFINE(DEBUG, 1, [Defined if debug mode is enabled (its easier to check).])
 274 fi
 275 if test "$enable_debug" = "no"; then
 276         AC_DEFINE(NDEBUG, 1, [Defined if debug mode is disabled.])
 277 fi
 278
 279 # runtime instrumentation
 280 AC_ARG_ENABLE(rtinst,
 281         [AS_HELP_STRING([--enable-rtinst],[Enable runtime instrumentation mode @<:@default=no@:>@])],
 282         [case "${enableval}" in
 283          yes) enable_rtinst="yes" ;;
 284           no) enable_rtinst="no" ;;
 285            *) AC_MSG_ERROR(bad value ${enableval} for --enable-rtinst) ;;
 286          esac],
 287         [enable_rtinst="no"]
 288 )
 289 if test "$enable_rtinst" = "yes"; then
 290         AC_DEFINE(RTINST, 1, [Defined if runtime instrumentation mode is enabled.])
 291 fi
 292
 293 # valgrind
 294 AC_ARG_ENABLE(valgrind,
 295         [AS_HELP_STRING([--enable-valgrind],[Enable valgrind support settings @<:@default=no@:>@])],
 296         [case "${enableval}" in
 297          yes) enable_valgrind="yes" ;;
 298           no) enable_valgrind="no" ;;
 299            *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind) ;;
 300          esac],
 301         [enable_valgrind="no"]
 302 )
 303 if test "$enable_valgrind" = "yes"; then
 304         AC_DEFINE(VALGRIND, 1, [Defined if valgrind support settings are to be enabled (e.g. prevents dlclose()).])
 305 fi
 306
 307
 308
 309 # MySQL support
 310 AC_ARG_ENABLE(mysql,
 311         [AS_HELP_STRING([--enable-mysql],[Enable MySql database support @<:@default=no@:>@])],
 312         [case "${enableval}" in
 313          yes) enable_mysql="yes" ;;
 314           no) enable_mysql="no" ;;
 315            *) AC_MSG_ERROR(bad value ${enableval} for --enable-mysql) ;;
 316          esac],
 317         [enable_mysql=no]
 318 )
 319 if test "x$enable_mysql" = "xyes"; then
 320   AC_CHECK_HEADERS(
 321     [mysql/mysql.h],,
 322     [AC_MSG_FAILURE([MySQL is missing])]
 323   )
 324   AC_CHECK_PROG(
 325     [HAVE_MYSQL_CONFIG],
 326     [mysql_config],
 327     [yes],,,
 328   )
 329   if test "x${HAVE_MYSQL_CONFIG}" != "xyes"; then
 330     AC_MSG_FAILURE([mysql_config not found in PATH])
 331   fi
 332   AC_CHECK_LIB(
 333     [mysqlclient],
 334     [mysql_init],
 335     [mysql_cflags=`mysql_config --cflags`
 336      mysql_libs=`mysql_config --libs`
 337     ],
 338     [AC_MSG_FAILURE([MySQL library is missing])],
 339     [`mysql_config --libs`]
 340   )
 341 fi
 342 AM_CONDITIONAL(ENABLE_MYSQL, test x$enable_mysql = xyes)
 343 AC_SUBST(mysql_cflags)
 344 AC_SUBST(mysql_libs)
 345
 346
 347 # PostgreSQL support
 348 AC_ARG_ENABLE(pgsql,
 349         [AS_HELP_STRING([--enable-pgsql],[Enable PostgreSQL database support @<:@default=no@:>@])],
 350         [case "${enableval}" in
 351          yes) enable_pgsql="yes" ;;
 352           no) enable_pgsql="no" ;;
 353            *) AC_MSG_ERROR(bad value ${enableval} for --enable-pgsql) ;;
 354          esac],
 355         [enable_pgsql=no]
 356 )
 357 if test "x$enable_pgsql" = "xyes"; then
 358   AC_CHECK_PROG(
 359     [HAVE_PGSQL_CONFIG],
 360     [pg_config],
 361     [yes],,,
 362   )
 363   if test "x${HAVE_PGSQL_CONFIG}" != "xyes"; then
 364     AC_MSG_FAILURE([pg_config not found in PATH])
 365   fi
 366   AC_CHECK_LIB(
 367     [pq],
 368     [PQconnectdb],
 369     [pgsql_cflags="-I`pg_config --includedir`"
 370      pgsql_libs="-L`pg_config --libdir` -lpq"
 371     ],
 372     [AC_MSG_FAILURE([PgSQL library is missing])],
 373     [-L`pg_config --libdir`]
 374   )
 375 fi
 376 AM_CONDITIONAL(ENABLE_PGSQL, test x$enable_pgsql = xyes)
 377 AC_SUBST(pgsql_cflags)
 378 AC_SUBST(pgsql_libs)
 379
 380
 381 # libdbi support
 382 AC_ARG_ENABLE(libdbi,
 383         [AS_HELP_STRING([--enable-libdbi],[Enable libdbi database support @<:@default=no@:>@])],
 384         [case "${enableval}" in
 385          yes) enable_libdbi="yes" ;;
 386           no) enable_libdbi="no" ;;
 387            *) AC_MSG_ERROR(bad value ${enableval} for --enable-libdbi) ;;
 388          esac],
 389         [enable_libdbi=no]
 390 )
 391 if test "x$enable_libdbi" = "xyes"; then
 392   AC_CHECK_HEADERS(
 393     [dbi/dbi.h],,
 394     [AC_MSG_FAILURE([libdbi is missing])]
 395   )
 396   AC_CHECK_LIB(
 397     [dbi],
 398     [dbi_initialize],
 399     [libdbi_cflags=""
 400      libdbi_libs="-ldbi"
 401     ],
 402     [AC_MSG_FAILURE([libdbi library is missing])]
 403   )
 404   AC_CHECK_LIB(
 405     [dbi],
 406     [dbi_initialize_r],
 407     [AC_DEFINE([HAVE_DBI_R], [1], [Define to 1 if libdbi supports the new plugin-safe interface])]
 408   )
 409 fi
 410 AM_CONDITIONAL(ENABLE_OMLIBDBI, test x$enable_libdbi = xyes)
 411 AC_SUBST(libdbi_cflags)
 412 AC_SUBST(libdbi_libs)
 413
 414
 415 # SNMP support
 416 AC_ARG_ENABLE(snmp,
 417         [AS_HELP_STRING([--enable-snmp],[Enable SNMP support @<:@default=no@:>@])],
 418         [case "${enableval}" in
 419          yes) enable_snmp="yes" ;;
 420           no) enable_snmp="no" ;;
 421            *) AC_MSG_ERROR(bad value ${enableval} for --enable-snmp) ;;
 422          esac],
 423         [enable_snmp=no]
 424 )
 425 if test "x$enable_snmp" = "xyes"; then
 426   AC_CHECK_HEADERS(
 427     [net-snmp/net-snmp-config.h],,
 428     [AC_MSG_FAILURE([Net-SNMP is missing])]
 429   )
 430   AC_CHECK_LIB(
 431     [netsnmp],
 432     [snmp_timeout],
 433     [snmp_cflags=""
 434      snmp_libs="-lnetsnmp"
 435     ],
 436     [AC_MSG_FAILURE([Net-SNMP library is missing])]
 437   )
 438 fi
 439 AM_CONDITIONAL(ENABLE_SNMP, test x$enable_snmp = xyes)
 440 AC_SUBST(snmp_cflags)
 441 AC_SUBST(snmp_libs)
 442
 443
 444 # support for NOT building rsyslogd (useful for source-based packaging systems)
 445 AC_ARG_ENABLE(rsyslogd,
 446         [AS_HELP_STRING([--enable-rsyslogd],[Build rsyslogd @<:@default=yes@:>@])],
 447         [case "${enableval}" in
 448          yes) enable_rsyslogd="yes" ;;
 449           no) enable_rsyslogd="no" ;;
 450            *) AC_MSG_ERROR(bad value ${enableval} for --enable-rsyslogd) ;;
 451          esac],
 452         [enable_rsyslogd=yes]
 453 )
 454 AM_CONDITIONAL(ENABLE_RSYSLOGD, test x$enable_rsyslogd = xyes)
 455
 456
 457 # RELP support
 458 AC_ARG_ENABLE(relp,
 459         [AS_HELP_STRING([--enable-relp],[Enable RELP support @<:@default=no@:>@])],
 460         [case "${enableval}" in
 461          yes) enable_relp="yes" ;;
 462           no) enable_relp="no" ;;
 463            *) AC_MSG_ERROR(bad value ${enableval} for --enable-relp) ;;
 464          esac],
 465         [enable_relp=no]
 466 )
 467 if test "x$enable_relp" = "xyes"; then
 468         PKG_CHECK_MODULES(RELP, relp)
 469 fi
 470 AM_CONDITIONAL(ENABLE_RELP, test x$enable_relp = xyes)
 471 AC_SUBST(RELP_CFLAGS)
 472 AC_SUBST(RELP_LIBS)
 473
 474 # RFC 3195 support
 475 # WARNING: THIS IS NOT REALLY PRESENT YET - needs to be build manually!
 476 AC_ARG_ENABLE(rfc3195,
 477         [AS_HELP_STRING([--enable-rfc3195],[Enable RFC3195 support @<:@default=no@:>@])],
 478         [case "${enableval}" in
 479          yes) enable_rfc3195="yes" ;;
 480           no) enable_rfc3195="no" ;;
 481            *) AC_MSG_ERROR(bad value ${enableval} for --enable-rfc3195) ;;
 482          esac],
 483         [enable_rfc3195=no]
 484 )
 485 if test "x$enable_rfc3195" = "xyes"; then
 486   AC_CHECK_HEADERS(
 487     [librfc3195.h],,
 488     [AC_MSG_FAILURE([RFC3195 library is missing (no headers)])]
 489   )
 490 # I don't know how to tell that librfc3195 needs -lrt, so I disable
 491 # this check for now - the header check should work well enough...
 492 # rgerhards, 2008-03-25
 493 #  AC_CHECK_LIB(
 494 #    [rfc3195],
 495 #    [rfc3195EngineGetVersion],
 496 #    [rfc3195_cflags=""
 497      rfc3195_libs="-lrfc3195"
 498 #    ],
 499 #    [AC_MSG_FAILURE([RFC3195 library is missing])]
 500 #  )
 501 fi
 502 AM_CONDITIONAL(ENABLE_RFC3195, test x$enable_rfc3195 = xyes)
 503 AC_SUBST(rfc3195_cflags)
 504 AC_SUBST(rfc3195_libs)
 505
 506
 507 # settings for the template input module; copy and modify this code
 508 # if you intend to add your own module. Be sure to replace imtemplate
 509 # by the actual name of your module.
 510 AC_ARG_ENABLE(imfile,
 511         [AS_HELP_STRING([--enable-imfile],[file input module enabled @<:@default=no@:>@])],
 512         [case "${enableval}" in
 513          yes) enable_imfile="yes" ;;
 514           no) enable_imfile="no" ;;
 515            *) AC_MSG_ERROR(bad value ${enableval} for --enable-imfile) ;;
 516          esac],
 517         [enable_imfile=no]
 518 )
 519 #
 520 # you may want to do some library checks here - see snmp, mysql, pgsql modules
 521 # for samples
 522 #
 523 AM_CONDITIONAL(ENABLE_IMFILE, test x$enable_imfile = xyes)
 524
 525 AM_CONDITIONAL(ENABLE_IMTEMPLATE, test x$enable_imtemplate = xyes)
 526 # end of copy template - be sure to serach for imtemplate to find everything!
 527 # settings for the template input module; copy and modify this code
 528 # if you intend to add your own module. Be sure to replace imtemplate
 529 # by the actual name of your module.
 530 AC_ARG_ENABLE(imtemplate,
 531         [AS_HELP_STRING([--enable-imtemplate],[Compiles imtemplate template module @<:@default=no@:>@])],
 532         [case "${enableval}" in
 533          yes) enable_imtemplate="yes" ;;
 534           no) enable_imtemplate="no" ;;
 535            *) AC_MSG_ERROR(bad value ${enableval} for --enable-imtemplate) ;;
 536          esac],
 537         [enable_imtemplate=no]
 538 )
 539 #
 540 # you may want to do some library checks here - see snmp, mysql, pgsql modules
 541 # for samples
 542 #
 543 AM_CONDITIONAL(ENABLE_IMTEMPLATE, test x$enable_imtemplate = xyes)
 544 # end of copy template - be sure to serach for imtemplate to find everything!
 545
 546
 547 AC_CONFIG_FILES([Makefile \
 548                 doc/Makefile \
 549                 plugins/imudp/Makefile \
 550                 plugins/imtcp/Makefile \
 551                 plugins/imgssapi/Makefile \
 552                 plugins/imuxsock/Makefile \
 553                 plugins/immark/Makefile \
 554                 plugins/imklog/Makefile \
 555                 plugins/imtemplate/Makefile \
 556                 plugins/imfile/Makefile \
 557                 plugins/imrelp/Makefile \
 558                 plugins/omtesting/Makefile \
 559                 plugins/omgssapi/Makefile \
 560                 plugins/ommysql/Makefile \
 561                 plugins/ompgsql/Makefile \
 562                 plugins/omrelp/Makefile \
 563                 plugins/omlibdbi/Makefile \
 564                 plugins/omsnmp/Makefile])
 565 AC_OUTPUT
 566
 567 echo "****************************************************"
 568 echo "rsyslog will be compiled with the following settings:"
 569 echo
 570 echo "Multithreading support enabled:           $enable_pthreads"
 571 echo "Klog functionality enabled:               $enable_klog"
 572 echo "Regular expressions support enabled:      $enable_regexp"
 573 echo "Zlib compression support enabled:         $enable_zlib"
 574 echo "MySql support enabled:                    $enable_mysql"
 575 echo "libdbi support enabled:                   $enable_libdbi"
 576 echo "PostgreSQL support enabled:               $enable_pgsql"
 577 echo "SNMP support enabled:                     $enable_snmp"
 578 echo "RELP support enabled:                     $enable_relp"
 579 echo "file input module enabled:                $enable_imfile"
 580 echo "input template module will be compiled:   $enable_imtemplate"
 581 echo "Large file support enabled:               $enable_largefile"
 582 echo "Networking support enabled:               $enable_inet"
 583 echo "Enable GSSAPI Kerberos 5 support:         $want_gssapi_krb5"
 584 echo "Debug mode enabled:                       $enable_debug"
 585 echo "Runtime Instrumentation enabled:          $enable_rtinst"
 586 echo "valgrind support settings enabled:        $enable_valgrind"
 587 echo "rsyslogd will be built:                   $enable_rsyslogd"
 588