z_build.bat

   1 @echo off
   2 REM ///////////////////////////////////////////////////////////////////////////
   3 REM // Set Paths
   4 REM ///////////////////////////////////////////////////////////////////////////
   5 set "MSVC_PATH=C:\Program Files\Microsoft Visual Studio 10.0\VC"
   6 set "NSIS_PATH=C:\Program Files\NSIS\Unicode"
   7 set "QTVC_PATH=C:\MuldeR\Qt\4.8.0"
   8 set "UPX3_PATH=C:\Program Files\UPX"
   9
  10 REM ###############################################
  11 REM # DO NOT MODIFY ANY LINES BELOW THIS LINE !!! #
  12 REM ###############################################
  13
  14
  15 REM ///////////////////////////////////////////////////////////////////////////
  16 REM // Setup environment
  17 REM ///////////////////////////////////////////////////////////////////////////
  18 if exist "%QTVC_PATH%\bin\qtvars.bat" ( call "%QTVC_PATH%\bin\qtvars.bat" )
  19 if exist "%QTVC_PATH%\bin\qtenv2.bat" ( call "%QTVC_PATH%\bin\qtenv2.bat" )
  20 call "%MSVC_PATH%\vcvarsall.bat" x86
  21
  22 REM ///////////////////////////////////////////////////////////////////////////
  23 REM // Check environment
  24 REM ///////////////////////////////////////////////////////////////////////////
  25 if "%VCINSTALLDIR%"=="" (
  26         echo %%VCINSTALLDIR%% not specified. Please check your MSVC_PATH var!
  27         goto BuildError
  28 )
  29 if "%QTDIR%"=="" (
  30         echo %%QTDIR%% not specified. Please check your MSVC_PATH var!
  31         goto BuildError
  32 )
  33 if not exist "%VCINSTALLDIR%\bin\cl.exe" (
  34         echo C++ compiler not found. Please check your MSVC_PATH var!
  35         goto BuildError
  36 )
  37 if not exist "%QTDIR%\bin\moc.exe" (
  38         echo Qt meta compiler not found. Please check your QTVC_PATH var!
  39         goto BuildError
  40 )
  41
  42 REM ///////////////////////////////////////////////////////////////////////////
  43 REM // Build the binaries
  44 REM ///////////////////////////////////////////////////////////////////////////
  45 echo ---------------------------------------------------------------------
  46 echo BEGIN BUILD
  47 echo ---------------------------------------------------------------------
  48 MSBuild.exe /property:Configuration=release /target:clean "%~dp0\x264_launcher.sln"
  49 if not "%ERRORLEVEL%"=="0" goto BuildError
  50 MSBuild.exe /property:Configuration=release /target:rebuild "%~dp0\x264_launcher.sln"
  51 if not "%ERRORLEVEL%"=="0" goto BuildError
  52
  53 REM ///////////////////////////////////////////////////////////////////////////
  54 REM // Copy base files
  55 REM ///////////////////////////////////////////////////////////////////////////
  56 echo ---------------------------------------------------------------------
  57 echo BEGIN PACKAGING
  58 echo ---------------------------------------------------------------------
  59 set "PACK_PATH=%TMP%\~%RANDOM%%RANDOM%.tmp"
  60 mkdir "%PACK_PATH%"
  61 mkdir "%PACK_PATH%\imageformats"
  62 mkdir "%PACK_PATH%\toolset"
  63 copy "%~dp0\bin\Release\*.exe" "%PACK_PATH%"
  64 copy "%~dp0\bin\Release\toolset\*.exe" "%PACK_PATH%\toolset"
  65 copy "%~dp0\*.txt" "%PACK_PATH%"
  66
  67 REM ///////////////////////////////////////////////////////////////////////////
  68 REM // Copy dependencies
  69 REM ///////////////////////////////////////////////////////////////////////////
  70 copy "%MSVC_PATH%\redist\x86\Microsoft.VC100.CRT\*.dll" "%PACK_PATH%"
  71 copy "%QTVC_PATH%\bin\QtCore4.dll" "%PACK_PATH%"
  72 copy "%QTVC_PATH%\bin\QtGui4.dll" "%PACK_PATH%"
  73 copy "%QTVC_PATH%\bin\QtSvg4.dll" "%PACK_PATH%"
  74 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
  75 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
  76 copy "%QTVC_PATH%\plugins\imageformats\*.dll" "%PACK_PATH%\imageformats"
  77 del "%PACK_PATH%\imageformats\*d4.dll"
  78
  79 REM ///////////////////////////////////////////////////////////////////////////
  80 REM // Compress
  81 REM ///////////////////////////////////////////////////////////////////////////
  82 "%UPX3_PATH%\upx.exe" --brute "%PACK_PATH%\*.exe"
  83 "%UPX3_PATH%\upx.exe" --best "%PACK_PATH%\*.dll"
  84
  85 REM ///////////////////////////////////////////////////////////////////////////
  86 REM // Get current date (in ISO format)
  87 REM ///////////////////////////////////////////////////////////////////////////
  88 if not exist "%~dp0\etc\date.exe" BuildError
  89 for /F "tokens=1,2 delims=:" %%a in ('"%~dp0\etc\date.exe" +ISODATE:%%Y-%%m-%%d') do (
  90         if "%%a"=="ISODATE" set "ISO_DATE=%%b"
  91 )
  92 if "%ISO_DATE%"=="" BuildError
  93
  94 REM ///////////////////////////////////////////////////////////////////////////
  95 REM // Setup install parameters
  96 REM ///////////////////////////////////////////////////////////////////////////
  97 set "NSI_FILE=%TMP%\~%RANDOM%%RANDOM%.nsi"
  98 set "OUT_NAME=x264_x64.%ISO_DATE%"
  99 set "OUT_PATH=%~dp0\bin"
 100 set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 101 :GenerateOutfileName
 102 if exist "%OUT_FULL%" (
 103         set "OUT_NAME=%OUT_NAME%.new"
 104         set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 105         goto GenerateOutfileName
 106 )
 107
 108 REM ///////////////////////////////////////////////////////////////////////////
 109 REM // Generate install script
 110 REM ///////////////////////////////////////////////////////////////////////////
 111 echo #Generated File - Do NOT modify! > "%NSI_FILE%"
 112 echo !define ZIP2EXE_NAME `Simple x264 Launcher (%ISO_DATE%)` >> "%NSI_FILE%"
 113 echo !define ZIP2EXE_OUTFILE `%OUT_FULL%` >> "%NSI_FILE%"
 114 echo !define ZIP2EXE_COMPRESSOR_LZMA >> "%NSI_FILE%"
 115 echo !define ZIP2EXE_INSTALLDIR `$PROGRAMFILES\MuldeR\Simple x264 Launcher v2` >> "%NSI_FILE%"
 116 echo !define MUI_INSTFILESPAGE_COLORS "C5DEFB 000000" >> "%NSI_FILE%"
 117 echo RequestExecutionLevel Admin >> "%NSI_FILE%"
 118 echo ShowInstDetails show >> "%NSI_FILE%"
 119 echo !include `${NSISDIR}\Contrib\zip2exe\Base.nsh` >> "%NSI_FILE%"
 120 echo !include `${NSISDIR}\Contrib\zip2exe\Modern.nsh` >> "%NSI_FILE%"
 121 echo !insertmacro SECTION_BEGIN >> "%NSI_FILE%"
 122 echo File /r `%PACK_PATH%\*.*` >> "%NSI_FILE%"
 123 echo !include `%~dp0\etc\shortcut.nsh` >> "%NSI_FILE%"
 124 echo !insertmacro SECTION_END >> "%NSI_FILE%"
 125 echo !include `%~dp0\etc\check_os.nsh` >> "%NSI_FILE%"
 126 echo !include `%~dp0\etc\finalization.nsh` >> "%NSI_FILE%"
 127 echo !include `%~dp0\etc\version.nsh` >> "%NSI_FILE%"
 128 echo !insertmacro X264_VERSIONINFO `%ISO_DATE%` >> "%NSI_FILE%"
 129
 130 REM ///////////////////////////////////////////////////////////////////////////
 131 REM // Build the installer
 132 REM ///////////////////////////////////////////////////////////////////////////
 133 "%NSIS_PATH%\makensis.exe" "%NSI_FILE%"
 134 if not "%ERRORLEVEL%"=="0" goto BuildError
 135 attrib +R "%OUT_FULL%"
 136 del "%NSI_FILE%"
 137 rmdir /Q /S "%PACK_PATH%"
 138
 139 REM ///////////////////////////////////////////////////////////////////////////
 140 REM // COMPLETE
 141 REM ///////////////////////////////////////////////////////////////////////////
 142 echo.
 143 echo Build completed.
 144 echo.
 145 pause
 146 goto:eof
 147
 148 REM ///////////////////////////////////////////////////////////////////////////
 149 REM // FAILED
 150 REM ///////////////////////////////////////////////////////////////////////////
 151 :BuildError
 152 echo.
 153 echo Build has failed !!!
 154 echo.
 155 pause