ShellExtension/RegisterPerUser.bat

   1 @echo off
   2 : RegisterPerUser.bat
   3 :
   4 : ShellExtension.dll is a so called 'Shell Extension'
   5 : allowing user to start WinMerge from explorer's context
   6 : menu to compare selected files/directories.
   7 : However this dll file must be registered for
   8 : Windows before it works.
   9 :
  10 : ShellExtension.dll can be unregistered with command:
  11 : "RegisterPerUser.bat /U"
  12
  13 IF "%OS%" == ""                          Set DLLPATH=%0\..\ShellExtension.dll
  14 IF "%PROCESSOR_ARCHITECTURE%" == "x86"   Set DLLPATH=%~dp0%ShellExtensionU.dll
  15 IF "%PROCESSOR_ARCHITECTURE%" == "AMD64" Set DLLPATH=%~dp0%ShellExtensionX64.dll
  16 IF "%PROCESSOR_ARCHITECTURE%" == "IA64"  Set DLLPATH=%~dp0%ShellExtensionX64.dll
  17 IF "%PROCESSOR_ARCHITECTURE%" == "ARM64" Set DLLPATH=%~dp0%ShellExtensionARM64.dll
  18
  19 SET OPTIONS=
  20 FOR %%i IN (%*) DO (
  21   IF "%%i" == "/s" SET OPTIONS=%OPTIONS% /s
  22   IF "%%i" == "/S" SET OPTIONS=%OPTIONS% /s
  23 )
  24
  25 FOR %%i IN (%*) DO (
  26   IF "%%i" == "/u" Goto Uninstall
  27   IF "%%i" == "/U" Goto Uninstall
  28 )
  29
  30 Echo Registering ShellExtension.dll for current user only...
  31 %WINDIR%\System32\RegSvr32 /n %OPTIONS% /i:user "%DLLPATH%"
  32 IF EXIST "%~dp0\WinMerge32BitPluginProxy.exe" "%~dp0\WinMerge32BitPluginProxy.exe" /RegServerPerUser
  33 Goto End
  34
  35 :Uninstall
  36 Echo UnRegistering ShellExtension.dll for current user only...
  37 %WINDIR%\System32\RegSvr32 /u /n %OPTIONS% /i:user "%DLLPATH%"
  38 IF EXIST "%~dp0\WinMerge32BitPluginProxy.exe" "%~dp0\WinMerge32BitPluginProxy.exe" /UnregServerPerUser
  39 Goto End
  40
  41 :End