z_build.bat

   1 @echo off
   2 REM ///////////////////////////////////////////////////////////////////////////
   3 REM // Set Paths
   4 REM ///////////////////////////////////////////////////////////////////////////
   5 set "MSVC_PATH=C:\Program Files\Microsoft Visual Studio 10.0\VC"
   6 set "NSIS_PATH=C:\Program Files\NSIS\Unicode"
   7 set "QTVC_PATH=C:\MuldeR\Qt\4.8.0"
   8 set "UPX3_PATH=C:\Program Files\UPX"
   9
  10 REM ###############################################
  11 REM # DO NOT MODIFY ANY LINES BELOW THIS LINE !!! #
  12 REM ###############################################
  13
  14
  15 REM ///////////////////////////////////////////////////////////////////////////
  16 REM // Setup environment
  17 REM ///////////////////////////////////////////////////////////////////////////
  18 if exist "%QTVC_PATH%\bin\qtvars.bat" ( call "%QTVC_PATH%\bin\qtvars.bat" )
  19 if exist "%QTVC_PATH%\bin\qtenv2.bat" ( call "%QTVC_PATH%\bin\qtenv2.bat" )
  20 call "%MSVC_PATH%\vcvarsall.bat" x86
  21
  22 REM ///////////////////////////////////////////////////////////////////////////
  23 REM // Check environment
  24 REM ///////////////////////////////////////////////////////////////////////////
  25 if "%VCINSTALLDIR%"=="" (
  26         echo %%VCINSTALLDIR%% not specified. Please check your MSVC_PATH var!
  27         goto BuildError
  28 )
  29 if "%QTDIR%"=="" (
  30         echo %%QTDIR%% not specified. Please check your MSVC_PATH var!
  31         goto BuildError
  32 )
  33 if not exist "%VCINSTALLDIR%\bin\cl.exe" (
  34         echo C++ compiler not found. Please check your MSVC_PATH var!
  35         goto BuildError
  36 )
  37 if not exist "%QTDIR%\bin\moc.exe" (
  38         echo Qt meta compiler not found. Please check your QTVC_PATH var!
  39         goto BuildError
  40 )
  41
  42 REM ///////////////////////////////////////////////////////////////////////////
  43 REM // Get current date and time (in ISO format)
  44 REM ///////////////////////////////////////////////////////////////////////////
  45 set "ISO_DATE="
  46 set "ISO_TIME="
  47 if not exist "%~dp0\etc\date.exe" BuildError
  48 for /F "tokens=1,2 delims=:" %%a in ('"%~dp0\etc\date.exe" +ISODATE:%%Y-%%m-%%d') do (
  49         if "%%a"=="ISODATE" set "ISO_DATE=%%b"
  50 )
  51 for /F "tokens=1,2,3,4 delims=:" %%a in ('"%~dp0\etc\date.exe" +ISOTIME:%%T') do (
  52         if "%%a"=="ISOTIME" set "ISO_TIME=%%b:%%c:%%d"
  53 )
  54 if "%ISO_DATE%"=="" goto BuildError
  55 if "%ISO_TIME%"=="" goto BuildError
  56
  57 REM ///////////////////////////////////////////////////////////////////////////
  58 REM // Build the binaries
  59 REM ///////////////////////////////////////////////////////////////////////////
  60 echo ---------------------------------------------------------------------
  61 echo BEGIN BUILD
  62 echo ---------------------------------------------------------------------
  63 MSBuild.exe /property:Configuration=release /target:clean "%~dp0\x264_launcher.sln"
  64 if not "%ERRORLEVEL%"=="0" goto BuildError
  65 MSBuild.exe /property:Configuration=release /target:rebuild "%~dp0\x264_launcher.sln"
  66 if not "%ERRORLEVEL%"=="0" goto BuildError
  67
  68 REM ///////////////////////////////////////////////////////////////////////////
  69 REM // Detect build number
  70 REM ///////////////////////////////////////////////////////////////////////////
  71 set "BUILD_NO="
  72 for /F "tokens=2,*" %%s in (%~dp0\src\version.h) do (
  73         if "%%s"=="VER_X264_BUILD" set "BUILD_NO=%%~t"
  74 )
  75 if "%BUILD_NO%"=="" goto BuildError
  76
  77 REM ///////////////////////////////////////////////////////////////////////////
  78 REM // Copy base files
  79 REM ///////////////////////////////////////////////////////////////////////////
  80 echo ---------------------------------------------------------------------
  81 echo BEGIN PACKAGING
  82 echo ---------------------------------------------------------------------
  83 set "PACK_PATH=%TMP%\~%RANDOM%%RANDOM%.tmp"
  84 mkdir "%PACK_PATH%"
  85 mkdir "%PACK_PATH%\imageformats"
  86 mkdir "%PACK_PATH%\toolset"
  87 copy "%~dp0\bin\Release\*.exe" "%PACK_PATH%"
  88 copy "%~dp0\bin\Release\toolset\*.exe" "%PACK_PATH%\toolset"
  89 copy "%~dp0\*.txt" "%PACK_PATH%"
  90
  91 REM ///////////////////////////////////////////////////////////////////////////
  92 REM // Copy dependencies
  93 REM ///////////////////////////////////////////////////////////////////////////
  94 copy "%MSVC_PATH%\redist\x86\Microsoft.VC100.CRT\*.dll" "%PACK_PATH%"
  95 copy "%QTVC_PATH%\bin\QtCore4.dll" "%PACK_PATH%"
  96 copy "%QTVC_PATH%\bin\QtGui4.dll" "%PACK_PATH%"
  97 copy "%QTVC_PATH%\bin\QtSvg4.dll" "%PACK_PATH%"
  98 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
  99 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
 100 copy "%QTVC_PATH%\plugins\imageformats\*.dll" "%PACK_PATH%\imageformats"
 101 del "%PACK_PATH%\imageformats\*d4.dll"
 102
 103 REM ///////////////////////////////////////////////////////////////////////////
 104 REM // Compress
 105 REM ///////////////////////////////////////////////////////////////////////////
 106 "%UPX3_PATH%\upx.exe" --brute "%PACK_PATH%\*.exe"
 107 "%UPX3_PATH%\upx.exe" --best "%PACK_PATH%\*.dll"
 108
 109 REM ///////////////////////////////////////////////////////////////////////////
 110 REM // Setup install parameters
 111 REM ///////////////////////////////////////////////////////////////////////////
 112 set "NSI_FILE=%TMP%\~%RANDOM%%RANDOM%.nsi"
 113 set "OUT_NAME=x264_x64.%ISO_DATE%"
 114 set "OUT_PATH=%~dp0\bin"
 115 set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 116 :GenerateOutfileName
 117 if exist "%OUT_FULL%" (
 118         set "OUT_NAME=%OUT_NAME%.new"
 119         set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 120         goto GenerateOutfileName
 121 )
 122
 123 REM ///////////////////////////////////////////////////////////////////////////
 124 REM // Generate install script
 125 REM ///////////////////////////////////////////////////////////////////////////
 126 echo #Generated File - Do NOT modify! > "%NSI_FILE%"
 127 echo !define ZIP2EXE_NAME `Simple x264 Launcher (%ISO_DATE%)` >> "%NSI_FILE%"
 128 echo !define ZIP2EXE_OUTFILE `%OUT_FULL%` >> "%NSI_FILE%"
 129 echo !define ZIP2EXE_COMPRESSOR_LZMA >> "%NSI_FILE%"
 130 echo !define ZIP2EXE_INSTALLDIR `$PROGRAMFILES\MuldeR\Simple x264 Launcher v2` >> "%NSI_FILE%"
 131 echo !define ZIP2EXE_REGPATH `SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{986E454F-DACA-4326-A9C7-3E46C0BFFDCE}` >> "%NSI_FILE%"
 132 echo !define MUI_INSTFILESPAGE_COLORS "C5DEFB 000000" >> "%NSI_FILE%"
 133 echo RequestExecutionLevel Admin >> "%NSI_FILE%"
 134 echo ShowInstDetails show >> "%NSI_FILE%"
 135 echo BrandingText `Created: %ISO_DATE%, %ISO_TIME% [Build #%BUILD_NO%]` >> "%NSI_FILE%"
 136 echo InstallDirRegKey HKLM `${ZIP2EXE_REGPATH}` InstallLocation >> "%NSI_FILE%"
 137 echo !include `${NSISDIR}\Contrib\zip2exe\Base.nsh` >> "%NSI_FILE%"
 138 echo !include `${NSISDIR}\Contrib\zip2exe\Modern.nsh` >> "%NSI_FILE%"
 139 echo !include `%~dp0\etc\check_os.nsh` >> "%NSI_FILE%"
 140 echo !include `%~dp0\etc\finalization.nsh` >> "%NSI_FILE%"
 141 echo !include `%~dp0\etc\version.nsh` >> "%NSI_FILE%"
 142 echo !insertmacro X264_VERSIONINFO `%ISO_DATE%` `%ISO_TIME%` `%BUILD_NO%` >> "%NSI_FILE%"
 143 echo !insertmacro SECTION_BEGIN >> "%NSI_FILE%"
 144 echo File /r `%PACK_PATH%\*.*` >> "%NSI_FILE%"
 145 echo WriteRegStr HKLM `${ZIP2EXE_REGPATH}` InstallLocation `$INSTDIR` >> "%NSI_FILE%"
 146 echo !include `%~dp0\etc\shortcut.nsh` >> "%NSI_FILE%"
 147 echo !insertmacro SECTION_END >> "%NSI_FILE%"
 148
 149 REM ///////////////////////////////////////////////////////////////////////////
 150 REM // Build the installer
 151 REM ///////////////////////////////////////////////////////////////////////////
 152 "%NSIS_PATH%\makensis.exe" "%NSI_FILE%"
 153 if not "%ERRORLEVEL%"=="0" goto BuildError
 154 attrib +R "%OUT_FULL%"
 155 del "%NSI_FILE%"
 156 rmdir /Q /S "%PACK_PATH%"
 157
 158 REM ///////////////////////////////////////////////////////////////////////////
 159 REM // COMPLETE
 160 REM ///////////////////////////////////////////////////////////////////////////
 161 echo.
 162 echo Build completed.
 163 echo.
 164 pause
 165 goto:eof
 166
 167 REM ///////////////////////////////////////////////////////////////////////////
 168 REM // FAILED
 169 REM ///////////////////////////////////////////////////////////////////////////
 170 :BuildError
 171 echo.
 172 echo Build has failed !!!
 173 echo.
 174 pause