inc/LP_MSP430FR2476.asm

   1 ; -*- coding: utf-8 -*-
   2 ; LP_MSP430FR2476.asm
   3
   4 ; ===================================================================================
   5 ; in case of 3.3V powered by UARTtoUSB bridge, open J13 straps {RST,TST,V+,5V} BEFORE
   6 ; ===================================================================================
   7
   8 ;     J101 Target    J101    eZ-FET             UARTtoUSB
   9 ;
  10 ;            DVSS 14 o--o 13 GND
  11 ;             5V0 12 o--o 11 5V0
  12 ;            DVCC 10 o--o 9  3V3
  13 ;    P1.5 UCA0_RX  8 o--o 7  <------------ TX   UARTtoUSB
  14 ;    P1.4 UCA0_TX  6 o--o 5  <---------+-> RX   UARTtoUSB
  15 ;     SBWTDIO/RST  4 o--o 3            |         _
  16 ;      SBWTCK/TST  2 o--o 1            +--4k7---o o-- GND
  17 ;                                             DeepRST
  18 ; SD_Card socket
  19 ;  VCC -                       ----> VCC  SD_CardAdapter
  20 ;  GND -                       <---> GND  SD_CardAdapter
  21 ; P2.4 - UCA1 CLK       J2     ----> CLK  SD_CardAdapter (SCK)
  22 ; P2.6 - UCA1 TXD/SIMO  J1     ----> SDI  SD_CardAdapter (MOSI)
  23 ; P2.5 - UCA1 RXD/SOMI  J1     <---- SDO  SD_CardAdapter (MISO)
  24 ; P1.6 -                J4     ----> CS   SD_CardAdapter (Card Select)
  25 ; P1.7 -                J4     <---- CD   SD_CardAdapter (Card Detect)
  26 ;
  27 ; ======================================================================
  28 ; LP_MSP430FR2476 board
  29 ; ======================================================================
  30
  31 ; J1 - left ext.
  32 ; 3v3
  33 ; P1.6/UCA0CLK/TA1CLK/TDI/TCLK/A6
  34 ; P2.5/UCA1RXD/UCA1SOMI/CAP1.2
  35 ; P2.6/UCA1TXD/UCA1SIMO/CAP1.3
  36 ; P2.2/SYNC/ACLK/COMP0.1
  37 ; P5.4/UCB1STE/TA3CLK/A11
  38 ; P3.5/UCB1CLK/TB0TRG/CAP3.1
  39 ; P4.5/UCB0SOMI/UCB0SCL/TA3.2
  40 ; P1.3/UCB0SOMI/UCB0SCL/MCLK/A3
  41 ; P1.2/UCB0SIMO/UCB0SDA/TA0.2/A2/VEREF-
  42 ;
  43 ;
  44 ; J3 - left int.
  45 ; 5V
  46 ; GND
  47 ; P1.7/UCA0STE/SMCLK/TDO/A7
  48 ; P4.3/UCB1SOMI/UCB1SCL/TB0.5/A8
  49 ; P4.4/UCB1SIMO/UCB1SDA/TB0.6/A9
  50 ; P5.3/UCB1CLK/TA3.0/A10
  51 ; P1.0/UCB0STE/TA0CLK/A0/VEREF+     -<J7>- LED1
  52 ; P1.1/UCB0CLK/TA0.1/COMP0.0/A1     --- TEMPERATURE SENSOR ---<J9>--- 3V3
  53 ; P5.7/TA2.1/COMP0.2
  54 ; P3.7/TA3.2/CAP2.0
  55 ;
  56 ; J4 - right int.
  57 ; P5.2/UCA0TXD/UCA0SIMO/TB0.4
  58 ; P5.1/UCA0RXD/UCA0SOMI/TB0.3       -<J8>- LED2Red
  59 ; P5.0/UCA0CLK/TB0.2                -<J8>- LED2Green
  60 ; P4.7/UCA0STE/TB0.1                -<J8>- LED2Blue
  61 ; P6.0/TA2.2/COMP0.3
  62 ; P3.3/TA2.1/CAP0.1
  63 ; P6.1/TB0CLK
  64 ; P6.2/TB0.0
  65 ; P4.1/TA3.0/CAP2.2
  66 ; P3.1/UCA1STE/CAP1.0
  67 ;
  68 ; J2 - right ext.
  69 ; GND
  70 ; P4.6/UCB0SIMO/UCB0SDA/TA3.1
  71 ; P2.1/XIN
  72 ; P2.0/XOUT
  73 ; /RST/SBWTDIO
  74 ; P3.2/UCB1SIMO/UCB1SDA/CAP3.2
  75 ; P3.6/UCB1SOMI/UCB1SCL/CAP3.3
  76 ; P4.2/TA3CLK/CAP2.3
  77 ; P2.7/UCB1STE/CAP3.0
  78 ; P2.4/UCA1CLK/CAP1.1
  79 ;
  80 ; switch-keys:
  81 ; P4.0/TA3.1/CAP2.1                 - S1
  82 ; P2.3/TA2.0/CAP0.2                 - S2
  83 ; /RST                              - S3
  84 ;
  85 ; XTAL LF 32768 Hz
  86 ; P2.0/XOUT
  87 ; P2.1/XIN
  88 ;
  89 ;
  90 ; Clocks:
  91 ; 8 MHz DCO intern
  92 ;
  93 ;
  94 ; ----------------------------------------------------------------------
  95 ; POWER ON RESET AND INITIALIZATION : I/O
  96 ; ----------------------------------------------------------------------
  97 ; ----------------------------------------------------------------------
  98 ; POWER ON RESET AND INITIALIZATION : PORT1/2
  99 ; ----------------------------------------------------------------------
 100
 101 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 102
 103 ; PORT1 usage
 104 ; P1.0 - green LED2
 105
 106 LED2_OUT    .equ    P1OUT
 107 LED2_DIR    .equ    P1DIR
 108 LED2        .equ    1
 109
 110
 111 ; PORTx default wanted state : pins as input with pullup resistor
 112
 113             BIS     #-1,&PAREN      ; all pins with pull up/down resistors
 114             MOV     #0FFFEh,&PAOUT  ; all pins with pull up resistors  else P1.0 (LED2)
 115
 116     .IFDEF UCA0_TERM
 117 ; P1.4  UCA0-TXD    --> USB2UART RXD
 118 ; P1.5  UCA0-RXD    <-- USB2UART TXD
 119 TERM_IN     .equ P1IN
 120 TERM_SEL    .equ P1SEL0
 121 TERM_REN    .equ P1REN
 122 TXD         .equ 10h      ; P1.4 = TX
 123 RXD         .equ 20h      ; P1.5 = RX
 124 BUS_TERM    .equ 30h
 125     .ENDIF
 126
 127 CD_SD       .equ 080h   ; P1.7 as Card Detect
 128 SD_CDIN     .equ P1IN
 129
 130 CS_SD       .equ 040h   ; P1.6 as Card Select
 131 SD_CSOUT    .equ P1OUT
 132 SD_CSDIR    .equ P1DIR
 133
 134     .IFDEF UCA1_SD
 135 BUS_SD      .equ 7000h  ; pins P2.4 as UCA1CLK, P2.6 as UCA1SIMO & P2.5 as UCA1SOMI
 136 SD_SEL      .equ PASEL0 ; to configure UCA1
 137 SD_REN      .equ PAREN  ; to configure pullup resistors
 138     .ENDIF
 139
 140 ; P2.3/TA2.0/CAP0.2                 - S2
 141 SW2_IN      .equ    P2IN
 142 SW2         .equ    8
 143
 144 ; ----------------------------------------------------------------------
 145 ; POWER ON RESET AND INITIALIZATION : PORT3/4
 146 ; ----------------------------------------------------------------------
 147 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 148
 149             BIS     #-1,&PBREN      ; all pins 1 with pull up/down resistors
 150             MOV     #07FFFh,&PBOUT  ; all pins with pull up resistors else P4.7 (LED2B)
 151
 152 ; PORT3 usage
 153
 154     .IFDEF UCB1_TERM        ;
 155 TERM_SEL    .equ    P3SEL0
 156 TERM_REN    .equ    P3REN
 157 TERM_OUT    .equ    P3OUT
 158 BUS_TERM    .equ    0Ch     ; P3.2=SDA P3.3=SCL
 159     .ENDIF
 160
 161 ; PORT4 usage
 162
 163 ; S1 - P4.0
 164 SW1_IN      .equ    P4IN
 165 SW1         .equ    1       ; P4.0 = S1
 166
 167
 168 ; LED2B - J8 - P4.7
 169
 170 ; ----------------------------------------------------------------------
 171 ; POWER ON RESET AND INITIALIZATION : PORT5/6
 172 ; ----------------------------------------------------------------------
 173 ; reset state : Px{DIR,REN,SEL0,SEL1,SELC,IE,IFG,IV} = 0 ; Px{IN,OUT,IES} = ?
 174
 175 ; PORT5 usage
 176
 177 ; LED2R - J8 - P5.1  red LED1
 178 ; LED2G - J8 - P5.0
 179
 180 LED1_OUT    .equ P5OUT
 181 LED1_DIR    .equ P5DIR
 182 LED1        .equ 2
 183
 184 ; PORT6 usage
 185
 186 HANDSHAKOUT .equ    P6OUT
 187 HANDSHAKIN  .equ    P6IN
 188 RTS         .equ    2           ; P6.1
 189 CTS         .equ    4           ; P6.2
 190
 191 ;            BIS     #00003h,&PCDIR  ; all pins 0 as input else P5.0 (LED2G) P5.1 (LED2R)
 192 ;            MOV     #0FFFCh,&PCOUT  ; all pins high  else P5.0 (LED2G) P5.1 (LED2R)
 193 ;            BIS     #0FFFCh,&PCREN  ; all pins with pull resistors else P5.0 (LED2G) P5.1 (LED2R)
 194
 195             BIS     #-1,&PCREN      ; all pins with pull up/down resistors
 196             MOV     #0FFFCh,&PCOUT  ; all pins with pull up resistors else P5.0 (LED2G) P5.1 (LED2R)
 197
 198     .IFDEF TERMINAL4WIRES
 199 ; RTS output is wired to the CTS input of UART2USB bridge
 200 ; configure RTS as output high to disable RX TERM during start FORTH
 201             BIS.B #RTS,&P6DIR   ; RTS as output high
 202         .IFDEF TERMINAL5WIRES
 203 ; CTS input must be wired to the RTS output of UART2USB bridge
 204 ; configure CTS as input low (true) to avoid lock when CTS is not wired
 205             BIC.B #CTS,&P6OUT   ; CTS input pulled down
 206         .ENDIF  ; TERMINAL5WIRES
 207     .ENDIF  ; TERMINAL4WIRES
 208
 209 ; ----------------------------------------------------------------------
 210 ; FRAM config
 211 ; ----------------------------------------------------------------------
 212     .IF  FREQUENCY > 8
 213             MOV.B   #0A5h,&FRCTL0_H ; enable FRCTL0 access
 214             MOV.B   #10h,&FRCTL0    ; 1 waitstate @ 16 MHz
 215             MOV.B   #01h,&FRCTL0_H  ; disable FRCTL0 access
 216     .ENDIF
 217
 218 ; ----------------------------------------------------------------------
 219 ; POWER ON RESET SYS config
 220 ; ----------------------------------------------------------------------
 221 ; SYS code
 222 ;    BIC #1,&SYSCFG0 ; enable write program in FRAM
 223     MOV #0A500h,&SYSCFG0 ; enable write MAIN and INFO
 224
 225 ; ----------------------------------------------------------------------
 226 ; POWER ON RESET AND INITIALIZATION : CLOCK SYSTEM
 227 ; ----------------------------------------------------------------------
 228 ; CS code for MSP430FR2476
 229
 230 ; to measure REFO frequency, output ACLK on P2.2:
 231 ;    BIS.B #4,&P2SEL1
 232 ;    BIS.B #4,&P2DIR
 233 ; result : REFO = xx.xx kHz
 234
 235     .IFDEF LF_XTAL
 236 ;            MOV     #0000h,&CSCTL3      ; FLL select XT1, FLLREFDIV=0 (default value)
 237             MOV     #0000h,&CSCTL4      ; ACLOCK select XT1, MCLK & SMCLK select DCOCLKDIV
 238             BIS.B   #03,&P2SEL0         ; P2.0 as XOUT, P2.1 as XIN
 239     .ELSE
 240             BIS     #0010h,&CSCTL3      ; FLL select REFCLOCK
 241 ;            MOV     #0100h,&CSCTL4      ; ACLOCK select REFO, MCLK & SMCLK select DCOCLKDIV (default value)
 242     .ENDIF
 243             BIC.B   #-1,&CSCTL1     ; clear DCORSEL (Set 1MHZ DCORSEL), DCOFTRIM=0, ENable MODulation to reduce EMI
 244     .IF FREQUENCY = 1                   ; nothing else to do
 245     .ELSEIF FREQUENCY = 2
 246             BIS.B   #2,&CSCTL1          ; Set 2MHZ DCORSEL
 247     .ELSEIF FREQUENCY = 4
 248             BIS.B   #4,&CSCTL1          ; Set 4MHZ DCORSEL
 249     .ELSEIF FREQUENCY = 8
 250             BIS.B   #6,&CSCTL1          ; Set 8MHZ DCORSEL
 251     .ELSEIF FREQUENCY = 12
 252             BIS.B   #8,&CSCTL1          ; Set 12MHZ DCORSEL
 253     .ELSEIF FREQUENCY = 16
 254             BIS.B   #10,&CSCTL1         ; Set 16MHZ DCORSEL
 255     .ELSEIF FREQUENCY = 20
 256             BIS.B   #12,&CSCTL1         ; Set 20MHZ DCORSEL
 257     .ELSEIF FREQUENCY = 24
 258             BIS.B   #14,&CSCTL1         ; Set 24MHZ DCORSEL
 259     .ELSEIF
 260     .error "bad frequency setting, only 1,2,4,8,12,16,20,24 MHz"
 261     .ENDIF
 262 ;            MOV #INT(FREQUENCY*1000000/32768)-1,&CSCTL2; set FLLD=0 (DCOCLKCDIV=DCO),set FLLN for frequency slight lower
 263             MOV #INT(FREQUENCY*1000000/32768),&CSCTL2; set FLLD=0 (DCOCLKCDIV=DCO),set FLLN for frequency slight upper
 264             MOV     #92,X           ; 96* 3 ms = 288 ms delay, because FLL lock time = 200 ms
 265 ClockWaitX  MOV     &FREQ_KHZ,Y     ;
 266 ClockWaitY  SUB     #1,Y            ;1
 267             JNZ     ClockWaitY      ;2 FREQ_KHZ x 3 ==> 3ms
 268             SUB     #1,X            ;
 269             JNZ     ClockWaitX      ;