implementations/defs.txt

   1 eq [false] [true] [false] cmp
   2 gt [true] [false] [false] cmp
   3 lt [false] [false] [true] cmp
   4 neq [true] [false] [true] cmp
   5 le [false] [true] [true] cmp
   6 ge [true] [true] [false] cmp
   7 ? dup bool
   8 !- 0 >=
   9 ++ 1 +
  10 -- 1 -
  11 <{} [] swap
  12 <<{} [] rollup
  13 abs dup 0 < [] [neg] branch
  14 anamorphism [pop []] swap [dip swons] genrec
  15 and nulco [nullary [false]] dip branch
  16 app1 grba infrst
  17 app2 [grba swap grba swap] dip [infrst] cons ii
  18 app3 3 appN
  19 appN [grabN] codi map reverse disenstacken
  20 at drop first
  21 average [sum] [size] cleave /
  22 b [i] dip i
  23 binary unary popd
  24 ccccons ccons ccons
  25 ccons cons cons
  26 clear [] swaack pop
  27 cleave fork popdd
  28 clop cleave popdd
  29 cmp [[>] swap] dipd [ifte] ccons [=] swons ifte
  30 codi cons dip
  31 codireco codi reco
  32 dinfrirst dip infrst
  33 dipd [dip] codi
  34 disenstacken swaack pop
  35 divmod [/] [%] clop
  36 down_to_zero [0 >] [dup --] while
  37 drop [rest] times
  38 dupdd [dup] dipd
  39 dupd [dup] dip
  40 dupdipd dup dipd
  41 dupdip dupd dip
  42 enstacken stack [clear] dip
  43 first uncons pop
  44 flatten <{} [concat] step
  45 fork [i] app2
  46 fourth rest third
  47 gcd true [tuck mod dup 0 >] loop pop
  48 genrec [[genrec] ccccons] nullary swons concat ifte
  49 grabN <{} [cons] times
  50 grba [stack popd] dip
  51 hypot [sqr] ii + sqrt
  52 ifte [nullary] dipd swap branch
  53 ii [dip] dupdip i
  54 infra swons swaack [i] dip swaack
  55 infrst infra first
  56 << lshift
  57 lshift [2 *] times
  58 make_generator [codireco] ccons
  59 mod %
  60 neg 0 swap -
  61 not [true] [false] branch
  62 nulco [nullary] cons
  63 nullary [stack] dinfrirst
  64 null [] swap concat bool not
  65 of swap at
  66 or nulco [nullary] dip [true] branch
  67 over [dup] dip swap
  68 pam [i] map
  69 pm [+] [-] clop
  70 popdd [pop] dipd
  71 popd [pop] dip
  72 popopdd [popop] dipd
  73 popopd [popop] dip
  74 popopop pop popop
  75 popop pop pop
  76 product 1 swap [*] step
  77 quoted [unit] dip
  78 range [0 <=] [-- dup] anamorphism
  79 range_to_zero unit [down_to_zero] infra
  80 reco rest cons
  81 rest uncons popd
  82 reverse <{} shunt
  83 rolldown roll<
  84 roll< swapd swap
  85 roll> swap swapd
  86 rollup roll>
  87 rrest rest rest
  88 >> rshift
  89 rshift [2 /] times
  90 run <{} infra
  91 second rest first
  92 shift uncons [swons] dip
  93 shunt [swons] step
  94 size [pop ++] step_zero
  95 small dup null [rest null] [pop true] branch
  96 spiral_next [[[abs] ii <=] [[<>] [pop !-] or] and] [[!-] [[++]] [[--]] ifte dip] [[pop !-] [--] [++] ifte] ifte
  97 split_at [drop] [take] clop
  98 split_list [take reverse] [drop] clop
  99 sqr dup mul
 100 stackd [stack] dip
 101 step_zero 0 roll> step
 102 stuncons stack uncons
 103 sum [+] step_zero
 104 swapd [swap] dip
 105 swoncat swap concat
 106 swons swap cons
 107 tailrec [i] genrec
 108 take <<{} [shift] times pop
 109 ternary binary popd
 110 third rest second
 111 tuck dup swapd
 112 unary nullary popd
 113 uncons [first] [rest] cleave
 114 unit [] cons
 115 unquoted [i] dip
 116 unstack [[] swaack] dip swoncat swaack pop
 117 unswons uncons swap
 118 while swap nulco dupdipd concat loop
 119 x dup i
 120 step [_step0] x
 121 _step0 _step1 [popopop] [_stept] branch
 122 _step1 [?] dipd roll<
 123 _stept [uncons] dipd [dupdipd] dip x
 124 times [_times0] x
 125 _times0 _times1 [popopop] [_timest] branch
 126 _times1 [dup 0 >] dipd roll<
 127 _timest [[--] dip dupdipd] dip x
 128 map [_map0] cons [[] [_map?] [_mape]] dip tailrec
 129 _map? pop bool not
 130 _mape popd reverse
 131 _map0 [_map1] dipd _map2
 132 _map1 stackd shift
 133 _map2 [infrst] cons dipd roll< swons
 134 _isnt_bool not not
 135 _isnt_two_bools [_isnt_bool] ii
 136 _\/_ [_isnt_bool] [not] branch
 137 /\ _isnt_two_bools [pop false] [] branch
 138 \/ _isnt_two_bools [] [pop true] branch
 139 xor [] [not] branch