configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  47
  48 # Support silent build rules, requires at least automake-1.11. Disable
  49 # by either passing --disable-silent-rules to configure or passing V=1
  50 # to make
  51 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  52     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  53
  54 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  55
  56 dnl Set internal versions
  57 OSMESA_VERSION=8
  58 AC_SUBST([OSMESA_VERSION])
  59
  60 dnl Versions for external dependencies
  61 LIBDRM_REQUIRED=2.4.38
  62 LIBDRM_RADEON_REQUIRED=2.4.56
  63 LIBDRM_INTEL_REQUIRED=2.4.52
  64 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  65 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  66 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  67 DRI2PROTO_REQUIRED=2.6
  68 DRI3PROTO_REQUIRED=1.0
  69 PRESENTPROTO_REQUIRED=1.0
  70 LIBUDEV_REQUIRED=151
  71 GLPROTO_REQUIRED=1.4.14
  72 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  73 LIBVA_REQUIRED=0.35.0
  74 VDPAU_REQUIRED=0.4.1
  75 WAYLAND_REQUIRED=1.2.0
  76 XCB_REQUIRED=1.9.3
  77 XCBDRI2_REQUIRED=1.8
  78 XCBGLX_REQUIRED=1.8.1
  79 XSHMFENCE_REQUIRED=1.1
  80 XVMC_REQUIRED=1.0.6
  81 PYTHON_MAKO_REQUIRED=0.3.4
  82
  83 dnl Check for progs
  84 AC_PROG_CPP
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 AM_PROG_CC_C_O
  88 AM_PROG_AS
  89 AX_CHECK_GNU_MAKE
  90 AC_CHECK_PROGS([PYTHON2], [python2 python])
  91 AC_PROG_SED
  92 AC_PROG_MKDIR_P
  93
  94 AC_SYS_LARGEFILE
  95
  96 LT_PREREQ([2.2])
  97 LT_INIT([disable-static])
  98
  99 AX_PROG_BISON([],
 100               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 101                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 102 AX_PROG_FLEX([],
 103              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 104                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 105
 106 AC_CHECK_PROG(INDENT, indent, indent, cat)
 107 if test "x$INDENT" != "xcat"; then
 108     # Only GNU indent is supported
 109     INDENT_VERSION=`indent --version | grep GNU`
 110     if test $? -eq 0; then
 111        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 112     else
 113        INDENT="cat"
 114     fi
 115 fi
 116
 117 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 118
 119 if test -z "$PYTHON2"; then
 120     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 121         AC_MSG_ERROR([Python not found - unable to generate sources])
 122     fi
 123 else
 124     if test "x$acv_mako_found" = xno; then
 125         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 126             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 127         fi
 128     fi
 129 fi
 130
 131 AC_PROG_INSTALL
 132
 133 dnl We need a POSIX shell for parts of the build. Assume we have one
 134 dnl in most cases.
 135 case "$host_os" in
 136 solaris*)
 137     # Solaris /bin/sh is too old/non-POSIX compliant
 138     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 139     SHELL="$POSIX_SHELL"
 140     ;;
 141 esac
 142
 143 dnl clang is mostly GCC-compatible, but its version is much lower,
 144 dnl so we have to check for it.
 145 AC_MSG_CHECKING([if compiling with clang])
 146
 147 AC_COMPILE_IFELSE(
 148 [AC_LANG_PROGRAM([], [[
 149 #ifndef __clang__
 150        not clang
 151 #endif
 152 ]])],
 153 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 154
 155 AC_MSG_RESULT([$acv_mesa_CLANG])
 156
 157 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 158 dnl versions are explictly not supported.
 159 GEN_ASM_OFFSETS=no
 160 USE_GNU99=no
 161 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 162     AC_MSG_CHECKING([whether gcc version is sufficient])
 163     major=0
 164     minor=0
 165
 166     GCC_VERSION=`$CC -dumpversion`
 167     if test $? -eq 0; then
 168         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 169         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 170     fi
 171
 172     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 173         AC_MSG_RESULT([no])
 174         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 175     else
 176         AC_MSG_RESULT([yes])
 177     fi
 178
 179     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 180         USE_GNU99=yes
 181     fi
 182     if test "x$cross_compiling" = xyes; then
 183         GEN_ASM_OFFSETS=yes
 184     fi
 185 fi
 186
 187 dnl Check for compiler builtins
 188 AX_GCC_BUILTIN([__builtin_bswap32])
 189 AX_GCC_BUILTIN([__builtin_bswap64])
 190 AX_GCC_BUILTIN([__builtin_clz])
 191 AX_GCC_BUILTIN([__builtin_clzll])
 192 AX_GCC_BUILTIN([__builtin_ctz])
 193 AX_GCC_BUILTIN([__builtin_expect])
 194 AX_GCC_BUILTIN([__builtin_ffs])
 195 AX_GCC_BUILTIN([__builtin_ffsll])
 196 AX_GCC_BUILTIN([__builtin_popcount])
 197 AX_GCC_BUILTIN([__builtin_popcountll])
 198 AX_GCC_BUILTIN([__builtin_unreachable])
 199
 200 AX_GCC_FUNC_ATTRIBUTE([flatten])
 201 AX_GCC_FUNC_ATTRIBUTE([format])
 202 AX_GCC_FUNC_ATTRIBUTE([malloc])
 203 AX_GCC_FUNC_ATTRIBUTE([packed])
 204
 205 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 206
 207 dnl Make sure the pkg-config macros are defined
 208 m4_ifndef([PKG_PROG_PKG_CONFIG],
 209     [m4_fatal([Could not locate the pkg-config autoconf macros.
 210   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 211   are in a different location, try setting the environment variable
 212   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 213 PKG_PROG_PKG_CONFIG()
 214
 215 dnl LIB_DIR - library basename
 216 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 217 AC_SUBST([LIB_DIR])
 218
 219 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 220 _SAVE_LDFLAGS="$LDFLAGS"
 221 _SAVE_CPPFLAGS="$CPPFLAGS"
 222
 223 dnl Compiler macros
 224 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 225 AC_SUBST([DEFINES])
 226 case "$host_os" in
 227 linux*|*-gnu*|gnu*)
 228     DEFINES="$DEFINES -D_GNU_SOURCE"
 229     ;;
 230 solaris*)
 231     DEFINES="$DEFINES -DSVR4"
 232     ;;
 233 cygwin*)
 234     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 235     ;;
 236 esac
 237
 238 dnl Add flags for gcc and g++
 239 if test "x$GCC" = xyes; then
 240     CFLAGS="$CFLAGS -Wall"
 241
 242     if test "x$USE_GNU99" = xyes; then
 243         CFLAGS="$CFLAGS -std=gnu99"
 244     else
 245         CFLAGS="$CFLAGS -std=c99"
 246     fi
 247
 248     # Enable -Werror=implicit-function-declaration and
 249     # -Werror=missing-prototypes, if available, or otherwise, just
 250     # -Wmissing-prototypes.  This is particularly useful to avoid
 251     # generating a loadable driver module that has undefined symbols.
 252     save_CFLAGS="$CFLAGS"
 253     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 254     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 255     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 256     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 257                    AC_MSG_RESULT([yes]),
 258                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 259                     AC_MSG_RESULT([no])]);
 260
 261     # Enable -fvisibility=hidden if using a gcc that supports it
 262     save_CFLAGS="$CFLAGS"
 263     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 264     VISIBILITY_CFLAGS="-fvisibility=hidden"
 265     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 266     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 267                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 268
 269     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 270     CFLAGS=$save_CFLAGS
 271
 272     # Work around aliasing bugs - developers should comment this out
 273     CFLAGS="$CFLAGS -fno-strict-aliasing"
 274
 275     # gcc's builtin memcmp is slower than glibc's
 276     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 277     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 278 fi
 279 if test "x$GXX" = xyes; then
 280     CXXFLAGS="$CXXFLAGS -Wall"
 281
 282     # Enable -fvisibility=hidden if using a gcc that supports it
 283     save_CXXFLAGS="$CXXFLAGS"
 284     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 285     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 286     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 287     AC_LANG_PUSH([C++])
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 289                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 290     AC_LANG_POP([C++])
 291
 292     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 293     CXXFLAGS=$save_CXXFLAGS
 294
 295     # Work around aliasing bugs - developers should comment this out
 296     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 297
 298     # gcc's builtin memcmp is slower than glibc's
 299     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 300     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 301 fi
 302
 303 dnl even if the compiler appears to support it, using visibility attributes isn't
 304 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 305 case "$host_os" in
 306 cygwin*)
 307     VISIBILITY_CFLAGS=""
 308     VISIBILITY_CXXFLAGS=""
 309     ;;
 310 esac
 311
 312 AC_SUBST([VISIBILITY_CFLAGS])
 313 AC_SUBST([VISIBILITY_CXXFLAGS])
 314
 315 dnl
 316 dnl Optional flags, check for compiler support
 317 dnl
 318 SSE41_CFLAGS="-msse4.1"
 319 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 320 dnl stack, but on x86-32 such alignment is not guaranteed.
 321 case "$target_cpu" in
 322 i?86)
 323     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 324     ;;
 325 esac
 326 save_CFLAGS="$CFLAGS"
 327 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 328 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 329 #include <smmintrin.h>
 330 int main () {
 331     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 332     c = _mm_max_epu32(a, b);
 333     return 0;
 334 }]])], SSE41_SUPPORTED=1)
 335 CFLAGS="$save_CFLAGS"
 336 if test "x$SSE41_SUPPORTED" = x1; then
 337     DEFINES="$DEFINES -DUSE_SSE41"
 338 fi
 339 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 340 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 341
 342 dnl Can't have static and shared libraries, default to static if user
 343 dnl explicitly requested. If both disabled, set to static since shared
 344 dnl was explicitly requested.
 345 case "x$enable_static$enable_shared" in
 346 xyesyes)
 347     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 348     enable_shared=no
 349     ;;
 350 xnono)
 351     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 352     enable_shared=yes
 353     ;;
 354 esac
 355
 356 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 357
 358 dnl
 359 dnl other compiler options
 360 dnl
 361 AC_ARG_ENABLE([debug],
 362     [AS_HELP_STRING([--enable-debug],
 363         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 364     [enable_debug="$enableval"],
 365     [enable_debug=no]
 366 )
 367 if test "x$enable_debug" = xyes; then
 368     DEFINES="$DEFINES -DDEBUG"
 369     if test "x$GCC" = xyes; then
 370         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 371             CFLAGS="$CFLAGS -g"
 372         fi
 373         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 374             CFLAGS="$CFLAGS -O0"
 375         fi
 376     fi
 377     if test "x$GXX" = xyes; then
 378         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 379             CXXFLAGS="$CXXFLAGS -g"
 380         fi
 381         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 382             CXXFLAGS="$CXXFLAGS -O0"
 383         fi
 384     fi
 385 fi
 386
 387 dnl
 388 dnl Check if linker supports -Bsymbolic
 389 dnl
 390 save_LDFLAGS=$LDFLAGS
 391 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 392 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 393 AC_LINK_IFELSE(
 394     [AC_LANG_SOURCE([int main() { return 0;}])],
 395     [AC_MSG_RESULT([yes])
 396         BSYMBOLIC="-Wl,-Bsymbolic";],
 397     [AC_MSG_RESULT([no])
 398         BSYMBOLIC="";])
 399 LDFLAGS=$save_LDFLAGS
 400
 401 AC_SUBST([BSYMBOLIC])
 402
 403 dnl
 404 dnl Check if linker supports garbage collection
 405 dnl
 406 save_LDFLAGS=$LDFLAGS
 407 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 408 AC_MSG_CHECKING([whether ld supports --gc-sections])
 409 AC_LINK_IFELSE(
 410     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 411     [AC_MSG_RESULT([yes])
 412         GC_SECTIONS="-Wl,--gc-sections";],
 413     [AC_MSG_RESULT([no])
 414         GC_SECTIONS="";])
 415 LDFLAGS=$save_LDFLAGS
 416
 417 AC_SUBST([GC_SECTIONS])
 418
 419 dnl
 420 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 421 dnl so when these flags are passed to ld via libtool the checks will fail
 422 dnl
 423 case "$host_os" in
 424 openbsd* | darwin* )
 425     LD_NO_UNDEFINED="" ;;
 426 *)
 427     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 428 esac
 429
 430 AC_SUBST([LD_NO_UNDEFINED])
 431
 432 dnl
 433 dnl Check if linker supports version scripts
 434 dnl
 435 AC_MSG_CHECKING([if the linker supports version-scripts])
 436 save_LDFLAGS=$LDFLAGS
 437 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 438 cat > conftest.map <<EOF
 439 VERSION_1 {
 440      global:
 441          main;
 442
 443      local:
 444          *;
 445 };
 446 EOF
 447 AC_LINK_IFELSE(
 448     [AC_LANG_SOURCE([int main() { return 0;}])],
 449     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 450     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 451 LDFLAGS=$save_LDFLAGS
 452 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 453
 454 dnl
 455 dnl Check if linker supports dynamic list files
 456 dnl
 457 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 458 save_LDFLAGS=$LDFLAGS
 459 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 460 cat > conftest.dyn <<EOF
 461 {
 462         radeon_drm_winsys_create;
 463 };
 464 EOF
 465 AC_LINK_IFELSE(
 466     [AC_LANG_SOURCE([int main() { return 0;}])],
 467     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 468     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 469 LDFLAGS=$save_LDFLAGS
 470 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 471
 472 dnl
 473 dnl compatibility symlinks
 474 dnl
 475 case "$host_os" in
 476 linux* )
 477     HAVE_COMPAT_SYMLINKS=yes ;;
 478 * )
 479     HAVE_COMPAT_SYMLINKS=no ;;
 480 esac
 481
 482 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 483
 484 dnl
 485 dnl library names
 486 dnl
 487 case "$host_os" in
 488 darwin* )
 489     LIB_EXT='dylib' ;;
 490 cygwin* )
 491     LIB_EXT='dll' ;;
 492 aix* )
 493     LIB_EXT='a' ;;
 494 * )
 495     LIB_EXT='so' ;;
 496 esac
 497
 498 AC_SUBST([LIB_EXT])
 499
 500 AC_ARG_WITH([gl-lib-name],
 501   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 502     [specify GL library name @<:@default=GL@:>@])],
 503   [GL_LIB=$withval],
 504   [GL_LIB=GL])
 505 AC_ARG_WITH([osmesa-lib-name],
 506   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 507     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 508   [OSMESA_LIB=$withval],
 509   [OSMESA_LIB=OSMesa])
 510 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 511 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 512
 513 dnl
 514 dnl Mangled Mesa support
 515 dnl
 516 AC_ARG_ENABLE([mangling],
 517   [AS_HELP_STRING([--enable-mangling],
 518     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 519   [enable_mangling="${enableval}"],
 520   [enable_mangling=no]
 521 )
 522 if test "x${enable_mangling}" = "xyes" ; then
 523   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 524   GL_LIB="Mangled${GL_LIB}"
 525   OSMESA_LIB="Mangled${OSMESA_LIB}"
 526 fi
 527 AC_SUBST([GL_LIB])
 528 AC_SUBST([OSMESA_LIB])
 529
 530 dnl
 531 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 532 dnl
 533 AC_ARG_ENABLE([texture-float],
 534     [AS_HELP_STRING([--enable-texture-float],
 535         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 536     [enable_texture_float="$enableval"],
 537     [enable_texture_float=no]
 538 )
 539 if test "x$enable_texture_float" = xyes; then
 540     AC_MSG_WARN([Floating-point textures enabled.])
 541     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 542     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 543 fi
 544
 545 dnl
 546 dnl Arch/platform-specific settings
 547 dnl
 548 AC_ARG_ENABLE([asm],
 549     [AS_HELP_STRING([--disable-asm],
 550         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 551     [enable_asm="$enableval"],
 552     [enable_asm=yes]
 553 )
 554 asm_arch=""
 555 AC_MSG_CHECKING([whether to enable assembly])
 556 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 557 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 558 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 559     case "$host_cpu" in
 560     i?86 | x86_64 | amd64)
 561         enable_asm=no
 562         AC_MSG_RESULT([no, cross compiling])
 563         ;;
 564     esac
 565 fi
 566 # check for supported arches
 567 if test "x$enable_asm" = xyes; then
 568     case "$host_cpu" in
 569     i?86)
 570         case "$host_os" in
 571         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 572             asm_arch=x86
 573             ;;
 574         esac
 575         ;;
 576     x86_64|amd64)
 577         case "$host_os" in
 578         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 579             asm_arch=x86_64
 580             ;;
 581         esac
 582         ;;
 583     sparc*)
 584         case "$host_os" in
 585         linux*)
 586             asm_arch=sparc
 587             ;;
 588         esac
 589         ;;
 590     esac
 591
 592     case "$asm_arch" in
 593     x86)
 594         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 595         AC_MSG_RESULT([yes, x86])
 596         ;;
 597     x86_64|amd64)
 598         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 599         AC_MSG_RESULT([yes, x86_64])
 600         ;;
 601     sparc)
 602         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 603         AC_MSG_RESULT([yes, sparc])
 604         ;;
 605     *)
 606         AC_MSG_RESULT([no, platform not supported])
 607         ;;
 608     esac
 609 fi
 610
 611 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 612 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 613 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 614
 615 dnl Check to see if dlopen is in default libraries (like Solaris, which
 616 dnl has it in libc), or if libdl is needed to get it.
 617 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 618     [AC_CHECK_LIB([dl], [dlopen],
 619        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 620 AC_SUBST([DLOPEN_LIBS])
 621
 622 dnl Check if that library also has dladdr
 623 save_LIBS="$LIBS"
 624 LIBS="$LIBS $DLOPEN_LIBS"
 625 AC_CHECK_FUNCS([dladdr])
 626 LIBS="$save_LIBS"
 627
 628 case "$host_os" in
 629 darwin*|mingw*)
 630     ;;
 631 *)
 632     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 633                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 634                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 635     AC_SUBST([CLOCK_LIB])
 636     ;;
 637 esac
 638
 639 dnl See if posix_memalign is available
 640 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 641
 642 dnl Check for pthreads
 643 case "$host_os" in
 644 mingw*)
 645     ;;
 646 *)
 647     AX_PTHREAD
 648     ;;
 649 esac
 650 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 651 dnl to -pthread, which causes problems if we need -lpthread to appear in
 652 dnl pkgconfig files.
 653 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 654
 655 dnl SELinux awareness.
 656 AC_ARG_ENABLE([selinux],
 657     [AS_HELP_STRING([--enable-selinux],
 658         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 659     [MESA_SELINUX="$enableval"],
 660     [MESA_SELINUX=no])
 661 if test "x$enable_selinux" = "xyes"; then
 662     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 663         [AC_CHECK_HEADER([selinux/selinux.h],[],
 664                          [AC_MSG_ERROR([SELinux headers not found])])
 665          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 666                       [AC_MSG_ERROR([SELinux library not found])])
 667          SELINUX_LIBS="-lselinux"])
 668     DEFINES="$DEFINES -DMESA_SELINUX"
 669 fi
 670 AC_SUBST([SELINUX_CFLAGS])
 671 AC_SUBST([SELINUX_LIBS])
 672
 673 dnl Options for APIs
 674 AC_ARG_ENABLE([opengl],
 675     [AS_HELP_STRING([--disable-opengl],
 676         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 677     [enable_opengl="$enableval"],
 678     [enable_opengl=yes])
 679 AC_ARG_ENABLE([gles1],
 680     [AS_HELP_STRING([--enable-gles1],
 681         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 682     [enable_gles1="$enableval"],
 683     [enable_gles1=no])
 684 AC_ARG_ENABLE([gles2],
 685     [AS_HELP_STRING([--enable-gles2],
 686         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 687     [enable_gles2="$enableval"],
 688     [enable_gles2=no])
 689 AC_ARG_ENABLE([openvg],
 690     [AS_HELP_STRING([--enable-openvg],
 691         [enable support for OpenVG API @<:@default=disabled@:>@])],
 692     [enable_openvg="$enableval"],
 693     [enable_openvg=no])
 694
 695 AC_ARG_ENABLE([dri],
 696     [AS_HELP_STRING([--enable-dri],
 697         [enable DRI modules @<:@default=enabled@:>@])],
 698     [enable_dri="$enableval"],
 699     [enable_dri=yes])
 700
 701 case "$host_os" in
 702 linux*)
 703     dri3_default=yes
 704     ;;
 705 *)
 706     dri3_default=no
 707     ;;
 708 esac
 709 AC_ARG_ENABLE([dri3],
 710     [AS_HELP_STRING([--enable-dri3],
 711         [enable DRI3 @<:@default=auto@:>@])],
 712     [enable_dri3="$enableval"],
 713     [enable_dri3="$dri3_default"])
 714 AC_ARG_ENABLE([glx],
 715     [AS_HELP_STRING([--enable-glx],
 716         [enable GLX library @<:@default=enabled@:>@])],
 717     [enable_glx="$enableval"],
 718     [enable_glx=yes])
 719 AC_ARG_ENABLE([osmesa],
 720     [AS_HELP_STRING([--enable-osmesa],
 721         [enable OSMesa library @<:@default=disabled@:>@])],
 722     [enable_osmesa="$enableval"],
 723     [enable_osmesa=no])
 724 AC_ARG_ENABLE([gallium-osmesa],
 725     [AS_HELP_STRING([--enable-gallium-osmesa],
 726         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 727     [enable_gallium_osmesa="$enableval"],
 728     [enable_gallium_osmesa=no])
 729 AC_ARG_ENABLE([egl],
 730     [AS_HELP_STRING([--disable-egl],
 731         [disable EGL library @<:@default=enabled@:>@])],
 732     [enable_egl="$enableval"],
 733     [enable_egl=yes])
 734
 735 AC_ARG_ENABLE([xa],
 736     [AS_HELP_STRING([--enable-xa],
 737         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 738     [enable_xa="$enableval"],
 739     [enable_xa=no])
 740 AC_ARG_ENABLE([gbm],
 741    [AS_HELP_STRING([--enable-gbm],
 742          [enable gbm library @<:@default=auto@:>@])],
 743    [enable_gbm="$enableval"],
 744    [enable_gbm=auto])
 745 AC_ARG_ENABLE([nine],
 746     [AS_HELP_STRING([--enable-nine],
 747         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 748     [enable_nine="$enableval"],
 749     [enable_nine=no])
 750
 751 AC_ARG_ENABLE([xvmc],
 752    [AS_HELP_STRING([--enable-xvmc],
 753          [enable xvmc library @<:@default=auto@:>@])],
 754    [enable_xvmc="$enableval"],
 755    [enable_xvmc=auto])
 756 AC_ARG_ENABLE([vdpau],
 757    [AS_HELP_STRING([--enable-vdpau],
 758          [enable vdpau library @<:@default=auto@:>@])],
 759    [enable_vdpau="$enableval"],
 760    [enable_vdpau=auto])
 761 AC_ARG_ENABLE([omx],
 762    [AS_HELP_STRING([--enable-omx],
 763          [enable OpenMAX library @<:@default=disabled@:>@])],
 764    [enable_omx="$enableval"],
 765    [enable_omx=no])
 766 AC_ARG_ENABLE([va],
 767    [AS_HELP_STRING([--enable-va],
 768          [enable va library @<:@default=auto@:>@])],
 769    [enable_va="$enableval"],
 770    [enable_va=auto])
 771 AC_ARG_ENABLE([opencl],
 772    [AS_HELP_STRING([--enable-opencl],
 773          [enable OpenCL library @<:@default=disabled@:>@])],
 774    [enable_opencl="$enableval"],
 775    [enable_opencl=no])
 776 AC_ARG_ENABLE([opencl_icd],
 777    [AS_HELP_STRING([--enable-opencl-icd],
 778           [Build an OpenCL ICD library to be loaded by an ICD implementation
 779            @<:@default=disabled@:>@])],
 780     [enable_opencl_icd="$enableval"],
 781     [enable_opencl_icd=no])
 782 AC_ARG_ENABLE([xlib-glx],
 783     [AS_HELP_STRING([--enable-xlib-glx],
 784         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 785     [enable_xlib_glx="$enableval"],
 786     [enable_xlib_glx=no])
 787
 788 AC_ARG_ENABLE([r600-llvm-compiler],
 789     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 790         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 791     [enable_r600_llvm="$enableval"],
 792     [enable_r600_llvm=no])
 793
 794 AC_ARG_ENABLE([gallium-tests],
 795     [AS_HELP_STRING([--enable-gallium-tests],
 796         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 797     [enable_gallium_tests="$enableval"],
 798     [enable_gallium_tests=no])
 799
 800 # Option for Gallium drivers
 801
 802 # Keep this in sync with the --with-gallium-drivers help string default value
 803 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 804
 805 AC_ARG_WITH([gallium-drivers],
 806     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 807         [comma delimited Gallium drivers list, e.g.
 808         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 809         @<:@default=r300,r600,svga,swrast@:>@])],
 810     [with_gallium_drivers="$withval"],
 811     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 812
 813 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 814 # here so that the script doesn't choke on an unknown driver name later.
 815 case "$with_gallium_drivers" in
 816     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 817     no) with_gallium_drivers='' ;;
 818 esac
 819
 820 if test "x$enable_opengl" = xno -a \
 821         "x$enable_gles1" = xno -a \
 822         "x$enable_gles2" = xno -a \
 823         "x$enable_nine" = xno -a \
 824         "x$enable_openvg" = xno -a \
 825         "x$enable_xa" = xno -a \
 826         "x$enable_xvmc" = xno -a \
 827         "x$enable_vdpau" = xno -a \
 828         "x$enable_omx" = xno -a \
 829         "x$enable_va" = xno -a \
 830         "x$enable_opencl" = xno; then
 831     AC_MSG_ERROR([at least one API should be enabled])
 832 fi
 833
 834 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 835 if test "x$enable_opengl" = xno -a \
 836         "x$enable_gles1" = xyes; then
 837     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 838 fi
 839
 840 if test "x$enable_opengl" = xno -a \
 841         "x$enable_gles2" = xyes; then
 842     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 843 fi
 844
 845 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 846 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 847 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 848 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 849                                         "x$enable_gles1" = xyes -o \
 850                                         "x$enable_gles2" = xyes)
 851
 852 if test "x$enable_glx" = xno; then
 853     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 854     enable_xlib_glx=no
 855 fi
 856
 857 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 858     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 859 fi
 860
 861 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 862     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 863 fi
 864
 865 # Disable GLX if OpenGL is not enabled
 866 if test "x$enable_glx$enable_opengl" = xyesno; then
 867     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 868     enable_glx=no
 869 fi
 870
 871 # Disable GLX if DRI and Xlib-GLX are not enabled
 872 if test "x$enable_glx" = xyes -a \
 873         "x$enable_dri" = xno -a \
 874         "x$enable_xlib_glx" = xno; then
 875     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 876     enable_glx=no
 877 fi
 878
 879 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 880                                   "x$enable_dri" = xyes)
 881
 882 # Select which platform-dependent DRI code gets built
 883 case "$host_os" in
 884 darwin*)
 885     dri_platform='apple' ;;
 886 gnu*|mingw*|cygwin*)
 887     dri_platform='none' ;;
 888 *)
 889     dri_platform='drm' ;;
 890 esac
 891
 892 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 893 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 894 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 895 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 896 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 897
 898 AC_ARG_ENABLE([shared-glapi],
 899     [AS_HELP_STRING([--enable-shared-glapi],
 900         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 901     [enable_shared_glapi="$enableval"],
 902     [enable_shared_glapi=yes])
 903
 904 case "x$enable_opengl$enable_gles1$enable_gles2" in
 905 x*yes*yes*)
 906     if test "x$enable_shared_glapi" = xno; then
 907         AC_MSG_ERROR([shared GLAPI required when building two or more of
 908                       the following APIs - opengl, gles1 gles2])
 909     fi
 910     ;;
 911 esac
 912
 913 # Building Xlib-GLX requires shared glapi to be disabled.
 914 if test "x$enable_xlib_glx" = xyes; then
 915     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 916     enable_shared_glapi=no
 917 fi
 918
 919 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 920
 921 # Build the pipe-drivers as separate libraries/modules.
 922 # Do not touch this unless you know what you are doing.
 923 # XXX: Expose via configure option ?
 924 enable_shared_pipe_drivers=no
 925
 926 dnl
 927 dnl Driver specific build directories
 928 dnl
 929
 930 case "x$enable_glx$enable_xlib_glx" in
 931 xyesyes)
 932     NEED_WINSYS_XLIB="yes"
 933     ;;
 934 esac
 935
 936 if test "x$enable_dri" = xyes; then
 937     enable_gallium_loader="$enable_shared_pipe_drivers"
 938 fi
 939
 940 if test "x$enable_gallium_osmesa" = xyes; then
 941     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 942         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 943     fi
 944     if test "x$enable_osmesa" = xyes; then
 945         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 946     fi
 947 fi
 948
 949 AC_SUBST([MESA_LLVM])
 950
 951 # Check for libdrm
 952 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 953                   [have_libdrm=yes], [have_libdrm=no])
 954 if test "x$have_libdrm" = xyes; then
 955         DEFINES="$DEFINES -DHAVE_LIBDRM"
 956 fi
 957
 958 case "$host_os" in
 959 linux*)
 960     need_pci_id=yes ;;
 961 *)
 962     need_pci_id=no ;;
 963 esac
 964
 965 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 966                   have_libudev=yes, have_libudev=no)
 967
 968 AC_ARG_ENABLE([sysfs],
 969     [AS_HELP_STRING([--enable-sysfs],
 970         [enable /sys PCI identification @<:@default=disabled@:>@])],
 971     [have_sysfs="$enableval"],
 972     [have_sysfs=no]
 973 )
 974
 975 if test "x$enable_dri" = xyes; then
 976     if test "$enable_static" = yes; then
 977         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 978     fi
 979
 980     # not a hard requirement as swrast does not depend on it
 981     if test "x$have_libdrm" = xyes; then
 982         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 983     fi
 984 fi
 985
 986 AC_ARG_ENABLE([driglx-direct],
 987     [AS_HELP_STRING([--disable-driglx-direct],
 988         [disable direct rendering in GLX and EGL for DRI \
 989             @<:@default=auto@:>@])],
 990     [driglx_direct="$enableval"],
 991     [driglx_direct="yes"])
 992
 993 dnl
 994 dnl libGL configuration per driver
 995 dnl
 996 case "x$enable_glx$enable_xlib_glx" in
 997 xyesyes)
 998     # Xlib-based GLX
 999     dri_modules="x11 xext xcb"
1000     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1001     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1002     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1003     GL_LIB_DEPS="$XLIBGL_LIBS"
1004     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1005     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1006     ;;
1007 xyesno)
1008     # DRI-based GLX
1009     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1010
1011     # find the DRI deps for libGL
1012     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1013
1014     if test x"$driglx_direct" = xyes; then
1015         if test x"$dri_platform" = xdrm ; then
1016             DEFINES="$DEFINES -DGLX_USE_DRM"
1017             if test "x$have_libdrm" != xyes; then
1018                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1019             fi
1020
1021             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1022             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1023             if test x"$enable_dri3" = xyes; then
1024                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1025                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1026             fi
1027
1028             if test x"$enable_dri" = xyes; then
1029                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1030             fi
1031
1032             if test x"$enable_dri3" = xyes; then
1033                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1034                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1035             fi
1036         fi
1037         if test x"$dri_platform" = xapple ; then
1038             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1039         fi
1040     fi
1041
1042     # add xf86vidmode if available
1043     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1044     if test "$HAVE_XF86VIDMODE" = yes ; then
1045         dri_modules="$dri_modules xxf86vm"
1046     fi
1047
1048     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1049     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1050     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1051     GL_LIB_DEPS="$DRIGL_LIBS"
1052
1053     # need DRM libs, $PTHREAD_LIBS, etc.
1054     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1055     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1056     ;;
1057 esac
1058
1059 have_pci_id=no
1060 if test "$have_libudev" = yes; then
1061     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1062     have_pci_id=yes
1063 fi
1064
1065 if test "$have_sysfs" = yes; then
1066     DEFINES="$DEFINES -DHAVE_SYSFS"
1067     have_pci_id=yes
1068 fi
1069
1070 # This is outside the case (above) so that it is invoked even for non-GLX
1071 # builds.
1072 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1073
1074 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1075 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1076 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1077 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1078
1079 AC_SUBST([X11_INCLUDES])
1080 AC_SUBST([GL_LIB_DEPS])
1081 AC_SUBST([GL_PC_REQ_PRIV])
1082 AC_SUBST([GL_PC_LIB_PRIV])
1083 AC_SUBST([GL_PC_CFLAGS])
1084 AC_SUBST([DRI_PC_REQ_PRIV])
1085 AC_SUBST([GLESv1_CM_LIB_DEPS])
1086 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1087 AC_SUBST([GLESv2_LIB_DEPS])
1088 AC_SUBST([GLESv2_PC_LIB_PRIV])
1089
1090 AC_SUBST([HAVE_XF86VIDMODE])
1091
1092 dnl
1093 dnl More GLX setup
1094 dnl
1095 case "x$enable_glx$enable_xlib_glx" in
1096 xyesyes)
1097     DEFINES="$DEFINES -DUSE_XSHM"
1098     ;;
1099 xyesno)
1100     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1101     if test "x$driglx_direct" = xyes; then
1102         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1103     fi
1104     ;;
1105 esac
1106
1107 dnl
1108 dnl TLS detection
1109 dnl
1110
1111 AC_ARG_ENABLE([glx-tls],
1112     [AS_HELP_STRING([--enable-glx-tls],
1113         [enable TLS support in GLX @<:@default=disabled@:>@])],
1114     [GLX_USE_TLS="$enableval"],
1115     [GLX_USE_TLS=no])
1116 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1117
1118 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1119       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1120
1121 dnl
1122 dnl More DRI setup
1123 dnl
1124 dnl Directory for DRI drivers
1125 AC_ARG_WITH([dri-driverdir],
1126     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1127         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1128     [DRI_DRIVER_INSTALL_DIR="$withval"],
1129     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1130 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1131 dnl Extra search path for DRI drivers
1132 AC_ARG_WITH([dri-searchpath],
1133     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1134         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1135     [DRI_DRIVER_SEARCH_DIR="$withval"],
1136     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1137 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1138 dnl Which drivers to build - default is chosen by platform
1139 AC_ARG_WITH([dri-drivers],
1140     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1141         [comma delimited classic DRI drivers list, e.g.
1142         "swrast,i965,radeon" @<:@default=auto@:>@])],
1143     [with_dri_drivers="$withval"],
1144     [with_dri_drivers=auto])
1145
1146 if test "x$with_dri_drivers" = xauto; then
1147     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1148         with_dri_drivers="yes"
1149     else
1150         with_dri_drivers="no"
1151     fi
1152 fi
1153 if test "x$with_dri_drivers" = xno; then
1154     with_dri_drivers=''
1155 fi
1156
1157 dnl If $with_dri_drivers is yes, drivers will be added through
1158 dnl platform checks. Set DEFINES and LIB_DEPS
1159 if test "x$enable_dri" = xyes; then
1160     # Platform specific settings and drivers to build
1161     case "$host_os" in
1162     linux*)
1163         DEFINES="$DEFINES -DHAVE_ALIAS"
1164         if test "x$enable_dri3" = xyes; then
1165             DEFINES="$DEFINES -DHAVE_DRI3"
1166         fi
1167
1168         if test "x$have_pci_id" != xyes; then
1169             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1170         fi
1171
1172         case "$host_cpu" in
1173         powerpc* | sparc*)
1174             # Build only the drivers for cards that exist on PowerPC/sparc
1175             if test "x$with_dri_drivers" = "xyes"; then
1176                 with_dri_drivers="r200 radeon swrast"
1177             fi
1178             ;;
1179         esac
1180         ;;
1181     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1182         DEFINES="$DEFINES -DHAVE_ALIAS"
1183         ;;
1184     gnu*)
1185         DEFINES="$DEFINES -DHAVE_ALIAS"
1186         ;;
1187     cygwin*)
1188         if test "x$with_dri_drivers" = "xyes"; then
1189             with_dri_drivers="swrast"
1190         fi
1191         ;;
1192     darwin*)
1193         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1194         if test "x$with_dri_drivers" = "xyes"; then
1195             with_dri_drivers="swrast"
1196         fi
1197         ;;
1198     esac
1199
1200     # default drivers
1201     if test "x$with_dri_drivers" = "xyes"; then
1202         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1203     fi
1204
1205     # Check for expat
1206     PKG_CHECK_MODULES([EXPAT], [expat], [],
1207         # expat version 2.0 and earlier do not provide expat.pc
1208         [AC_CHECK_HEADER([expat.h],[],
1209                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1210          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1211                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1212          EXPAT_LIBS="-lexpat"])
1213
1214     DRICOMMON_NEED_LIBDRM=no
1215     # If we are building any DRI driver other than swrast.
1216     if test -n "$with_dri_drivers"; then
1217         if test "x$with_dri_drivers" != xswrast; then
1218             # ... libdrm is required
1219             if test "x$have_libdrm" != xyes; then
1220                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1221             fi
1222             DRICOMMON_NEED_LIBDRM=yes
1223         fi
1224     fi
1225
1226     # If we're building any gallium DRI driver other than swrast
1227     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1228         if test "x$with_gallium_drivers" != xswrast; then
1229             # ... build a libdrm aware dricommon
1230             DRICOMMON_NEED_LIBDRM=yes
1231         fi
1232     fi
1233
1234     # put all the necessary libs together
1235     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1236 fi
1237
1238 AC_SUBST([DRI_LIB_DEPS])
1239
1240 DRI_DIRS=''
1241 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1242 if test -n "$with_dri_drivers"; then
1243     if test "x$enable_opengl" != xyes; then
1244         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1245     fi
1246
1247     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1248     for driver in $dri_drivers; do
1249         DRI_DIRS="$DRI_DIRS $driver"
1250         case "x$driver" in
1251         xi915)
1252             HAVE_I915_DRI=yes;
1253             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1254             ;;
1255         xi965)
1256             HAVE_I965_DRI=yes;
1257             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1258             ;;
1259         xnouveau)
1260             HAVE_NOUVEAU_DRI=yes;
1261             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1262             ;;
1263         xradeon)
1264             HAVE_RADEON_DRI=yes;
1265             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1266             ;;
1267         xr200)
1268             HAVE_R200_DRI=yes;
1269             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1270             ;;
1271         xswrast)
1272             HAVE_SWRAST_DRI=yes;
1273             ;;
1274         *)
1275             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1276             ;;
1277         esac
1278     done
1279     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1280 fi
1281
1282 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1283 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1284                                   "x$enable_osmesa" = xyes -o \
1285                                   -n "$DRI_DIRS")
1286
1287 dnl
1288 dnl OSMesa configuration
1289 dnl
1290
1291 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1292 AC_ARG_WITH([osmesa-bits],
1293     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1294         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1295     [osmesa_bits="$withval"],
1296     [osmesa_bits=8])
1297 if test "x$osmesa_bits" != x8; then
1298     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1299         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1300         osmesa_bits=8
1301     fi
1302 fi
1303 case "x$osmesa_bits" in
1304 x8)
1305     OSMESA_LIB="${OSMESA_LIB}"
1306     ;;
1307 x16|x32)
1308     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1309     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1310     ;;
1311 *)
1312     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1313     ;;
1314 esac
1315
1316 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1317     # only link libraries with osmesa if shared
1318     if test "$enable_static" = no; then
1319         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1320     else
1321         OSMESA_LIB_DEPS=""
1322     fi
1323     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1324 fi
1325
1326 AC_SUBST([OSMESA_LIB_DEPS])
1327 AC_SUBST([OSMESA_PC_REQ])
1328 AC_SUBST([OSMESA_PC_LIB_PRIV])
1329
1330 dnl
1331 dnl gbm configuration
1332 dnl
1333 if test "x$enable_gbm" = xauto; then
1334     case "$with_egl_platforms" in
1335         *drm*)
1336             enable_gbm=yes ;;
1337          *)
1338             enable_gbm=no ;;
1339     esac
1340 fi
1341 if test "x$enable_gbm" = xyes; then
1342     if test "x$need_pci_id$have_pci_id" = xyesno; then
1343         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1344     fi
1345
1346     if test "x$enable_dri" = xyes; then
1347         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1348         if test "x$enable_shared_glapi" = xno; then
1349             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1350         fi
1351     else
1352         # Strictly speaking libgbm does not require --enable-dri, although
1353         # both of its backends do. Thus one can build libgbm without any
1354         # backends if --disable-dri is set.
1355         # To avoid unnecessary complexity of checking if at least one backend
1356         # is available when building, just mandate --enable-dri.
1357         AC_MSG_ERROR([gbm requires --enable-dri])
1358     fi
1359 fi
1360 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1361 if test "x$need_pci_id$have_libudev" = xyesyes; then
1362     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1363 else
1364     GBM_PC_REQ_PRIV=""
1365 fi
1366 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1367 AC_SUBST([GBM_PC_REQ_PRIV])
1368 AC_SUBST([GBM_PC_LIB_PRIV])
1369
1370 dnl
1371 dnl EGL configuration
1372 dnl
1373 EGL_CLIENT_APIS=""
1374
1375 if test "x$enable_egl" = xyes; then
1376     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1377
1378     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1379
1380     if test "$enable_static" != yes; then
1381         if test "x$enable_dri" = xyes; then
1382             HAVE_EGL_DRIVER_DRI2=1
1383         fi
1384
1385     fi
1386 fi
1387 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1388 AC_SUBST([EGL_LIB_DEPS])
1389
1390 dnl
1391 dnl XA configuration
1392 dnl
1393 if test "x$enable_xa" = xyes; then
1394     if test "x$with_gallium_drivers" = xswrast; then
1395        AC_MSG_ERROR([
1396           Building xa requires at least one non swrast gallium driver.
1397           If you are looking to use libxatracker.so with the VMware driver,
1398           make sure to include svga in the gallium drivers list, apart from
1399           enabling XA.
1400           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1401     fi
1402     enable_gallium_loader=$enable_shared_pipe_drivers
1403 fi
1404 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1405
1406 dnl
1407 dnl OpenVG configuration
1408 dnl
1409 VG_LIB_DEPS=""
1410
1411 if test "x$enable_openvg" = xyes; then
1412     if test "x$enable_egl" = xno; then
1413         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1414     fi
1415     if test -z "$with_gallium_drivers"; then
1416         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1417     fi
1418
1419     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1420                   OpenVG has not been integrated into standard libEGL yet])
1421
1422     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1423     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1424     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1425     AC_SUBST([VG_PC_LIB_PRIV])
1426 fi
1427 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1428
1429 dnl
1430 dnl Gallium G3DVL configuration
1431 dnl
1432 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1433     if test "x$enable_xvmc" = xauto; then
1434         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1435     fi
1436
1437     if test "x$enable_vdpau" = xauto; then
1438         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1439     fi
1440
1441     if test "x$enable_omx" = xauto; then
1442         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1443     fi
1444
1445     if test "x$enable_va" = xauto; then
1446         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1447     fi
1448 fi
1449
1450 if test "x$enable_dri" = xyes -o \
1451         "x$enable_xvmc" = xyes -o \
1452         "x$enable_vdpau" = xyes -o \
1453         "x$enable_omx" = xyes -o \
1454         "x$enable_va" = xyes; then
1455     need_gallium_vl=yes
1456 fi
1457 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1458
1459 if test "x$enable_xvmc" = xyes -o \
1460         "x$enable_vdpau" = xyes -o \
1461         "x$enable_omx" = xyes -o \
1462         "x$enable_va" = xyes; then
1463     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1464     need_gallium_vl_winsys=yes
1465 fi
1466 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1467
1468 if test "x$enable_xvmc" = xyes; then
1469     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1470     enable_gallium_loader=$enable_shared_pipe_drivers
1471 fi
1472 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1473
1474 if test "x$enable_vdpau" = xyes; then
1475     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1476     enable_gallium_loader=$enable_shared_pipe_drivers
1477 fi
1478 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1479
1480 if test "x$enable_omx" = xyes; then
1481     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1482     enable_gallium_loader=$enable_shared_pipe_drivers
1483 fi
1484 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1485
1486 if test "x$enable_va" = xyes; then
1487     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1488     enable_gallium_loader=$enable_shared_pipe_drivers
1489 fi
1490 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1491
1492 dnl
1493 dnl Nine Direct3D9 configuration
1494 dnl
1495 if test "x$enable_nine" = xyes; then
1496     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1497         AC_MSG_ERROR([nine requires the gallium swrast driver])
1498     fi
1499     if test "x$with_gallium_drivers" == xswrast; then
1500         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1501     fi
1502     if test "x$enable_dri3" = xno; then
1503         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1504     fi
1505
1506     enable_gallium_loader=$enable_shared_pipe_drivers
1507 fi
1508 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1509
1510 dnl
1511 dnl OpenCL configuration
1512 dnl
1513
1514 AC_ARG_WITH([libclc-path],
1515    [AS_HELP_STRING([--with-libclc-path],
1516          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1517    [LIBCLC_PATH="$withval"],
1518    [LIBCLC_PATH=''])
1519
1520 if test -n "$LIBCLC_PATH"; then
1521    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1522                   Please review the updated build instructions for clover:
1523                   http://dri.freedesktop.org/wiki/GalliumCompute])
1524 fi
1525
1526
1527 AC_ARG_WITH([clang-libdir],
1528    [AS_HELP_STRING([--with-clang-libdir],
1529          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1530    [CLANG_LIBDIR="$withval"],
1531    [CLANG_LIBDIR=''])
1532
1533 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1534 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1535
1536 if test "x$enable_opencl" = xyes; then
1537     if test -z "$with_gallium_drivers"; then
1538         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1539     fi
1540
1541     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1542         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1543     fi
1544
1545     if test "x$have_libclc" = xno; then
1546         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1547                     Make sure the directory containing libclc.pc is specified in your
1548                     PKG_CONFIG_PATH environment variable.
1549                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1550     else
1551         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1552         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1553         AC_SUBST([LIBCLC_INCLUDEDIR])
1554         AC_SUBST([LIBCLC_LIBEXECDIR])
1555     fi
1556
1557     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1558     enable_gallium_loader=yes
1559
1560     if test "x$enable_opencl_icd" = xyes; then
1561         OPENCL_LIBNAME="MesaOpenCL"
1562     else
1563         OPENCL_LIBNAME="OpenCL"
1564     fi
1565
1566     if test "x$have_libelf" != xyes; then
1567        AC_MSG_ERROR([Clover requires libelf])
1568     fi
1569 fi
1570 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1571 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1572 AC_SUBST([OPENCL_LIBNAME])
1573
1574 dnl
1575 dnl Gallium configuration
1576 dnl
1577 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1578
1579 AC_SUBST([LLVM_BINDIR])
1580 AC_SUBST([LLVM_CFLAGS])
1581 AC_SUBST([LLVM_CPPFLAGS])
1582 AC_SUBST([LLVM_CXXFLAGS])
1583 AC_SUBST([LLVM_LIBDIR])
1584 AC_SUBST([LLVM_LIBS])
1585 AC_SUBST([LLVM_LDFLAGS])
1586 AC_SUBST([LLVM_INCLUDEDIR])
1587 AC_SUBST([LLVM_VERSION])
1588 AC_SUBST([CLANG_RESOURCE_DIR])
1589
1590 case "x$enable_opengl$enable_gles1$enable_gles2" in
1591 x*yes*)
1592     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1593     ;;
1594 esac
1595
1596 AC_SUBST([VG_LIB_DEPS])
1597 AC_SUBST([EGL_CLIENT_APIS])
1598
1599 dnl
1600 dnl EGL Platforms configuration
1601 dnl
1602 AC_ARG_WITH([egl-platforms],
1603     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1604         [comma delimited native platforms libEGL supports, e.g.
1605         "x11,drm" @<:@default=auto@:>@])],
1606     [with_egl_platforms="$withval"],
1607     [if test "x$enable_egl" = xyes; then
1608         with_egl_platforms="x11"
1609     else
1610         with_egl_platforms=""
1611     fi])
1612
1613 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1614     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1615 fi
1616
1617 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1618         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1619         WAYLAND_SCANNER='')
1620 if test "x$WAYLAND_SCANNER" = x; then
1621     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1622 fi
1623
1624 # Do per-EGL platform setups and checks
1625 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1626 for plat in $egl_platforms; do
1627         case "$plat" in
1628         wayland)
1629                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1630
1631                 if test "x$WAYLAND_SCANNER" = x; then
1632                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1633                 fi
1634                 ;;
1635
1636         x11)
1637                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1638                 ;;
1639
1640         drm)
1641                 test "x$enable_gbm" = "xno" &&
1642                         AC_MSG_ERROR([EGL platform drm needs gbm])
1643                 test "x$have_libdrm" != xyes &&
1644                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1645                 ;;
1646
1647         android|fbdev|gdi|null)
1648                 ;;
1649
1650         *)
1651                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1652                 ;;
1653         esac
1654
1655         case "$plat$need_pci_id$have_pci_id" in
1656                 waylandyesno|drmyesno)
1657                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1658         esac
1659 done
1660
1661 # libEGL wants to default to the first platform specified in
1662 # ./configure.  parse that here.
1663 if test "x$egl_platforms" != "x"; then
1664     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1665     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1666 else
1667     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1668 fi
1669
1670 if echo "$egl_platforms" | grep -q 'x11'; then
1671     NEED_WINSYS_XLIB=yes
1672 fi
1673 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1674 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1675 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1676 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1677 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1678
1679 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1680
1681 AC_SUBST([EGL_NATIVE_PLATFORM])
1682 AC_SUBST([EGL_CFLAGS])
1683
1684 # If we don't have the X11 platform, set this define so we don't try to include
1685 # the X11 headers.
1686 if ! echo "$egl_platforms" | grep -q 'x11'; then
1687     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1688     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1689 fi
1690
1691 AC_ARG_WITH([max-width],
1692     [AS_HELP_STRING([--with-max-width=N],
1693                     [Maximum framebuffer width (4096)])],
1694     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1695      AS_IF([test "${withval}" -gt "4096"],
1696            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1697 )
1698 AC_ARG_WITH([max-height],
1699     [AS_HELP_STRING([--with-max-height=N],
1700                     [Maximum framebuffer height (4096)])],
1701     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1702      AS_IF([test "${withval}" -gt "4096"],
1703            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1704 )
1705
1706 dnl
1707 dnl Gallium LLVM
1708 dnl
1709 AC_ARG_ENABLE([gallium-llvm],
1710     [AS_HELP_STRING([--enable-gallium-llvm],
1711         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1712     [enable_gallium_llvm="$enableval"],
1713     [enable_gallium_llvm=auto])
1714
1715 AC_ARG_ENABLE([llvm-shared-libs],
1716     [AS_HELP_STRING([--enable-llvm-shared-libs],
1717         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1718     [enable_llvm_shared_libs="$enableval"],
1719     [enable_llvm_shared_libs=yes])
1720
1721 AC_ARG_WITH([llvm-prefix],
1722     [AS_HELP_STRING([--with-llvm-prefix],
1723         [Prefix for LLVM installations in non-standard locations])],
1724     [llvm_prefix="$withval"],
1725     [llvm_prefix=''])
1726
1727
1728 # Call this inside ` ` to get the return value.
1729 # $1 is the llvm-config command with arguments.
1730 strip_unwanted_llvm_flags() {
1731     # Use \> (marks the end of the word)
1732     echo `$1` | sed \
1733         -e 's/-DNDEBUG\>//g' \
1734         -e 's/-D_GNU_SOURCE\>//g' \
1735         -e 's/-pedantic\>//g' \
1736         -e 's/-Wcovered-switch-default\>//g' \
1737         -e 's/-O.\>//g' \
1738         -e 's/-g\>//g' \
1739         -e 's/-Wall\>//g' \
1740         -e 's/-Wcast-qual\>//g' \
1741         -e 's/-Woverloaded-virtual\>//g' \
1742         -e 's/-fcolor-diagnostics\>//g' \
1743         -e 's/-fdata-sections\>//g' \
1744         -e 's/-ffunction-sections\>//g' \
1745         -e 's/-fno-exceptions\>//g' \
1746         -e 's/-fomit-frame-pointer\>//g' \
1747         -e 's/-fvisibility-inlines-hidden\>//g' \
1748         -e 's/-fPIC\>//g' \
1749         -e 's/-fstack-protector-strong\>//g'
1750 }
1751
1752
1753 if test -z "$with_gallium_drivers"; then
1754     enable_gallium_llvm=no
1755 fi
1756 if test "x$enable_gallium_llvm" = xauto; then
1757     case "$host_cpu" in
1758     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1759     esac
1760 fi
1761 if test "x$enable_gallium_llvm" = xyes; then
1762     if test -n "$llvm_prefix"; then
1763         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1764     else
1765         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1766     fi
1767
1768     if test "x$LLVM_CONFIG" != xno; then
1769         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1770         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1771         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1772         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1773         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1774         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1775         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1776         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1777
1778         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1779             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1780         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1781             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1782
1783         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1784         if test -z "$LLVM_VERSION_PATCH"; then
1785             LLVM_VERSION_PATCH=0
1786         fi
1787
1788         if test -n "${LLVM_VERSION_MAJOR}"; then
1789             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1790         else
1791             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1792         fi
1793
1794         LLVM_REQUIRED_VERSION_MAJOR="3"
1795         LLVM_REQUIRED_VERSION_MINOR="3"
1796         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1797             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1798         fi
1799
1800         LLVM_COMPONENTS="engine bitwriter"
1801         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1802             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1803         fi
1804
1805         if test "x$enable_opencl" = xyes; then
1806             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1807             # LLVM 3.3 >= 177971 requires IRReader
1808             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1809                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1810             fi
1811             # LLVM 3.4 requires Option
1812             if $LLVM_CONFIG --components | grep -qw 'option'; then
1813                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1814             fi
1815             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1816             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1817                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1818             fi
1819             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1820                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1821             fi
1822         fi
1823         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1824         MESA_LLVM=1
1825
1826         dnl Check for Clang internal headers
1827         if test "x$enable_opencl" = xyes; then
1828             if test -z "$CLANG_LIBDIR"; then
1829                 CLANG_LIBDIR=${LLVM_LIBDIR}
1830             fi
1831             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1832             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1833                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1834         fi
1835     else
1836         MESA_LLVM=0
1837         LLVM_VERSION_INT=0
1838     fi
1839 else
1840     MESA_LLVM=0
1841     LLVM_VERSION_INT=0
1842
1843     if test "x$enable_opencl" = xyes; then
1844         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1845     fi
1846 fi
1847
1848 dnl Directory for XVMC libs
1849 AC_ARG_WITH([xvmc-libdir],
1850     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1851         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1852     [XVMC_LIB_INSTALL_DIR="$withval"],
1853     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1854 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1855
1856 dnl
1857 dnl Gallium Tests
1858 dnl
1859 if test "x$enable_gallium_tests" = xyes; then
1860     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1861     enable_gallium_loader=yes
1862 fi
1863 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1864
1865 dnl Directory for VDPAU libs
1866 AC_ARG_WITH([vdpau-libdir],
1867     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1868         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1869     [VDPAU_LIB_INSTALL_DIR="$withval"],
1870     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1871 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1872
1873 dnl Directory for OMX libs
1874
1875 AC_ARG_WITH([omx-libdir],
1876     [AS_HELP_STRING([--with-omx-libdir=DIR],
1877         [directory for the OMX libraries])],
1878     [OMX_LIB_INSTALL_DIR="$withval"],
1879     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1880 AC_SUBST([OMX_LIB_INSTALL_DIR])
1881
1882 dnl Directory for VA libs
1883
1884 AC_ARG_WITH([va-libdir],
1885     [AS_HELP_STRING([--with-va-libdir=DIR],
1886         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1887     [VA_LIB_INSTALL_DIR="$withval"],
1888     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1889 AC_SUBST([VA_LIB_INSTALL_DIR])
1890
1891 AC_ARG_WITH([d3d-libdir],
1892     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1893         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1894     [D3D_DRIVER_INSTALL_DIR="$withval"],
1895     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1896 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1897
1898 dnl
1899 dnl Gallium helper functions
1900 dnl
1901 gallium_require_drm() {
1902     if test "x$have_libdrm" != xyes; then
1903        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1904     fi
1905 }
1906
1907 gallium_require_llvm() {
1908     if test "x$MESA_LLVM" = x0; then
1909         case "$host" in *gnux32) return;; esac
1910         case "$host_cpu" in
1911         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1912         esac
1913     fi
1914 }
1915
1916 gallium_require_drm_loader() {
1917     if test "x$enable_gallium_loader" = xyes; then
1918         if test "x$need_pci_id$have_pci_id" = xyesno; then
1919             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1920         fi
1921         enable_gallium_drm_loader=yes
1922     fi
1923     if test "x$enable_va" = xyes && test "x$7" != x; then
1924          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1925     fi
1926 }
1927
1928 require_egl_drm() {
1929     case "$with_egl_platforms" in
1930         *drm*)
1931             ;;
1932          *)
1933             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1934             ;;
1935     esac
1936     if test "x$enable_gbm" != xyes; then
1937             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1938     fi
1939 }
1940
1941 radeon_llvm_check() {
1942     if test "x$enable_gallium_llvm" != "xyes"; then
1943         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1944     fi
1945     LLVM_REQUIRED_VERSION_MAJOR="3"
1946     LLVM_REQUIRED_VERSION_MINOR="4"
1947     LLVM_REQUIRED_VERSION_PATCH="2"
1948     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1949         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1950     fi
1951     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1952         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1953                       sources with the --enable-experimental-targets=R600
1954                       configure flag])
1955     fi
1956     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1957     NEED_RADEON_LLVM=yes
1958     if test "x$have_libelf" != xyes; then
1959        AC_MSG_ERROR([$1 requires libelf when using llvm])
1960     fi
1961 }
1962
1963 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1964 if test -n "$with_gallium_drivers"; then
1965     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1966     for driver in $gallium_drivers; do
1967         case "x$driver" in
1968         xsvga)
1969             HAVE_GALLIUM_SVGA=yes
1970             gallium_require_drm "svga"
1971             gallium_require_drm_loader
1972             ;;
1973         xi915)
1974             HAVE_GALLIUM_I915=yes
1975             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1976             gallium_require_drm "Gallium i915"
1977             gallium_require_drm_loader
1978             ;;
1979         xilo)
1980             HAVE_GALLIUM_ILO=yes
1981             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1982             gallium_require_drm "Gallium i965/ilo"
1983             gallium_require_drm_loader
1984             ;;
1985         xr300)
1986             HAVE_GALLIUM_R300=yes
1987             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1988             gallium_require_drm "Gallium R300"
1989             gallium_require_drm_loader
1990             gallium_require_llvm "Gallium R300"
1991             ;;
1992         xr600)
1993             HAVE_GALLIUM_R600=yes
1994             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1995             gallium_require_drm "Gallium R600"
1996             gallium_require_drm_loader
1997             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1998                 radeon_llvm_check "r600g"
1999                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2000             fi
2001             if test "x$enable_r600_llvm" = xyes; then
2002                 USE_R600_LLVM_COMPILER=yes;
2003             fi
2004             if test "x$enable_opencl" = xyes; then
2005                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2006             fi
2007             ;;
2008         xradeonsi)
2009             HAVE_GALLIUM_RADEONSI=yes
2010             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2011             gallium_require_drm "radeonsi"
2012             gallium_require_drm_loader
2013             radeon_llvm_check "radeonsi"
2014             require_egl_drm "radeonsi"
2015             ;;
2016         xnouveau)
2017             HAVE_GALLIUM_NOUVEAU=yes
2018             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2019             gallium_require_drm "nouveau"
2020             gallium_require_drm_loader
2021             ;;
2022         xfreedreno)
2023             HAVE_GALLIUM_FREEDRENO=yes
2024             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2025             gallium_require_drm "freedreno"
2026             gallium_require_drm_loader
2027             ;;
2028         xswrast)
2029             HAVE_GALLIUM_SOFTPIPE=yes
2030             if test "x$MESA_LLVM" = x1; then
2031                 HAVE_GALLIUM_LLVMPIPE=yes
2032             fi
2033             ;;
2034         xvc4)
2035             HAVE_GALLIUM_VC4=yes
2036             gallium_require_drm "vc4"
2037             gallium_require_drm_loader
2038
2039             case "$host_cpu" in
2040                 i?86 | x86_64 | amd64)
2041                 USE_VC4_SIMULATOR=yes
2042                 ;;
2043             esac
2044             ;;
2045         *)
2046             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2047             ;;
2048         esac
2049     done
2050 fi
2051
2052 dnl Set LLVM_LIBS - This is done after the driver configuration so
2053 dnl that drivers can add additional components to LLVM_COMPONENTS.
2054 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2055 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2056 dnl this was causing the same libraries to be appear multiple times
2057 dnl in LLVM_LIBS.
2058
2059 if test "x$MESA_LLVM" != x0; then
2060
2061     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2062
2063     if test "x$enable_llvm_shared_libs" = xyes; then
2064         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2065         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2066         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2067
2068         if test "x$llvm_have_one_so" = xyes; then
2069             dnl LLVM was built using auto*, so there is only one shared object.
2070             LLVM_LIBS="-l$LLVM_SO_NAME"
2071         else
2072             dnl If LLVM was built with CMake, there will be one shared object per
2073             dnl component.
2074             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2075                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2076         Please make sure you have built llvm with the --enable-shared option
2077         and that your llvm libraries are installed in $LLVM_LIBDIR
2078         If you have installed your llvm libraries to a different directory you
2079         can use the --with-llvm-prefix= configure flag to specify this directory.
2080         NOTE: Mesa is attempting to use llvm shared libraries by default.
2081         If you do not want to build with llvm shared libraries and instead want to
2082         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2083         invocation and rebuild.])])
2084
2085            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2086            dnl install uses a shared object for each component and we have
2087            dnl already added all of these objects to LLVM_LIBS.
2088         fi
2089     else
2090         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2091         dnl We need to link to llvm system libs when using static libs
2092         dnl However, only llvm 3.5+ provides --system-libs
2093         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2094             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2095         fi
2096     fi
2097 fi
2098
2099 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2100 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2101 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2102 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2103 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2104 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2105 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2106                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2107 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2108 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2109 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2110 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2111 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2112
2113 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2114
2115 # NOTE: anything using xcb or other client side libs ends up in separate
2116 #       _CLIENT variables.  The pipe loader is built in two variants,
2117 #       one that is standalone and does not link any x client libs (for
2118 #       use by XA tracker in particular, but could be used in any case
2119 #       where communication with xserver is not desired).
2120 if test "x$enable_gallium_loader" = xyes; then
2121     if test "x$NEED_WINSYS_XLIB" = xyes; then
2122         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2123     fi
2124
2125     if test "x$enable_dri" = xyes; then
2126         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2127     fi
2128
2129     if test "x$enable_gallium_drm_loader" = xyes; then
2130         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2131         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2132                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2133         if test "x$pipe_loader_have_xcb" = xyes; then
2134             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2135             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2136         fi
2137     fi
2138
2139     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2140     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2141
2142     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2143     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2144     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2145     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2146 fi
2147
2148 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2149 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2150 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2151 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2152 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2153 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2154
2155 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2156                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2157                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2158 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2159 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2160 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2161 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2162 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2163 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2164 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2165 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2166 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2167     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2168 fi
2169
2170 AC_SUBST([ELF_LIB])
2171
2172 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2173 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2174 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2175 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2176 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2177
2178 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2179 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2180 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2181
2182 AC_SUBST([NINE_MAJOR], 1)
2183 AC_SUBST([NINE_MINOR], 0)
2184 AC_SUBST([NINE_TINY], 0)
2185 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2186
2187 AC_SUBST([VDPAU_MAJOR], 1)
2188 AC_SUBST([VDPAU_MINOR], 0)
2189
2190 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2191 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2192 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2193 AC_SUBST([VA_MINOR], $VA_MINOR)
2194
2195 AC_SUBST([XVMC_MAJOR], 1)
2196 AC_SUBST([XVMC_MINOR], 0)
2197
2198 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2199 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2200 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2201 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2202
2203 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2204 AC_SUBST([XA_MINOR], $XA_MINOR)
2205 AC_SUBST([XA_TINY], $XA_TINY)
2206 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2207
2208 dnl Restore LDFLAGS and CPPFLAGS
2209 LDFLAGS="$_SAVE_LDFLAGS"
2210 CPPFLAGS="$_SAVE_CPPFLAGS"
2211
2212 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2213 if test "x$acv_mesa_CLANG" = xyes; then
2214     CFLAGS="$CFLAGS -Qunused-arguments"
2215     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2216 fi
2217
2218 dnl Add user CFLAGS and CXXFLAGS
2219 CFLAGS="$CFLAGS $USER_CFLAGS"
2220 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2221
2222 dnl Substitute the config
2223 AC_CONFIG_FILES([Makefile
2224                 src/Makefile
2225                 src/egl/drivers/dri2/Makefile
2226                 src/egl/main/Makefile
2227                 src/egl/main/egl.pc
2228                 src/egl/wayland/wayland-drm/Makefile
2229                 src/egl/wayland/wayland-egl/Makefile
2230                 src/egl/wayland/wayland-egl/wayland-egl.pc
2231                 src/gallium/Makefile
2232                 src/gallium/auxiliary/Makefile
2233                 src/gallium/auxiliary/pipe-loader/Makefile
2234                 src/gallium/drivers/freedreno/Makefile
2235                 src/gallium/drivers/galahad/Makefile
2236                 src/gallium/drivers/i915/Makefile
2237                 src/gallium/drivers/identity/Makefile
2238                 src/gallium/drivers/ilo/Makefile
2239                 src/gallium/drivers/llvmpipe/Makefile
2240                 src/gallium/drivers/noop/Makefile
2241                 src/gallium/drivers/nouveau/Makefile
2242                 src/gallium/drivers/r300/Makefile
2243                 src/gallium/drivers/r600/Makefile
2244                 src/gallium/drivers/radeon/Makefile
2245                 src/gallium/drivers/radeonsi/Makefile
2246                 src/gallium/drivers/rbug/Makefile
2247                 src/gallium/drivers/softpipe/Makefile
2248                 src/gallium/drivers/svga/Makefile
2249                 src/gallium/drivers/trace/Makefile
2250                 src/gallium/drivers/vc4/Makefile
2251                 src/gallium/drivers/vc4/kernel/Makefile
2252                 src/gallium/state_trackers/clover/Makefile
2253                 src/gallium/state_trackers/dri/Makefile
2254                 src/gallium/state_trackers/glx/xlib/Makefile
2255                 src/gallium/state_trackers/nine/Makefile
2256                 src/gallium/state_trackers/omx/Makefile
2257                 src/gallium/state_trackers/osmesa/Makefile
2258                 src/gallium/state_trackers/va/Makefile
2259                 src/gallium/state_trackers/vdpau/Makefile
2260                 src/gallium/state_trackers/vega/Makefile
2261                 src/gallium/state_trackers/xa/Makefile
2262                 src/gallium/state_trackers/xvmc/Makefile
2263                 src/gallium/targets/d3dadapter9/Makefile
2264                 src/gallium/targets/d3dadapter9/d3d.pc
2265                 src/gallium/targets/dri/Makefile
2266                 src/gallium/targets/libgl-xlib/Makefile
2267                 src/gallium/targets/omx/Makefile
2268                 src/gallium/targets/opencl/Makefile
2269                 src/gallium/targets/osmesa/Makefile
2270                 src/gallium/targets/osmesa/osmesa.pc
2271                 src/gallium/targets/pipe-loader/Makefile
2272                 src/gallium/targets/va/Makefile
2273                 src/gallium/targets/vdpau/Makefile
2274                 src/gallium/targets/xa/Makefile
2275                 src/gallium/targets/xa/xatracker.pc
2276                 src/gallium/targets/xvmc/Makefile
2277                 src/gallium/tests/trivial/Makefile
2278                 src/gallium/tests/unit/Makefile
2279                 src/gallium/winsys/freedreno/drm/Makefile
2280                 src/gallium/winsys/i915/drm/Makefile
2281                 src/gallium/winsys/intel/drm/Makefile
2282                 src/gallium/winsys/nouveau/drm/Makefile
2283                 src/gallium/winsys/radeon/drm/Makefile
2284                 src/gallium/winsys/svga/drm/Makefile
2285                 src/gallium/winsys/sw/dri/Makefile
2286                 src/gallium/winsys/sw/fbdev/Makefile
2287                 src/gallium/winsys/sw/kms-dri/Makefile
2288                 src/gallium/winsys/sw/null/Makefile
2289                 src/gallium/winsys/sw/wayland/Makefile
2290                 src/gallium/winsys/sw/wrapper/Makefile
2291                 src/gallium/winsys/sw/xlib/Makefile
2292                 src/gallium/winsys/vc4/drm/Makefile
2293                 src/gbm/Makefile
2294                 src/gbm/main/gbm.pc
2295                 src/glsl/Makefile
2296                 src/glx/Makefile
2297                 src/glx/apple/Makefile
2298                 src/glx/tests/Makefile
2299                 src/gtest/Makefile
2300                 src/loader/Makefile
2301                 src/mapi/Makefile
2302                 src/mapi/es1api/glesv1_cm.pc
2303                 src/mapi/es2api/glesv2.pc
2304                 src/mapi/glapi/gen/Makefile
2305                 src/mesa/Makefile
2306                 src/mesa/gl.pc
2307                 src/mesa/drivers/dri/dri.pc
2308                 src/mesa/drivers/dri/common/Makefile
2309                 src/mesa/drivers/dri/common/xmlpool/Makefile
2310                 src/mesa/drivers/dri/i915/Makefile
2311                 src/mesa/drivers/dri/i965/Makefile
2312                 src/mesa/drivers/dri/Makefile
2313                 src/mesa/drivers/dri/nouveau/Makefile
2314                 src/mesa/drivers/dri/r200/Makefile
2315                 src/mesa/drivers/dri/radeon/Makefile
2316                 src/mesa/drivers/dri/swrast/Makefile
2317                 src/mesa/drivers/osmesa/Makefile
2318                 src/mesa/drivers/osmesa/osmesa.pc
2319                 src/mesa/drivers/x11/Makefile
2320                 src/mesa/main/tests/Makefile
2321                 src/util/Makefile
2322                 src/util/tests/hash_table/Makefile])
2323
2324 AC_OUTPUT
2325
2326 dnl
2327 dnl Output some configuration info for the user
2328 dnl
2329 echo ""
2330 echo "        prefix:          $prefix"
2331 echo "        exec_prefix:     $exec_prefix"
2332 echo "        libdir:          $libdir"
2333 echo "        includedir:      $includedir"
2334
2335 dnl API info
2336 echo ""
2337 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2338 echo "        OpenVG:          $enable_openvg"
2339
2340 dnl Driver info
2341 echo ""
2342 case "x$enable_osmesa$enable_gallium_osmesa" in
2343 xnoyes)
2344         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2345         ;;
2346 xyesno)
2347         echo "        OSMesa:          lib$OSMESA_LIB"
2348         ;;
2349 xnono)
2350         echo "        OSMesa:          no"
2351         ;;
2352 esac
2353
2354 echo ""
2355 if test "x$enable_dri" != xno; then
2356         echo "        DRI platform:    $dri_platform"
2357         if test -z "$DRI_DIRS"; then
2358             echo "        DRI drivers:     no"
2359         else
2360             echo "        DRI drivers:     $DRI_DIRS"
2361         fi
2362         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2363 fi
2364
2365 case "x$enable_glx$enable_xlib_glx" in
2366 xyesyes)
2367     echo "        GLX:             Xlib-based"
2368     ;;
2369 xyesno)
2370     echo "        GLX:             DRI-based"
2371     ;;
2372 *)
2373     echo "        GLX:             $enable_glx"
2374     ;;
2375 esac
2376
2377 dnl EGL
2378 echo ""
2379 echo "        EGL:             $enable_egl"
2380 if test "$enable_egl" = yes; then
2381     echo "        EGL platforms:   $egl_platforms"
2382
2383     egl_drivers=""
2384     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2385         egl_drivers="$egl_drivers builtin:egl_dri2"
2386     fi
2387
2388     echo "        EGL drivers:    $egl_drivers"
2389 fi
2390
2391 echo ""
2392 if test "x$MESA_LLVM" = x1; then
2393     echo "        llvm:            yes"
2394     echo "        llvm-config:     $LLVM_CONFIG"
2395     echo "        llvm-version:    $LLVM_VERSION"
2396 else
2397     echo "        llvm:            no"
2398 fi
2399
2400 echo ""
2401 if test -n "$with_gallium_drivers"; then
2402     echo "        Gallium:         yes"
2403 else
2404     echo "        Gallium:         no"
2405 fi
2406
2407
2408 dnl Libraries
2409 echo ""
2410 echo "        Shared libs:     $enable_shared"
2411 echo "        Static libs:     $enable_static"
2412 echo "        Shared-glapi:    $enable_shared_glapi"
2413
2414 dnl Compiler options
2415 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2416 cflags=`echo $CFLAGS | \
2417     $SED 's/^ *//;s/  */ /;s/ *$//'`
2418 cxxflags=`echo $CXXFLAGS | \
2419     $SED 's/^ *//;s/  */ /;s/ *$//'`
2420 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2421 echo ""
2422 echo "        CFLAGS:          $cflags"
2423 echo "        CXXFLAGS:        $cxxflags"
2424 echo "        Macros:          $defines"
2425 echo ""
2426 if test "x$MESA_LLVM" = x1; then
2427     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2428     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2429     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2430     echo ""
2431 fi
2432 echo "        PYTHON2:         $PYTHON2"
2433
2434 echo ""
2435 echo "        Run '${MAKE-make}' to build Mesa"
2436 echo ""